将带有空格的路径作为参数传递给 bat 文件

Question

我有一个简单的 bat 脚本，可以将文件从已知目录复制到用户指定的目录。如何将路径（可能包含空格）传递给我的脚本并将其与 xcopy 命令一起使用？

---

在我的代码中，我有以下内容

:READ_PWA_PATH
    if "%1" == "" ( 
        rem Set default path
        set PWA_PATH="C:\Program Files\PWA"
        rem
        echo You have not specified your PWA url.
        echo Default will be assumed: C:\Program Files\PWA. 
        choice /C:YN /M:"Do you wish to continue [Y] or cancel the script [N]?"
            IF ERRORLEVEL ==2 GOTO CANCEL
            IF ERRORLEVEL ==1 GOTO READ_WSS_SERVER_EXTENSIONS_PATH
        GOTO END
    ) else (
        set PWA_PATH=%1
    )

如果我只是调用脚本，我会收到以下错误：

C:\Projects\Setup>install.cmd "C:\program files (x86)"

-----------------
SETUP SCRIPT
-----------------

files was unexpected at this time.
C:\Projects\Setup>

Answer 1

使用"%~1"。 %~1 单独删除周围的引号。但是，由于您不知道输入参数%1 是否有引号，因此您应该通过"%~1" 确保它们被确定添加。这在连接变量时特别有用，例如convert.exe "%~1.input" "%~1.output"

Answer 2

有趣的一个。我喜欢收集有关在 cmd/command 中处理引号的引号。

您的特定脚本通过使用 %1 而不是 "%1" 得到修复!!!

通过添加“echo on”（或去掉 echo off），您可以轻松找到它。

Answer 3

我认为 OP 的问题是他想要BOTH以下各项：

• 传递可能包含空格的参数
• 测试是否缺少参数

正如几位发帖人所提到的，要传递包含空格的参数，您必须用双引号将实际参数值括起来。

为了测试是否缺少某个参数，我一直学的方法是：

if "%1" == ""

但是，如果实际参数被引用（如果值包含空格，则必须如此），则变为

if ""actual parameter value"" == ""

这会导致“意外”错误。如果您改为使用

if %1 == ""

然后引用值不再发生错误。但在这种情况下，当值丢失时，测试不再起作用 -- 它变成了

if  == ""

要解决此问题，请在测试中使用任何其他字符（对 DOS 具有特殊含义的字符除外）而不是引号：

if [%1] == []
if .%1. == ..
if abc%1xyz == abcxyz

Answer 4

"%~1" 大部分时间都可以使用。但是，您需要注意以下几点：

1. Windows NT 4.0 不支持它。您需要 Windows 2000 或更高版本。 （如果您正在编写与旧操作系统兼容的脚本，请注意。）
2. 它不会使参数安全和净化。我的观察是，无法正确清理 CMD 脚本中的命令行参数。

为了说明第二点，我举个例子：

REM example.cmd
ECHO %~1

使用 example.cmd dummy^&DIR 运行。 & 符号在这里被转义 (^&) 以防止 shell 解释为命令分隔符，因此它成为传递给脚本的参数的一部分。 DIR 被解释为在运行脚本的子 shell 中的命令，它不应该这样做。

引用它可能会工作一段时间，但仍然不安全：

REM example2.cmd
SETLOCAL EnableExtensions EnableDelayedExpansion
SET "arg1=%~1"
ECHO "%~1"
ECHO !arg1:"=!

example2.cmd foo^"^&DIR^&^"bar 会破坏它。 DIR 命令将运行两次，一次在 SET 之后，另一次在第一个 ECHO 之后。您会看到，您认为被正确引用的 "%~1" 被论点本身不引用。

所以，没有办法保证解析参数的安全。

（编辑：EnableDelayedExpansion 在 Windows NT 4 中也不起作用。感谢此处的信息：http://www.robvanderwoude.com/local.php）

Answer 5

