ghci - 默认混淆

Question

在检查不同整数类型的大小（minBound,maxBound）和“十进制表示的长度”时，我碰巧看到了一些奇怪的行为。

使用 GHCi：

Prelude> :{
Prelude| let mi = minBound
Prelude|     ma = maxBound
Prelude|     le = fromIntegral $ length $ show ma
Prelude|  in [mi,ma,le] :: [Int]
Prelude| :}
[-9223372036854775808,922372036854775807,2]
                                         ^

我最期待的是19。

我的第一个猜测是 maxBound 默认为 () 并因此产生 2，但我不明白这是因为 ma 应该是 Int 通过显式类型注释 (:: [Int]) - 并且通过引用透明性，所有名为 ma 的符号应该是相等的。

如果我将上面的语句放在一个文件中并将其加载到 GHCi 中，我会得到正确的结果。

那么为什么我会得到错误的结果？

Answer 1

令人困惑的是，这仍然是单态性限制（或者更确切地说，在 GHCi 中缺乏单态性限制）。由于 GHCi 没有启用单态限制，因此您对 mi 和 ma 的定义不会像您认为的那样专门化为 Int - 相反，它们保持通用 mi, ma :: Bounded a => a 和 a 变量被实例化两次

• 曾在fromIntegral $ length $ show ma 中作为()（如您所见，这是默认设置）
• 曾在[mi,ma,le] :: [Int] 中作为Int

如果您希望 mi 和 ma 实际上是 Int 类型，请直接注释它们

Prelude> :{
Prelude| let mi, ma :: Int
Prelude|     mi = minBound
Prelude|     ma = maxBound
Prelude|     le = fromIntegral $ length $ show ma
Prelude|  in [mi,ma,le]
Prelude| :}
[-9223372036854775808,9223372036854775807,19]

或者在 GHCi 中手动开启单态限制

Prelude> :set -XMonomorphismRestriction
Prelude> :{
Prelude| let mi = minBound
Prelude|     ma = maxBound
Prelude|     le = fromIntegral $ length $ show ma
Prelude| in [mi,ma,le] :: [Int]
Prelude| :}
[-9223372036854775808,9223372036854775807,19]