在单词和粗体选择中查找字符串

Question

上下文

我有一个 Word 文档，我想对其进行检查以确保它符合标准格式。该文档用 1 行项目符号填充。我想解析每一行并检查与单词“Testing”匹配的每个单词，以确保它是粗体。

问题

我能够解析每一行并检查该行是否包含该单词，但不确定如何检查是否只有找到的选择是粗体的。

当前代码

Sub checkWords()

Dim singleLine As Paragraph      'bullet point document so just went by each paragraph
Dim lineText As String
Dim pos As Integer

  For Each singleLine In ActiveDocument.Paragraphs
    pos = InStr(singleLine, "Testing")

    If pos <> 0 Then
        MsgBox ("Testing InStr")
    End If


'PSEUDOCODE
'If singleLine.Range.Font.Bold <> True Then
'   Do This
'End If

Next singleLine

End Sub

Answer 1

您最初的问题说您想“解析每一行并检查与单词“Testing”匹配的每个单词，以确保它是粗体的”。这并不意味着涉及任何决策。允许用户选择更复杂：

Sub Demo()
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "Testing"
    .Replacement.Text = ""
    .Forward = True
    .Format = False
    .Wrap = wdFindStop
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    .Select
    Select Case MsgBox("Bold this instance?", vbYesNoCancel)
      Case vbCancel: Exit Sub
      Case vbNo: .Font.Bold = False
      Case vbYes: .Font.Bold = True
    End Select
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
End Sub

以上内容可让您取消已加粗的内容。要仅处理非粗体内容，您可以使用：

Sub Demo()
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "Testing"
    .Replacement.Text = ""
    .Forward = True
    .Format = True
    .Font.Bold = False
    .Wrap = wdFindStop
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    .Select
    Select Case MsgBox("Bold this instance?", vbYesNoCancel)
      Case vbCancel: Exit Sub
      Case vbYes: .Font.Bold = True
    End Select
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
End Sub

Answer 2

试试这个代码：

Sub checkWords()
   Dim singleLine As Paragraph
   Dim rng As Range
   Dim pos As Integer

   For Each singleLine In ActiveDocument.Paragraphs
      Set rng = singleLine.Range
      pos = InStr(1, rng.Text, "Testing")

      If pos <> 0 Then
         rng.Start = pos
         rng.End = pos + Len("Testing")

         If rng.Font.Bold Then
            MsgBox "This is bold"
         End If
      End If
   Next
End Sub

Answer 3

你让这件事变得比需要的困难得多；一个简单的 Find/Replace 就可以完成这项工作，Find/Replace 宏也是如此：

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Replacement.Font.Bold = True
    .Text = "Testing"
    .Replacement.Text = "^&"
    .Forward = True
    .Format = True
    .Wrap = wdFindContinue
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
  End With
End With
Application.ScreenUpdating = True
End Sub