重命名文件脚本的applescript奇怪行为

Question

我编写了这个简单的脚本来更改我桌面上图像文件夹的文件名。该脚本在第一次运行时有效，但是当我使用变量 newName 的不同字符串重新运行它时（相同的字符串会引发错误：文件名已存在）。它只会更改“文件夹的第 x 项”的偶数个名称。 有人可以告诉我这是如何发生的以及如何避免这种特殊行为。我很难弄清楚这一点。 非常感谢您。

tell application "Finder"
    set theFolder to ((path to desktop folder) & "Images") as string as alias
    set myImages to the name of every file of theFolder
    set indexOfFolder to (count items in myImages) as number
    set newName to "whateverName" as string

    repeat with x from 1 to indexOfFolder
        set name of item x of theFolder to newName & x & ".JPG"
    end repeat
end tell

编辑：经过更多测试，问题似乎不会完全指向不变的奇数。有超过 20 个文件，它似乎从 20 切换到不会重命名的偶数。

Answer 1

在我看来，您正在处理文件夹的名称，以及文件夹的字符（文件夹的项目）

请与应该正常工作的这个进行比较：

 tell application "Finder"
    set theFolder to ((path to desktop folder as text) & "Images")
    set myImages to the name of every file of folder theFolder
    set indexOfFolder to (count myImages)

    set newname to "Z picture " as string

    repeat with x from 1 to indexOfFolder
        set name of item x of folder theFolder to newname & x & ".JPG"
    end repeat
 end tell

它仍然不是没有错误，下一个差异是您在将内容收集到myImages 变量时使用文件，但是您处理文件夹的项目，这是两个不同的对象类。我还最终将文件夹设置为最后一个实现中的文件夹，以避免冗余。还请注意我在哪里放置了强制，以及我删除了哪些，因为它们是多余的。

 tell application "Finder"
    set theFolder to folder ((path to desktop folder as text) & "Images")
    set myImages to the name of every file of theFolder
    set indexOfFolder to (count myImages)

    set newname to "Z picture " as string

    repeat with x from 1 to indexOfFolder
        set name of file x of theFolder to newname & x & ".JPG"
    end repeat
 end tell

即使文件更改名称，此版本也应该可以工作，因为文件列表是预先获得的。

tell application "Finder"
    set theFolder to folder ((path to desktop folder as text) & "Images")
    set myImages to every file of theFolder
    set indexOfFolder to (count myImages)

    set newname to "Z picture " as string

    repeat with x from 1 to indexOfFolder
        set name of item x of myImages to newname & x & ".JPG"
    end repeat
  end tell