如何在 put 语句中使用函数？ SAS

Question

我正在尝试向 SAS 日志打印一条语句，提醒用户某些程序未运行。为此，我使用 put 语句打印到 SAS 日志：

%let step1 = My program;
%let rec= cats(&step1.);

data _null_;
put "** &rec.  did not run";
run;

put 语句打印：“** 猫（我的程序）没有运行”。有谁知道为什么 cat 函数没有执行？我猜这与在 SAS 语句之前执行的宏代码有关，但我不确定如何使它工作。

编辑

感谢 Reeza 和 Tom。现在我明白了为什么这不起作用 - 我必须使用 %sysfunc 来使用数据步骤之外的函数，并且我不能在 put 语句中使用函数。

Tom - 你要求一个更完整的例子：

我正在尝试在 SAS 日志中打印一条语句，以便用户可以轻松查看哪些程序运行了哪些程序被跳过了。我正在尝试完成以下操作：

data _null_;
array steps(*) $ step1-step7;
do i=1 to dim(steps);
    if symget(cats('run',i)) = 'N' then
    put "** The program "symget(cats('run',i)" did not run";
end;
run;

我想如果我能弄清楚如何在 put 语句中执行一个函数，那么这段代码就可以工作。然而，这是不可能的。不过，我 应该 能够让变量随“i”一起改变。

例如，当 i 为 1 时，put 语句应为“程序 file1.sas 未运行”。

当 i 为 2 时，put 语句应该是“程序 file2.sas 没有运行”，等等。

我尝试使用：

put "** The program &&step&i did not run";

但 SAS 无法识别我的变量。

希望这能提供更多背景信息！

Answer 1

您可以添加 %SYSFUNC() 以在数据步骤之外使用函数，但在这种情况下，CATS 不会为您的流程添加任何价值。

%let step1 = My program;
%let rec= %sysfunc(cats(&step1.));

data _null_;
put "** &rec.  did not run";
put "** &step1.  did not run";
run;

输出：

293
294
295  %let step1 = My program;
296  %let rec= %sysfunc(cats(&step1.));
297
298  data _null_;
299  put "** &rec.  did not run";
300  put "** &step1.  did not run";
301  run;

** My program  did not run
** My program  did not run
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds

Answer 2

如果您正在运行宏，则只需使用 %DO 循环。

%do i=1 %to 7 ;
  %if (N=&&run&i) %then %put NOTE: The program &&step&i did not run;
%end;

否则，只需使用数据步长变量并将其打印出来。

data _null_;
  do i=1 to 7 ;
    if symget(cats('run',i)) = 'N' then do;
      length program $100 ;
      program=symget(cats('step',i));
      put 'NOTE: The program ' program 'did not run';
    end;
  end;
run;