SQL Server：是否可以将 select @var=field from table 语法与变量数据库一起使用？

Question

当我使用下面的脚本时，一切正常：

 create table MyTable (MyField varchar(5))

 insert into Mytable values ('XXX')

 declare @MyVar varchar(5)

 select @MyVar = MyField 
 from dbo.MyTable

 print @MyVar

但我想做的是这样的：

 create table MyTable (MyField varchar(5))

 insert into Mytable values ('XXX')

 declare @MyVar varchar(5)

 declare @DataBase varchar(10) = 'DBMyBase'

 select @MyVar = MyField 
 from @DataBase.dbo.MyTable

 print @MyVar

我试过没有成功：

 create table MyTable (MyField varchar(5))

 insert into Mytable values ('XXX')

 declare @MyVar varchar(5)
 declare @DataBase varchar(10) = 'DBMyBase'
 declare @cmd varchar(max)

 set @cmd = 'select @MyVar = MyField from ' + @DataBase + '.dbo.MyTable'

 exec(@cmd)

 print @MyVar

我也尝试将整个脚本放在@cmd 中，但无法在脚本部分之外捕获@MyVar 值...

对不起，我不知道如何用英文解释，但如果你能理解我，谢谢你的帮助！

Answer 1

这里不需要动态SQL。

EXEC @some_variable（不带括号）需要一个可以是三部分名称的@module_name_var parameter。

因此您可以使用静态 SQL 字符串和 sp_executesql 的三部分名称来设置数据库上下文。

DECLARE @DataBase VARCHAR(10) = 'DBMyBase'
DECLARE @qualified_sp_executesql NVARCHAR(150) = QUOTENAME(@DataBase) + '.sys.sp_executesql'

EXEC @qualified_sp_executesql
  N'select @MyVar = MyField  from dbo.MyTable',
  N'@MyVar nvarchar(60) out',
  @MyVar OUT;

SELECT @MyVar 

Answer 2

当您在设计时不知道整个语句时，您必须像这样使用动态 SQL：

  DECLARE @DataBase NVARCHAR(80) = N'Adventureworks'
  DECLARE @QtdDataBase sysname = QUOTENAME (@DataBase);
  DECLARE @MyVar NVARCHAR(60);
  DECLARE @AddressID INT = 9;
  IF EXISTS (SELECT 1 FROM sys.databases d WHERE d.name= @DataBase)
  begin
    DECLARE 
      @sql NVARCHAR(4000) = 'select @MyVar=AddressLine1 from ' 
          + @QtdDataBase 
          + '.SalesLT.Address where AddressID=@AddressID'
    EXEC sys.sp_executesql 
      @sql, 
      N'@AddressID int, @MyVar nvarchar(60) out', 
      @AddressID, 
      @MyVar OUT;
  end
  SELECT @MyVar [@MyVar], @sql [@sql], @QtdDataBase [@QtdDataBase]

过程 sys.sp_executesql 接受带有形式参数描述的第二个参数和用于为它们提供值并接收输出结果的下一个参数