【问题标题】:Can I constrain the parametric polymorphic type on type/data constructor in Haskell?我可以在 Haskell 中的类型/数据构造函数上约束参数多态类型吗?
【发布时间】:2016-06-05 04:33:48
【问题描述】:

我有一个参数化类型,我想将其限制为数字类型,更具体地说是Fractional,例如:

data Rating a = (Fractional a) => Score a | Unscored deriving (Show, Eq)

这样 API 的用户可以定义他们可能使用的非整数类型(Float 或 Double?),但我编写的内部 API 代码仍然可以对数字类型执行算术运算。我不希望它是整数,因为我的“内部操作”的结果可能不是整数,我的理解是使用Fractional 会导致更准确的结果。

编译上述(至少在 GHCI 中)会给我以下错误:

    Data constructor `Score' has existential type variables, a context, or a specialised result type
  Score :: forall a. Fractional a => a -> Rating a
  (Use ExistentialQuantification or GADTs to allow this)
In the definition of data constructor `Score'
In the data declaration for `Rating'

这表明我正在做一些我可能不想继续尝试的事情;即我的设计是垃圾。

我想我想在这个 API 中说以下内容:“当你使用 Rating 类型时,它的参数必须是 Fractional 的子类,以便我可以对其执行准确的算术运算”。我怎样才能做到这一点?还是我离题和/或过度设计?

【问题讨论】:

  • 已经在this answer讨论过。
  • 是的,你是对的。谢谢。不过,我仍然喜欢我的问题的 API 设计方面,并且 Twan 在下面的回答与我的其他解决方案一致,即将其限制在功能上,而其他问题未涵盖。

标签: haskell types api-design parametric-polymorphism


【解决方案1】:

您不应该将Fractional 约束放在数据类型上,而应该放在使用它的函数上。所以

data Rating a = Score a | Unscored deriving (Show, Eq)

makeSomeRating :: Fractional a => a -> Rating a
makeSomeRating x = Score (x / 2) -- can use Fractional functions here

doSomethingElseWithRating :: Fractional a => Rating a -> Something

【讨论】:

  • 我想知道这一点。我不这样做的原因是我已经将使用Fractionals 的需要附加到Rating 类型,即如果你不使用Rating Fractional(但使用哪一个取决于用户...)。这有意义吗?不确定它是否会改变你的答案...
  • @atc,这个答案反映了社区对最佳实践的共识。人们已经尝试了很多东西,而这通常是最有效的方式。在某些特殊情况下,GADT 是可行的方法,但这不是其中之一。另外,请注意,这个答案作者在 Haskell 社区中的地位远远超过了他的 SO 声誉分数;-)
  • 我只是想添加更多背景信息,当然不是要争论或暗示 Twan 是错的,只是想表达我的想法是围绕我为什么要尝试做我自己。跨度>
【解决方案2】:

正如错误所说,您可以使用GADTs:

{-# LANGUAGE GADTs, StandaloneDeriving #-}

data Rating a where
    Score :: (Fractional a) => a -> Rating a
    Unscored :: Rating a

deriving instance (Show a) => Show (Rating a)
deriving instance (Eq a) => Eq (Rating a)

-- No need for a context here!
halfScore :: Rating a -> Rating a
halfScore (Score a) = Score (a / 2)
halfScore Unscored = Unscored

StandaloneDeriving 是必需的,因为否则 GHC 无法为 GADT 派生 Show 和 Eq。

【讨论】:

    猜你喜欢
    • 2020-02-26
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2013-08-14
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    相关资源
    最近更新 更多