懒惰的评估 - 空间泄漏

Question

Thinking Functionally with Haskell 提供了以下代码，用于计算 Float 列表的 mean。

mean :: [Float] -> Float
mean [] = 0
mean xs = sum xs / fromIntegral (length xs)

教授。理查德伯德：

现在我们准备好看看 mean 的真正问题是什么：它有空间泄漏。计算mean [1..1000] 将导致列表在求和后扩展并保留在内存中，因为有第二个指针指向它，即在计算其长度时。

如果我正确理解了这段文字，他的意思是，如果在长度计算中没有指向 xs 的指针，那么 xs 内存可能已经被释放在计算 @ 987654327@?

我的困惑是 - 如果 xs 已经在内存中，那么 length 函数不是只会使用已经被占用的相同内存吗？

这里的空间泄漏我不明白。

Answer 1

sum 函数不需要将整个列表保存在内存中；它可以一次查看一个元素，然后在移动到下一个元素时忘记它。

因为默认情况下 Haskell 有惰性求值，如果你有一个创建列表的函数，sum 可以在整个列表都不在内存中的情况下使用它（每次生成函数生成一个新元素时，它会被sum 消费然后释放）。

length 也会发生完全相同的事情。

另一方面，mean 函数将列表提供给sum 和length。所以在sum的求值过程中，我们需要将列表保存在内存中，以便稍后length处理。

[更新]要明确，列表最终将被垃圾收集。问题是它停留的时间比需要的长。在这种简单的情况下，这不是问题，但在对无限流进行操作的更复杂的函数中，这很可能会导致内存泄漏。

Answer 2

其他人已经解释了问题所在。最干净的解决方案可能是使用 Gabriel Gonzalez 的foldl package。具体来说，您需要使用

import qualified Control.Foldl as L
import Control.Foldl (Fold)
import Control.Applicative

meanFold :: Fractional n => Fold n (Maybe n)
meanFold = f <$> L.sum <*> L.genericLength where
  f _ 0 = Nothing
  f s l = Just (s/l)

mean :: (Fractional n, Foldable f) => f n -> Maybe n
mean = L.fold meanFold

Answer 3

如果在length 计算中没有指向xs 的指针，那么在计算sum 之后 可以释放xs 内存？

不，您在这里遗漏了惰性求值的重要方面。没错，length 将使用在 sum 调用期间分配的内存，即我们扩展整个列表的内存。

但这里的重点是根本不需要为整个列表分配内存。如果没有length 计算而只有sum，则内存可能已经在计算sum期间被释放。请注意，[1..1000] 列表仅在被消耗时延迟生成，因此实际上mean [1..1000] 应该在恒定空间中运行。

您可以编写如下函数，以了解如何避免此类空间泄漏：

import Control.Arrow

mean [] = 0
mean xs = uncurry (/) $ foldr (\x -> (x+) *** (1+)) (0, 0) xs

-- or more verbosely
mean xs = let (sum, len) = foldr (\x (s, l) -> (x+s, 1+l)) (0, 0)
          in sum / len

哪个应该只遍历xs一次。然而，Haskell 是该死的懒惰 - 并且仅在评估 sum 时计算第一个元组组件，并且仅在稍后为 len 计算第二个元组组件。我们需要use some more tricks 来实际强制评估：

{-# LANGUAGE BangPatterns #-}
import Data.List

mean [] = 0
mean xs = uncurry (/) $ foldl' (\(!s, !l) x -> (x+s, 1+l)) (0,0) xs

它确实在恒定空间中运行，您可以在 ghci 中使用:set +s 进行确认。

Answer 4

空间泄漏是整个评估的xs 保存在内存中以供length 函数使用。这很浪费，因为我们不会在评估 sum 之后使用列表的实际值，也不需要同时将它们全部存储在内存中，但 Haskell 不知道这一点。

消除空间泄漏的一种方法是每次重新计算列表：

sum [1..1000] / fromIntegral (length [1..1000])

现在应用程序可以立即开始丢弃第一个列表中的值，因为它正在评估 sum，因为它没有在表达式中的其他任何地方引用。

这同样适用于length。它生成的 thunk 可以立即标记为删除，因为没有其他东西可能希望它进一步评估。

编辑：

在Prelude中实现sum：

sum l = sum' l 0
  where
    sum' []     a = a
    sum' (x:xs) a = sum' xs (a+x)