如何检查一个概念是否是它自己的孩子

Question

我正在链接多个本体模型，所有模型都具有一个共享的基础模型，其中定义了所有类和关系。每个模型都是由不同的开发人员创建的，并且具有重叠的域。我需要检查以确保没有进行循环引用。例如 A 有一个孩子 B，B 有 C，然后，偶然地，C 有孩子 A。在我们的软件中可以做到这一点而不会出错。我已经编写了捕获 A 有子 B 并且同时 B 有子 A 的 SPARQL，但我不确定如何解决第一个问题。谢谢。

编辑： 我需要检测链接模型中的任何递归。因此，当链接多个本体时，在这个聚合模型中，可能会发生以下情况：

A
 \
  B
   \
    C
     \
      A

如果我有一个无限递归循环，这显然会在最终应用程序中产生问题。如果我最初不清楚，我很抱歉。

Answer 1

SPARQL 1.1 Property Paths 似乎是显而易见的解决方案，如果您知道涉及哪些谓词。例如，对于类和子类，我会做类似 --

SELECT DISTINCT ?selfParent
WHERE 
  { ?selfParent rdfs:subClassOf+ ?selfParent }

注意： 在撰写本文时，Virtuoso 的查询优化器中存在一个错误，该错误会阻止执行上述 OneOrMorePath（+ 运算符）查询.您可以使用等效的 SequencePath 或 One 后跟 ZeroOrMorePath（* 运算符）来解决此问题：

SELECT DISTINCT ?selfParent
在哪里
  { ?selfParent rdfs:subClassOf /
                rdfs:subClassOf* ?selfParent }

您还可以执行（和/或UNION）多个不同深度的SequencePath 查询，如下所示。使用此方法，您可以在每个级别指定不同的谓词。

SELECT DISTINCT ?selfParent
WHERE 
  { { ?selfParent rdfs:subClassOf ?selfParent }
    UNION
    { ?selfParent rdfs:subClassOf / 
                  rdfs:subClassOf ?selfParent }
    UNION
    { ?selfParent rdfs:subClassOf / 
                  rdfs:subClassOf / 
                  rdfs:subClassOf ?selfParent }
  }

如果您有多个可能出现在某个级别的谓词，您可以将rdfs:subClassOf 的实例更改为( rdfs:subClassOf | ex:myPredicate )，如--

SELECT DISTINCT ?selfParent
WHERE 
  { { ?selfParent rdfs:subClassOf ?selfParent }
    UNION
    { ?selfParent rdfs:subClassOf / 
                  rdfs:subClassOf ?selfParent }
    UNION
    { ?selfParent rdfs:subClassOf / 
                  ( rdfs:subClassOf | ex:myPredicate ) / 
                  rdfs:subClassOf ?selfParent }
  }

这些结果不会向您显示完整的路径，但我想您可以从这里计算出来。