将包含零的单元格替换为空白

Question

我有大量数据 A4:EW8000+，我想用空白单元格替换包含零的单元格。格式化单元格不是一种选择，因为我需要保留当前格式。我正在寻找用空白单元格替换零的最快方法。

我可以通过循环来做到这一点，但它非常慢。下面的代码：

Sub clearzero() 
Dim rng As Range 
For Each rng In Range("A1:EW10000")
    If rng.Value = 0 Then 
        rng.Value = "" 
    End If 
Next 
End Sub

有没有一种简单的方法可以在不循环的情况下做到这一点？

我尝试了以下代码，但它似乎无法正常工作。它将 Excel 挂起一段时间（没有响应），然后循环遍历范围并清空每个单元格。

Sub RemoveZero()
  Dim LastRow As Long
  Const StartRow As Long = 2
  LastRow = Cells.Find(What:="0", SearchOrder:=xlRows, SearchDirection:=xlPrevious, LookIn:=xlValues).Row
  With Range("B:EW")
     .Value = Range("B:EW").Value
     .Replace "0", "0", xlWhole, , False
     On Error Resume Next
     .SpecialCells(xlConstants).Value = ""
     .SpecialCells(xlFormulas).Value = 0
  End With
End Sub

Answer 1

这是自动化替换所需的所有 VBA：

[a4:ew10000].Replace 0, "", 1

.

更新

虽然以上内容简明扼要，但以下可能是最快的方法。在我的计算机上，您的整个范围只需要不到四分之一秒的时间：

Sub RemoveZero()

    Dim i&, j&, v, r As Range

    Set r = [a4:ew10000]
    v = r.Value2
    For i = 1 To UBound(v, 1)
        For j = 1 To UBound(v, 2)
            If Len(v(i, j)) Then
                If v(i, j) = 0 Then r(i, j) = vbNullString
            End If
        Next
    Next

End Sub

Answer 2

我发现有时在像这样的批量替换操作中循环遍历列实际上更方便。

dim c as long
with worksheets("Sheet1")
    with .cells(1, 1).currentregion
        for c = 1 to .columns.count
            with .columns(c)
                .replace what:=0, replacement:=vbNullString, lookat:=xlWhole
            end with
        next c
    end with
end with

将整个范围分成几个较小的操作可以提高整体性能。我自己的经验是在更大的数据块上（例如 142 列 × ~250K 行）并从 SQL 提要中替换 NULL 而不是零，但这应该会有所帮助。