在 Julia 中定义冲突模块

Question

我是 Julia 新手（与 MATLAB 一起使用）。我正在使用 ScikitLearn 中可用的工具对一些数据集进行清理并编码分类变量，然后运行清理数据的 XGBoost。

但是，我无法使用经过训练的 XGBoost 模型进行预测，因为 ScitkitLearn 和 XGBoost 都有一个名为 predict 的函数。参考下面的错误信息：

警告：ScikitLearn 和 XGBoost 都导出“预测”；在模块 Main 中使用它必须是合格的 错误：LoadError：UndefVarError：预测未定义

问题是我无法将 XGBoost 的 predict 函数定义为 XGBoost.predict，因为这不起作用，而且它似乎是我所知道的唯一解决方案。

此外，我无法找到或理解如何在不加载 predict 函数的情况下仅从 ScikitLearn 加载特定模块。例如，import MLDataUtils.splitobs 格式适用于大多数包，但 ScikitLearn.preprocessing 不适用。

Answer 1

这是您问题的 MWE（两个模块 exporting 同名）：

module A
    export f
    f() = println("f from A")
end
module B
    export f
    f() = println("f from B")
end

现在，考虑一下你 using 和 A 和 B 并尝试调用 f 的情况：

julia> using .A, .B

julia> f()
WARNING: both B and A export "f"; uses of it in module Main must be qualified
ERROR: UndefVarError: f not defined

失败的原因是 Julia 不知道你对 f 的意思；是A.f 还是B.f？您可以通过明确消除对 f 的任何调用的歧义来解决此问题：

julia> using .A, .B

julia> A.f()
f from A

julia> B.f()
f from B

如果您希望能够仅通过名称调用其中一个函数 (f)，那么您（用户）必须选择 f 应该指向的内容。您可以通过将其明确定义为 import 语句的一部分来做到这一点：

julia> using .A, .B

julia> using .B: f # explicitly choosing f to be B.f

julia> f() # no error
f from B

julia> A.f()
f from A

julia> B.f()
f from B

另一种选择是在命名空间中明确定义您自己的名称f：

julia> using .A, .B

julia> const f = B.f # defining a new name in this namespace pointing to B.f
f (generic function with 1 method)

julia> f() # no error
f from B

julia> A.f()
f from A

julia> B.f()
f from B