用于在代数数据类型之间转换的 Haskell 多态函数

Question

我有两个 haskell 函数，可以在两种代数数据类型之间进行转换。

data Ab = A | B
data Cd = C | D

fromAb :: Ab -> Cd
fromAb A = C
fromAb B = D

toAb :: Cd -> Ab
toAb C = A
toAb D = B

但我想创建一个多态函数，它同时接受代数数据类型并在它们之间进行转换。

foo A = C
foo B = D
foo C = A
foo D = B

但 Haskell 从“foo A = C”推导出函数是

foo :: Ab -> Cd

我尝试将一个类的数据类型实例化为 foo 多态，但没有成功。

class Abcd a
instance Abcd Ab
instance Abcd Cd

foo :: Abcd a => a -> Ab

有什么想法吗？

Answer 1

另一种方法是使用扩展名MultiParamTypeClasses 和FunctionalDependencies：

{-# LANGUAGE FunctionalDependencies #-}
{-# LANGUAGE MultiParamTypeClasses #-}

data Ab = A | B deriving (Show)
data Cd = C | D deriving (Show)

class Convert a b | a -> b where
  convert :: a -> b

instance Convert Ab Cd where
  convert A = C
  convert B = D

instance Convert Cd Ab where
  convert C = A
  convert D = B

演示：

λ> convert A
C
λ> convert B
D
λ> convert C
A
λ> convert D
B

Answer 2

TypeFamilies 这很自然。你定义一个类型级函数

type family Converted a
type instance Converted Ab = Cd
type instance Converted Cd = Ab

那么你的签名就变成了

foo :: a -> Converted a

如果您只是在摆弄类型，那么您已经完成了，但是由于您希望在值级别上有不同的行为（从 C 返回 A 等等），我们实际上需要传播我们的案例跨新类型类的实例：

class Convertable a where
    foo :: a -> Converted a

instance Convertable Ab where
    foo A = C
    foo B = D

instance Convertable Cd where
    foo C = A
    foo D = B

(live demo)

最后，如果使用最近的 GHC，您可以考虑将 Converted 设为封闭类型同义词系列，或者通过在 Convertable 实例声明中移动实例使其“关联”。

Answer 3

好吧，您最后一个代码片段中的签名仍然是错误的。不会是foo :: Abcd a => a -> Ab，因为如果是a ~ Ab，那么函数应该返回Cd，而不是Ab。

有几种不同的方法可以做你想做的事。首先，要认识到您要做的是表达一组共同的行为，而不是基于类型，而是基于两种类型之间的关系。这基本上是多参数类型类的目的（这可能是实现此目的的最简单方法）。

{-# LANGUAGE MultiParamTypeClasses #-}
data Ab = A | B
data Cd = C | D

fromAb :: Ab -> Cd
fromAb A = C
fromAb B = D

toAb :: Cd -> Ab
toAb C = A
toAb D = B

class Iso a b where
  to :: a -> b

instance Iso Ab Cd where
  to = fromAb

instance Iso Cd Ab where
  to = toAb

编辑：请注意，我的答案完全等同于使用类型系列的 jberryman。这就是我所说的“做你想做的事的几种方法”。