在sql中将超过1个句点替换为1个句点

Question

我有以下代码可以将表格列中的多个句点转换为一个句点。

alter proc replace_characters_1
@COLUMN_NAME varchar(30),
@TABLE_NAME varchar(30)
as 
    declare @SQL varchar(MAX)
    while @COLUMN_NAME like '%..%'
    begin
    set @SQL= 'update [' +@TABLE_NAME+ '] set [' +@COLUMN_NAME+ '] = replace([' +@COLUMN_NAME+ '],''..'',''.'')';
    exec(@SQL)
end

我想一口气将Anna...Amal 更改为Anna.Amal，但循环不起作用。我该怎么办？`

Answer 1

一种可能的方法是使用嵌套的REPLACE()s：

SET ColumnName = REPLACE(REPLACE(REPLACE(ColumnName, '.', '<>'), '><', ''), '<>', '.')

在第一个 REPLACE() 之后，文本中包含句点 (.) 的部分看起来像 <><><>。在第二个REPLACE() 之后，结果只有<>，最后一个REPLACE() 返回单个句点（.）。如果输入文本中存在<和>这两个字符，您可以选择另一对字符。

表：

CREATE TABLE Data (Name varchar(100))
INSERT INTO Data (Name)
VALUES
   ('ANNA..Amal'),
   ('ANNA..Amal.'),
   ('ANNA.Amal.'),
   ('ANNA...........Amal.'),
   ('ANNA.....Amal')

程序：

CREATE PROC replace_characters_1
   @COLUMN_NAME sysname,
   @TABLE_NAME sysname
AS
BEGIN
    DECLARE @SQL nvarchar(MAX)
    DECLARE @RC int

    SET @SQL = 
       N'UPDATE ' + QUOTENAME(@TABLE_NAME) + N' ' +
       N'SET ' + QUOTENAME(@COLUMN_NAME) + N' = ' + 
            N'REPLACE(REPLACE(REPLACE(' + QUOTENAME(@COLUMN_NAME) + ', ''.'', ''<>''), ''><'', ''''), ''<>'', ''.'') ' +
       N'WHERE ' + QUOTENAME(@COLUMN_NAME) + N' LIKE ''%..%'''

    EXEC @RC = sp_executesql @SQL
    RETURN @RC
END 

结果：

EXEC replace_characters_1 N'Name', N'Data'
SELECT * FROM Data

Name
ANNA.Amal
ANNA.Amal.
ANNA.Amal.
ANNA.Amal.
ANNA.Amal

Answer 2

我正在使用 CHARINDEX 和 STUFF 导出结果集

DECLARE @sqlstring Varchar(max) = 'Anna...Amal'
-- Getting first index of .
DECLARE @firstidx INT = CHARINDEX('.',@sqlstring) 
-- Getting last index of .  
Declare @lastidx int = (LEN(@sqlstring) - CHARINDEX('.',REVERSE(@sqlstring))) + 1
-- Stuffing the gap with emptystring
SELECT STUFF(@sqlstring,@firstidx+1,(@lastidx-@firstidx),'') as result

结果

+-----------+
|  result   |
+-----------+
| Anna.Amal |
+-----------+

UPDATE：如果有多个逗号分隔值

    DECLARE @sqlstring Varchar(max) = 'Anna...Amal,Vimal...Mathew'

    SELECT STRING_agg(removedvalues,',') as values
    FROM
    (SELECT STUFF(value, CHARINDEX('.',value)+1
        ,(LEN(value) - CHARINDEX('.',REVERSE(value)) + 1) - CHARINDEX('.',value),'') AS removedvalues
    FROM string_split(@sqlstring,',') ) AS t

+------------------------+
|         Values         |
+------------------------+
| Anna.Amal,Vimal.Mathew |
+------------------------+

Answer 3

请检查 Zhorov 的答案，因为它避免了像这样的多个操作。

---

CREATE PROCEDURE replace_characters_1
    @COLUMN_NAME varchar(30),
    @TABLE_NAME varchar(30)
AS
BEGIN

    DECLARE @SQL NVARCHAR(MAX) = N'
        UPDATE T SET
            ' + QUOTENAME(@COLUMN_NAME) + N' = REPLACE(' + QUOTENAME(@COLUMN_NAME) + N',''..'',''.'')
        FROM
            ' + QUOTENAME(@TABLE_NAME) + N' AS T
        WHERE
            T.' + QUOTENAME(@COLUMN_NAME) + N' LIKE ''%..%'';

        SET @UpdatedRowsOut = @@ROWCOUNT;';

    DECLARE @UpdatedRows INT = 1;

    WHILE @UpdatedRows > 0
    BEGIN

        EXECUTE sp_executesql 
            @SQL,
            N'@UpdatedRowsOut INT OUTPUT',
            @UpdatedRowsOut = @UpdatedRows OUTPUT;

    END

END

Dynamic SQL 现在返回已更新的行数，因此只要该列有 .. 的值，它就会继续运行（请注意，有一个 WHERE 过滤器，你不想每次更新所有行！）。

SQL Server 不是正则表达式的最佳选择，如果您需要使用正则表达式执行不同类型的操作，也许您想考虑使用 CLR 函数。

Answer 4

这是一种减少重复字符的方法。

示例

Declare @YourTable Table ([SomeCol] varchar(50))
Insert Into @YourTable Values 
 ('Anna...Amal')
,('Anna........Amal')
,('Anna.Amal')
,('Anna Amal') 

Select * 
      ,NewVal = replace(replace(replace(SomeCol,'.','†‡'),'‡†',''),'†‡','.')
 from @YourTable

返回

SomeCol             NewVal
Anna...Amal         Anna.Amal
Anna........Amal    Anna.Amal
Anna.Amal           Anna.Amal
Anna Amal           Anna Amal