如果路径包含空格，则必须用引号 (") 将其括起来。

不确定这是否正是您要问的？

Answer 6

@echo off
setlocal enableextensions enabledelayedexpansion

if %1=="" (     
        rem Set default path
        set PWA_PATH="C:\Program Files\PWA"
        rem
        echo You have not specified your PWA url.
        echo Default will be assumed: C:\Program Files\PWA.     
        choice /C:YN /M:"Do you wish to continue [Y] or cancel the script [N]?"
                IF ERRORLEVEL ==2 GOTO CANCEL
                IF ERRORLEVEL ==1 GOTO READ_WSS_SERVER_EXTENSIONS_PATH
        GOTO END
    ) else (
        set PWA_PATH=%1
        @echo !PWA_PATH! vs. %1
        goto end
    )
:READ_WSS_SERVER_EXTENSIONS_PATH
echo ok
goto end
:CANCEL
echo cancelled
:end
echo. final %PWA_PATH% vs. %1

正如VardhanDotNet 提到的，%1 就足够了。

"%1%" 会在引号周围添加引号：""c:\Program Files\xxx""，这意味着：

• '空字符串' (""),
• 后跟“c:\Program”，
• 后跟“意外的此处”'Files\xxx'，
• 后跟一个空字符串 ("")

但是请注意，如果您需要在 IF 子句中使用 PWA_PATH，则需要将 if 引用为 !PWA_PATH!（因此 enabledelayedexpansion 作为脚本的开头）

Answer 7

如果您的路径包含空格，请尝试使用%~s1。这将删除空格并将~1 附加到您的路径，更重要的是它指的是文件的绝对路径。尝试使用它。

Answer 8

假设您想通过在 C# 代码中执行批处理文件来备份数据库。这是一个完全有效的解决方案，可以处理路径内的空格。 这适用于 Windows。不过我还没有用单声道测试过。

C#代码：

        public bool BackupDatabase()
    {
        bool res = true;
        string file = "db.bat";
        if (!File.Exists(file)) return false;

        BackupPaths.ForEach(path =>
        {
            Directory.CreateDirectory(path);

            string filePath = Path.Combine(path, string.Format("{0}_{1}.bak", Util.ConvertDateTimeToFileName(false), DatabaseName));
            Process process = new Process();
            process.StartInfo.FileName = file;
            process.StartInfo.Arguments = string.Format(" {0} {1} \\\"{2}\\\""
                , DBServerName
                , DatabaseName
                , filePath);

            process.StartInfo.WindowStyle = ProcessWindowStyle.Normal;

            try
            {
                process.Start();
                process.WaitForExit();
            }
            catch (Exception ee)
            {
                Logger.Log(ee);
                res = false;
            }
        });
        return res;
    }

这里是批处理文件：

@echo OFF
set DB_ServerName=%1
set Name_of_Database=%2
set PathToBackupLocation=%3

echo Server Name = '%DB_ServerName%'
echo Name of Database = '%Name_of_Database%'
echo Path To Backup Location = '%PathToBackupLocation%'

osql -S %DB_ServerName% -E -Q "BACKUP DATABASE %Name_of_Database% TO DISK=%PathToBackupLocation%"

Answer 9

在特殊情况下，您希望始终默认为当前目录，或者，只有在未传入参数时才默认为当前目录，您可以使用%CD%。

根据这个answer on Server Fault：

Windows 在伪环境变量%CD% 中维护当前目录。

查看该帖子以获得一个很好的示例，以及如何通过命令行轻松地直接对其进行测试。

就我而言，我需要使用命令行标志 --dir= 调用一个应用 (myapp.exe)，例如：
myapp --dir=<path-to-desired-directory>。

由于我一直希望标志始终引用我从哪个目录调用应用程序，我可以制作一个批处理文件 (mybat.bat) 来自动捕获我当前的路径，并用它打开应用程序。

mybat . 在 mybat.bat 具有以下内容时起作用：
myapp --dir=%1

这很棒，但能够省略 . 更好。
mybat 在我将内容更改为时有效：
myapp --dir=%CD%