Windows 服务中的定时器队列

Question

对于 Windows 服务，我需要一个计时器来定期执行某项任务。当然，有很多选项看起来优于定时器（多线程，直接从服务的主线程调用方法），但在这种特殊情况下它们都有其缺点。

但是，出于显而易见的原因，SetTimer() 不能在没有 GUI 的消息队列的情况下工作。我所做的（在 Free Pascal 中）如下：

创建计时器：

MyTimerID := SetTimer(0, 0, 3333, @MyTimerProc);

在服务的主循环中，运行定时器队列：

procedure TMyServiceThread.Execute;
var
  AMessage: TMsg;
begin
  repeat
    // Some calls
    if PeekMessage(AMessage, -1, WM_TIMER, WM_TIMER, PM_REMOVE) then begin
      TranslateMessage(AMessage);
      DispatchMessage(AMessage);
    end;
    // Some more calls
    TerminateEventObject.WaitFor(1000);
  until Terminated;
end;

最后，终止计时器：

KillTimer(0, MyTimerID)

除了 KillTimer 总是返回 False 之外，这按预期工作。

我对您的反馈很感兴趣，但是，如果我的实现是正确的 - 我只是想避免弄乱其他应用程序的消息和其他我不知道的副作用，因为我没有处理消息的经验。

谢谢！

Answer 1

我会选择waitable timer。不需要消息队列。

function WaitableTimerDelayFromMilliseconds(milliseconds: Integer): TLargeInteger;
begin
  Result := 0 - (TLargeInteger(milliseconds) * 10000);
end;

procedure TMyServiceThread.Execute;
var
  TimerInterval: Integer;
  DueTime: TLargeInteger;
  hTimer: THandle;
  Handles: array[0..1] of THandle;
begin
  TimerInterval := 10000; // use whatever interval you need
  DueTime := WaitableTimerDelayFromMilliseconds(TimerInterval);

  hTimer := CreateWaitableTimer(nil, FALSE, nil);
  if hTimer = 0 then RaiseLastOSError;
  try
    if not SetWaitableTimer(hTimer, DueTime, TimerInterval, nil, nil, False) then RaiseLastOSError;
    try
      Handles[0] := TerminateEventObject.Handle;
      Handles[1] := hTimer;

      while not Terminated do
      begin
        case WaitForMultipleObjects(2, PWOHandleArray(@Handles), False, INFINITE) of
          WAIT_FAILED:
            RaiseLastOSError;
          WAIT_OBJECT_0+0:
            Terminate;
          WAIT_OBJECT_0+1:
          begin
            // do your work
          end;
        end;
      end;
    finally
      CancelWaitableTimer(hTimer);
    end;
  finally
    CloseHandle(hTimer);
  end;
end;

更新：或者，正如 David Heffernan 所建议的，您可以自己等待终止事件：

procedure TMyServiceThread.Execute;
var
  TimerInterval: Integer;
begin
  TimerInterval := 10000; // use whatever interval you need

  while not Terminated do
  begin
    case TerminateEventObject.WaitFor(TimerInterval) of
      wrSignaled:
        Terminate;
      wrTimeout:
      begin
        // do your work
      end;
      wrError:
        RaiseLastOSError;
    end;
  end;
end;

Answer 2

正如 cmets 中所讨论的，您可能根本不需要计时器。您可以简单地使用等待事件的超时来创建常规脉冲：

while not Terminated do
begin
  case TerminateEventObject.WaitFor(Interval) of
  wrSignaled:
    break;
  wrTimeout:
    // your periodic work goes here
  wrError:
    RaiseLastOSError;
  end;
end;

脉冲周期将是间隔加上完成工作所需的时间。如果您需要一个特定的时间间隔，并且这项工作需要大量时间，那么 Remy 建议的可等待计时器就是您要做的事情。

不惜一切代价，您真正不想做的是使用基于消息循环的计时器。这不适合服务。