替换代码行中的特定元素答案

【问题标题】：Replacing a specific element in a line of code替换代码行中的特定元素
【发布时间】：2021-10-16 11:28:06
【问题描述】：

我想用其他元素替换代码中的某些元素。例如：C.Offset(0, 1).Value = 0 到 C.Offset(0, 28).Value = 5 在 VbaEditor 的帮助下，我可以找到我需要的元素的行数和列数。并在 Mid (stringvar, start, [length]) = string 的帮助下替换它们。如何通过行号和列号获取 stringvar？

Sub кс()
Dim book1 As Workbook
Dim VBAEditor As VBIDE.VBE
Dim VBProj As VBIDE.VBProject
Dim VBComp As VBIDE.VBComponent
Dim CodeMod As VBIDE.CodeModule
Dim FindWhat As String
Dim SL As Long ' start line
Dim EL As Long ' end line
Dim SC As Long ' start column
Dim EC As Long ' end column
Dim Found As Boolean

Set VBAEditor = Application.VBE
Set book1 = Workbooks.Open("...")
Set VBProj = book1.VBProject
Set VBComp = VBProj.VBComponents("Module1")
Set CodeMod = VBComp.CodeModule

FindWhat = "C.Offset(0, 1).Value = 0"

      
With CodeMod
    SL = 1
    EL = .CountOfLines
    SC = 1
    EC = 255
    Found = .Find(target:=FindWhat, StartLine:=SL, StartColumn:=SC, _
        EndLine:=EL, EndColumn:=EC, _
        wholeword:=True, MatchCase:=False, patternsearch:=False)
    Do Until Found = False
        MsgBox "Found at: Line: " & CStr(SL) & " Column: " & CStr(SC)
        EL = .CountOfLines
        SC = EC + 1
        EC = 255
        Found = .Find(target:=FindWhat, StartLine:=SL, StartColumn:=SC, _
            EndLine:=EL, EndColumn:=EC, _
            wholeword:=True, MatchCase:=False, patternsearch:=False)
    Loop
End With
book1.Save
book1.Close
End Sub

【问题讨论】：

对我来说，您实际上在问什么并不明显。您能否提供更多详细信息以及您尝试过的方法？
@Tragamor 在 Statement Mid 的帮助下，我想替换我的代码中的一些元素。我可以替换一行代码。我可以在我的代码中找到元素，但我不知道如何将这些元素设置为字符串变量以使用 Mid 语句

标签： excel vba replace find vbe

【解决方案1】：

扫描线条并使用替换。

Option Explicit
Sub KC()
    Dim wb As Workbook
    Dim VBAEditor As VBIDE.VBE
    Dim VBProj As VBIDE.VBProject
    Dim VBComp As VBIDE.VBComponent
    Dim CodeMod As VBIDE.CodeModule
    Dim n As Long, sLine As String, i As Long
    Dim t0 As Single: t0 = Timer
   
    Const OLDCODE = "c.Offset(0, 1).Value = 0"
    Const NEWCODE = "c.Offset(0, 28).Value = 5"

    Set wb = ThisWorkbook
    Set VBProj = wb.VBProject
    Set VBComp = VBProj.VBComponents("Module1")
    Set CodeMod = VBComp.CodeModule
    With CodeMod
        For n = 1 To .CountOfLines
            sLine = .Lines(n, 1)
            If InStr(sLine, OLDCODE) > 0 Then
                 Debug.Print "BEFORE", n, sLine
                 sLine = Replace(sLine, OLDCODE, NEWCODE)
                 Debug.Print "AFTER", n, sLine
                 .ReplaceLine n, sLine
                 i = i + 1
            End If
        Next
    End With
    MsgBox i & " of " & n - 1 & " lines updated", vbInformation, _
           Format(Timer - t0, "0.00") & " seconds"
      
End Sub

【讨论】：