使用 cmd 在文件名中间批量添加一个字符

Question

所以我的文件（主要是文档）的文件名以“YYYYMMDD - 文件的标题”开头 我想将日期格式更改为 YYYY-MM-DD 我想做一个脚本来批量重命名，因为我会时不时地这样做。

我的蝙蝠代码经过 2 天的研究无济于事：

for %%a in ("*.*") do ren *.* ????-??-??*.*
pause

任何帮助或指向我要查看的正确方向都会非常有帮助。谢谢

最终

rem // Loop through all matching files:
for /F "eol=| delims=" %%F in ('
    dir /B /A:-D-H-S "*.*"
') do (
    rem // Store the current file name and extension to variables:
    set "NAME=%%~F"
    rem // Enable delayed expansion to avoid trouble with `!`:
    setlocal EnableDelayedExpansion
    rem // Rename file by applying sub-string expansion:
    ren "!NAME!" "!NAME:~,4!-!NAME:~4,2!-!NAME:~6!!EXT!"
    endlocal
)
pause

Answer 1

您正在使用 for 循环，但没有在正文中使用其元变量 %%a，这没有任何意义。

不幸的是，您不能只使用ren，因为新名称中的每个? 都代表该位置上旧名称的字符。

我会这样做：

rem // First change to the target directory:
cd /D "D:\Target\Dir"
rem // Loop through all matching files:
for /F "eol=| delims=" %%F in ('
    dir /B /A:-D-H-S "*.*" ^| findstr /I "^[1-2][0-9][0-9][0-9][0-1][0-9][0-3][0-9]"
') do (
    rem // Store the current file name and extension to variables:
    set "NAME=%%~nF" & set "EXT=%%~xF"
    rem // Enable delayed expansion to avoid trouble with `!`:
    setlocal EnableDelayedExpansion
    rem // Rename file by applying sub-string expansion:
    ren "!NAME!!EXT!" "!NAME:~,4!-!NAME:~4,2!-!NAME:~6!!EXT!"
    endlocal
)

findstr 在这里用于过滤以八位十进制数字开头的文件名，这些数字可能代表一个日期。如果您不想这样做，只需删除从 ^| findstr 到该行末尾的所有内容。

这里需要Delayed variable expansion，因为您在同一个代码块中写入和读取变量。在固定字符位置拆分原始名称由sub-string expansion完成。

Answer 2

您可以使用此函数将文件重命名为您想要的格式。如果需要，您可以在 FOR 循环中调用此函数。

set old_filename=YYYYMMDD - Title of file.etc
:: Extract only the first 4 characters
SET yyyy=%old_filename:~0,4%
:: Skip 4 characters and then extract the next 2
SET mm=%old_filename:~4,2%
:: Skip 6 characters and then extract the next 2
SET dd=%old_filename:~6,2%
:: Skip 8 characters and then extract everything else
SET everything_else=%old_filename:~8%
:: Rename de old filename to the new
rename "%old_filename%" "%yyyy%-%mm%-%dd%%everything_else%"

Answer 3

Powershell 会更容易做到这一点。使用这个：

@echo off
pushd "The Directory"
powershell -command "& {get-childitem | foreach {$NewName = $_.Name -replace '\d{8}.*', '\d{4}-\d{2}-\d{2}.*'; rename-item -path '.\$_.Name' -newname '$NewName'}}"
popd
goto :eof

Answer 4

右撇子，

也许你应该看看 Powershell 命令。

以下powershell命令用下划线替换当前目录下所有文件的空格：

dir | rename-item -NewName {$_.name -replace " ","_"}

来源：https://www.howtogeek.com/111859/how-to-batch-rename-files-in-windows-4-ways-to-rename-multiple-files/

您可以在此处查看如何修改 Powershell 字符串，例如：https://docs.microsoft.com/en-us/powershell/module/microsoft.powershell.utility/convert-string?view=powershell-5.1