带有条件分支的 awk gensub 中的反向引用

Question

我指的是 answer to: GNU awk: accessing captured groups in replacement text 但是? 正则表达式匹配的量词

我想制作if 语句或三元运算符?: 或更优雅的东西，这样如果用\\1 反向引用的正则表达式组返回非空字符串，则一个任意字符串（不排除\\1）被插入，如果它返回空字符串，则插入其他任意字符串。我的示例在捕获组返回非空字符串时有效，但在反向引用为空时不返回预期的分支“B”。如何根据反向引用值进行条件分支？

echo abba | awk '{ print gensub(/a(b*)?a/, "\\1"?"A":"B", "g", $0)}'

Answer 1

您传递给任何函数的任何参数中的表达式在调用该函数之前进行评估，因此gensub(/a(b*)?a/, "\\1"?"A":"B", "g", $0) 与str=("\\1"?"A":"B"); gensub(/a(b*)?a/, str, "g", $0) 相同，与gensub(/a(b*)?a/, "A", "g", $0) 相同。

因此，您不能通过单次调用任何函数来完成您显然想做的事情，也不能两次调用gsub()，一次使用ab+a，然后再次使用aa，或类似的调用而不破坏从左到右，最长的顺序，这样的替换函数会将正则表达式与输入进行匹配（如果存在）。

看起来您可能正在尝试执行以下操作，使用 GNU awk for patsplit()：

awk '
    n = patsplit($0,f,/ab*a/,s) {
        $0 = s[0]
        for ( i=1; i<=n; i++ ) {
            $0 = $0 (f[i] ~ /ab+a/ ? "A" : "B") s[i]
        }
    }
1'

或使用任何 awk：

awk '
    {
        head = ""
        while ( match($0,/ab*a/) ) {
            str = substr($0,RSTART,RLENGTH)
            head = head substr($0,1,RSTART-1) (str ~ /ab+a/ ? "A" : "B")
            $0 = substr($0,RSTART+RLENGTH)
        }
        $0 = head $0
    }
1'

但没有样本输入/输出，这是一个猜测。 FWIW 给出了这个示例输入文件：

$ cat file
XabbaXaaXabaX
foo
abbaabba
aabbaabba
bar
abbaaabba

上面会输出：

XAXBXAX
foo
AA
BbbBbba
bar
ABbba

Answer 2

您可以在 gensub 中进行赋值，然后使用三元运算符的值，类似这样

... | awk '{ v=gensub(/a(b*)?a/, "\\1", "g", $0); print v?"A":"B"}'

Answer 3

可能是这样的？：

$ gawk '{ print gensub(/a(.*)a/, (match($0,/a(b*)?a/)?"A":"B"), "g", $0)}' <<< abba
A

$ gawk '{ print gensub(/a(.*)a/, (match($0,/a(b*)?a/)?"A":"B"), "g", $0)}' <<< acca
B