.net 中的日期差异错误

Question

我使用下面的代码sn-p

lxDate= #1/1/1970#
GetUnixDate = CType(DateDiff("S", lxDate, pDate), Int32)

其中 pDate 是用户输入的日期及其格式 mm/dd/yyyy 例如#12/24/2014# 这会正确检索 unix 日期。但是在一台特定机器上，输出比所需日期少一秒。 那是转换结果在前一个日期时的 unix 时间戳。 例如，2004 年 12 月 18 日星期六 23:59:59 GMT 当所需结果为
2004 年 12 月 19 日星期日 00:00:00 GMT

Answer 1

是的，这在技术上是可行的。 DateDiff() 使用 Math.Round() 从 TimeSpan.TotalSeconds 生成返回值。像这样的浮点数学很容易受到机器上运行的行为不端代码的影响，这些代码会改变 FPU 控制字。控制字中的两个设置会导致这样的错误，即精度设置和舍入模式。

此类代码可以通过多种方式感染您的程序。通常的麻烦制造者是打印机驱动程序，一些 Hewlett Packard 驱动程序已知有这个错误。或者是一个 shell 扩展，它们会通过 OpenFileDialog 加载到您的进程中。更隐蔽的方式是 DirectX，它可以改变精度设置。众所周知，Microsoft ACE 数据提供程序的某个版本会破坏舍入模式。

到目前为止，解决此问题的最佳方法是重新映像机器。如果机器上没有可用的调试器，则很难找到 DLL。并且它可能导致其他程序以非常难以诊断的方式行为异常。如果您有调试器，This post 有调试提示。

但您可能只是想摆脱这个错误。您可以通过使用此代码避免浮点数学来做到这一点，将其放入模块中：

Public Function UnixTimestamp(ByVal dt As DateTime) As Integer
    Dim span = dt.ToUniversalTime() - New DateTime(1970, 1, 1, 0, 0, 0, 0, DateTimeKind.Utc)
    Return CInt(span.Ticks \ 10000000)
End Function

---

演示此问题的示例程序：

Imports System.Runtime.InteropServices

Module Module1
    Sub Main()
        SetFpuRoundingMode(RoundingMode.Down)  '' or Chop
        Dim lxDate = #1/1/1970#
        Dim pDate = #12/24/2014#
        Dim unix = CType(DateDiff("S", lxDate, pDate), Int32)
        System.Diagnostics.Debug.Assert(unix = 1419379200)
    End Sub

    Enum RoundingMode
        Near
        Down
        Up
        Chop
    End Enum

    Sub SetFpuRoundingMode(mode As RoundingMode)
        _controlfp(mode << 8, &H300)
    End Sub

    <DllImport("msvcrt.dll", CallingConvention:=CallingConvention.Cdecl)> _
    Friend Function _controlfp(bits As Integer, mask As Integer) As Integer
    End Function
End Module

这为您提供了另一种解决方法，您可以使用 SetFpuRoundingMode(RoundingMode.Near) 来恢复 FPU。但是，您必须弄清楚该调用的确切位置。