Stata 事件研究图形代码

Question

我正在尝试为 Stata 中的事件研究编写代码，但我无法完全得到我想要的。 Jacobson、LaLonde 和 Sullivan (1993)，第 698 页图 3 (http://www.princeton.edu/~davidlee/wp/0.pdf) 的图与我想要的非常相似，除了我还想添加置信区间。

基于本教程http://www.stata.com/meeting/germany14/abstracts/materials/de14_jann.pdf，我编写了以下代码：

sysuse auto, clear
egen t = fill(1,2,3,4,1,2,3,4)
quietly regress price ib2.t trunk weight if foreign==0
estimates store domestic
quietly regress price ib2.t trunk weight if foreign==1
estimates store foreign
coefplot (domestic, label(Domestic Cars)) (foreign, label(Foreign Cars)), drop(_cons) xline(0) vertical omitted baselevels

这会产生一些我想要的东西，但存在以下问题：

1. 点估计值和置信区间是并排的，而不是相互重叠的（如果这是唯一的问题，这可能没问题）。
2. 我的时间变量 t 出现在每个 x 标签中（t=1、t=2 等），但我只想说（1、2 等）没有 t=。
3. 在这个玩具示例中，我必须从 1 开始我的 t 编号，因为与 i 运算符相结合的因子变量必须是非负数。我想让我的时间变量能够接受负数。
4. 我不希望trunk 和weight 出现在情节中。将这些放在drop(...) 中可以吗？
5. 我还希望能够在回归残差中完成所有这些操作，而不是我上面的操作。
6. 我想将点估计值与线连接起来。

我根本没有与coefplot 命令结婚。其他技术，尤其是使用内置的 Stata 命令也是完全可以接受的。

Answer 1

希望我已经正确回答了您的问题，也许我误解了某些内容，但这是我的答案：

（我没有解决 5，因为我不确定你在寻找那个问题的确切内容，但也许在看到我的解决方案之后就会清楚）

代码：

// load data same as before
sysuse auto, clear
egen t = fill(1,2,3,4,1,2,3,4)

// get coefficients and standard errors of regressions over foreign
statsby _b _se , clear by(foreign): regress price ib2.t trunk weight

// there are some extra variables we don't need/want
drop *_trunk *_weight *_cons

// generate confidence intervals and rename coefficient variables
forvalues i = 1/4 {
    local j = `i'+7
    gen ci_low`i' = _stat_`i' - 1.96*_stat_`j'
    gen ci_high`i' = _stat_`i' + 1.96*_stat_`j'
    rename _stat_`i' coef`i'

}
// no longer in need of standard error variables
drop  _stat_8 _stat_9 _stat_10 _stat_11

// now, we want our data in long format so we can do a twoway graph
reshape long coef ci_low ci_high, i(foreign) j(t)

// we can label the t values so that they start below 1
lab def timeseries 1 "-1" 2 "0" 3 "1" 4 "2"
lab values t timeseries

// now graph, note each factor has two  pieces, a scatter (with connecting lines) 
// and an rcap for the confidence intervals
twoway (sc coef t if foreign == 1, mcolor(navy) lcolor(navy) connect(direct)) ///
        (rcap ci_low ci_high t if foreign == 1, lcolor(navy)) ///
    (sc coef t if foreign == 0, mcolor(maroon) lcolor(maroon) connect(direct)) ///
        (rcap ci_low ci_high t if foreign == 0, lcolor(maroon)), ///
    legend(lab(1 "Foreign") lab(2 "Foreign CI") lab(3 "Domestic") lab(4 "Domestic CI")) ///
    xlab(,val)

人们可能希望改进的一些方法是：

• 使用标签定义，可以使用 for 循环来处理比这更长的时间序列，所以它不是全部手动完成的

• 我不是 statsby 方面的专家，所以也许有一种更简单的方法来获取置信区间并省略躯干、重量和常数

至于残差，这个答案的基本直觉是您需要一个包含系数和置信区间的数据集。因此，如果您可以计算残差及其 CI 的值并将其放入数据集中，那么您可以使用相同类型的双向图。