Delphi 在自己的包中安装组件

【问题标题】：Delphi installing components in their own packageDelphi 在自己的包中安装组件
【发布时间】：2016-08-22 11:58:01
【问题描述】：

我开发了两个单元文件 (.pas)，我有 2 个不同的组件 第一个是 MyPCButton，第二个是 MyPanel

MyPCButton.pas 使用 MyPanel.pas

问题是当我尝试将它们放在单独的包中时，当我安装使用 MyPanel.pas 的 MyPCButton 组件时，该包将它们都安装在同一个包中，如果我先安装 MyPanel.pas，然后再安装 MyPCButton包拒绝安装并说“无法在包输出目录中为 MyPanel.bpl 创建输出文件”

我已将 MyPanel 放在接口部分，我已将其放在实现部分，但我仍然遇到相同的错误，

我想做的是将它们单独安装在自己的包中

MyPCButton.pas：

unit MyPCButton;

interface

uses
 Winapi.Windows,Winapi.Messages,System.SysUtils, System.Classes, Vcl.Controls, Vcl.ExtCtrls,
 Vcl.Imaging.PngImage,Vcl.Graphics,Types,cxGraphics;


type
  TMyPCButton=class (TCustomControl)
  private
    FCaption:TCaption;
    FIcon:TPngImage;
    FIconIndex:integer;
    FIconList:TcxImageList;
    FIconWidth:integer;
    FIconLeftMargin,FIconRightMargin:integer;
    FCloseIconList:TcxImageList;
    FCloseIconWidth:integer;
    FCloseIconLeftMargin,FCloseIconRightMargin:integer;
    FFont:TFont;
    FColorDefault,FColorDefaultFont:TColor;
    FColorHover,FColorHoverFont:TColor;
    FColorActive,FColorActiveFont:TColor;
    FCaptionWidth:integer;
    FMaximumCaptionWidth:integer;
    FState:Byte;
    FCurCloseIconState:integer;
    FActive: Boolean;

    FBuffer: TBitmap;
    R3:TRect;
    FOnClick,FOnCloseClick: TNotifyEvent;
    FOnActivate,FOnDeactivate:TNotifyEvent;

    FFocused:Boolean;
    FGroupNo: integer;
    procedure SetIconIndex(const Value:Integer);
    procedure SetIconList(const Value:TcxImageList);

    procedure SetCaption(const Value: TCaption);
    procedure SetCloseIconList(const Value: TcxImageList);

    procedure SetAutoSize;

    procedure WndProc(var Message: TMessage); override;
    procedure MouseDown(Button: TMouseButton; Shift: TShiftState; X: Integer; Y: Integer); override;
    procedure MouseMove(Shift: TShiftState; X: Integer; Y: Integer); override;
    procedure SetActive(const Value: Boolean);
    procedure SwapBuffers;
    procedure CheckGroupNo;
  protected
    procedure Paint; override;
    property Canvas;
    procedure DoEnter; override;
    procedure DoExit; override;
    procedure KeyDown(Sender: TObject; var Key: Word;Shift: TShiftState);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    function GetTotalWidth:integer;
    function GetLeftSpace:integer;
    function GetRightSpace:integer;
    procedure SetPositionInPanel;
    procedure SetActiveAfterClose;
  published
    property Caption:TCaption read FCaption write SetCaption;
    property IconIndex:integer Read FIconIndex write SetIconIndex;
    property IconList:TcxImageList Read FIconList write SetIconList;
    property CloseIconList:TcxImageList Read FCloseIconList write SetCloseIconList;
    property Active:Boolean read FActive write SetActive;
    property OnClick: TNotifyEvent read FOnClick write FOnClick;
    property OnCloseClick: TNotifyEvent read FOnCloseClick write FOnCloseClick;
    property OnActivate: TNotifyEvent read FOnActivate write FOnActivate;
    property OnDeActivate: TNotifyEvent read FOnDeactivate write FOnDeactivate;
    property GroupNo:integer read FGroupNo write FGroupNo;
    property TabStop;
    property Align;
end;

procedure Register;

implementation
uses Math,pvalues,pfunctions,MyPanel;

function IsIntInInterval(x, xmin, xmax: integer): boolean; inline;
begin
  IsIntInInterval := (xmin <= x) and (x <= xmax);
end;

function PointInRect(const Point: TPoint; const Rect: TRect): boolean; inline;
begin
  PointInRect := IsIntInInterval(Point.X, Rect.Left, Rect.Right) and
                 IsIntInInterval(Point.Y, Rect.Top, Rect.Bottom);
end;

procedure Register;
begin
  RegisterComponents('MyComponents', [TMyPCButton]);
end;

procedure TMyPCButton.CheckGroupNo;
var
i:integer;
begin
  for i:=0 to Parent.ControlCount-1 do
    begin
      if (Parent.Controls[i] is TMyPCButton) then
        begin
          if ((Parent.Controls[i] as TMyPCButton).Active) and
             ((Parent.Controls[i] as TMyPCButton).Name<>Self.Name) and
             ((Parent.Controls[i] as TMyPCButton).GroupNo=Self.GroupNo)
             then
              (Parent.Controls[i] as TMyPCButton).Active:=False;
        end;
    end;
end;

constructor TMyPCButton.Create(AOwner: TComponent);
begin
  inherited;
  if _V_RegValuesInitated=false then
    _P_RegValuesInitate;

  FFocused:=false;
  FBuffer := TBitmap.Create;
  Height:=30;
  Width:=50;

  FFont:=TFont.Create;
  FFont.Assign(R_BtnTB.VFont);
  FBuffer.Canvas.Font.Assign(FFont);

  FState:=0;
  FCurCloseIconState:=-1;
  FIconIndex:=-1;
  FIconWidth:=16;
  FIconLeftMargin:=5;
  FIconRightMargin:=5;

  FCloseIconWidth:=17;
  FCloseIconLeftMargin:=16;
  FCloseIconRightMargin:=6;
  FCaptionWidth:=0;
  FMaximumCaptionWidth:=160;

  OnKeyDown:=KeyDown;
end;

destructor TMyPCButton.Destroy;
begin
  inherited;
  FreeAndNil(FIcon);
  FreeAndNil(FBuffer);
end;

procedure TMyPCButton.DoEnter;
begin
  inherited;
  if FActive=false then
    FState:=1;
  FFocused:=true;
  paint;
end;

procedure TMyPCButton.DoExit;
begin
  inherited;
  if FActive=false then
    FState:=0
  else
    FState:=2;
  FFocused:=false;
  paint;
end;

function TMyPCButton.GetLeftSpace: integer;
begin
  Result:=Parent.Left;
end;

function TMyPCButton.GetRightSpace: integer;
begin
  Result:=GetTotalWidth-Parent.Width;
end;

function TMyPCButton.GetTotalWidth: integer;
begin
  Result:=Self.Left+Self.Width;
end;

procedure TMyPCButton.SetPositionInPanel;
var
TotalWidth,LeftSpace,RightSpace:integer;
begin
  if (Owner is TMyPanel) then
    begin
    if (Owner as TMyPanel).Parent is TMyPanel then
      begin
        LeftSpace:=GetLeftSpace;
        if LeftSpace<0 then
          LeftSpace:=LeftSpace*-1;
        RightSpace:=GetRightSpace;
        TotalWidth:=GetTotalWidth;
        if (TotalWidth-LeftSpace)<Self.Width then
          Parent.Left:=Parent.Left+(((TotalWidth-LeftSpace)-Self.Width)*-1)
        else
        if TotalWidth-LeftSpace>(Parent).Parent.Width then
          begin
            Parent.Left:=Parent.Left-(TotalWidth-LeftSpace-(Parent).Parent.Width);
          end;
      end;
    end;
end;

procedure TMyPCButton.SetActiveAfterClose;
var
VControlCount,VPosition:integer;
begin
  if (Parent is TMyPanel) then
    begin
      VControlCount:=Parent.ControlCount;
      if VControlCount>1 then
        begin
          for VPosition:=0 to VControlCount-1 do
            begin
              if (Parent.Controls[VPosition] as TMyPCButton).Name=Self.Name then
                break;
            end;
          if VPosition+1=Parent.ControlCount then
            (Parent.Controls[VPosition-1] as TMyPCButton).Active:=true
          else
            (Parent.Controls[VPosition+1] as TMyPCButton).Active:=true;
        end;
    end;
end;

procedure TMyPCButton.KeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if FActive=false then
    SetActive(True);
  if (Key=13) and (Assigned(FOnClick)) then FOnClick(Self);
  paint;
end;

procedure TMyPCButton.MouseDown(Button: TMouseButton; Shift: TShiftState; X,
  Y: Integer);
var
SelfWidth:integer;
begin
  inherited;
  if (FActive=false) and PointInRect(point(X,Y),R3)=false then
    begin
      FState:=2;
      SetActive(True);
      paint;
    end;
  if PointInRect(point(X,Y),R3) then
    begin
      if (Assigned(FOnCloseClick)) then FOnCloseClick(Self);
      SelfWidth:=Self.Width;
      Width:=0;
      Parent.Width:=Parent.Width-SelfWidth;
      if FActive then
        SetActiveAfterClose;
      Self.Destroy;
    end
  else
    begin
      if (Assigned(FOnClick)) then FOnClick(Self);
    end;
end;

procedure TMyPCButton.MouseMove(Shift: TShiftState; X, Y: Integer);
begin
  inherited;
  if PointInRect(point(X,Y),R3)=false then
    begin
      if FState-1<>FCurCloseIconState then
        begin
          FCurCloseIconState:=FState-1;
          paint;
        end;
    end
  else
    begin
      if FState+1<>FCurCloseIconState then
        begin
          FCurCloseIconState:=FState+1;
          paint;
        end;
    end;
end;

procedure TMyPCButton.Paint;
var
R2,R4:TRect;
ColorBackground,ColorFont:TColor;
begin
  inherited;
  if FBuffer.Canvas.Font.Name<>R_BtnTB.VFont.Name then
    begin
      FBuffer.Canvas.Font.Name:=R_BtnTB.VFont.Name;
    end;
  if FBuffer.Canvas.Font.Size<>R_BtnTB.VFont.Size then
    begin
      FBuffer.Canvas.Font.Size:=R_BtnTB.VFont.Size;
    end;
  if FBuffer.Canvas.Font.Quality<>R_BtnTB.VFont.Quality then
    begin
      FBuffer.Canvas.Font.Quality:=R_BtnTB.VFont.Quality;
    end;

  FBuffer.SetSize(Width,Height);

  if FState=0 then
    begin
      ColorBackground:=R_BtnTB.DefaultColor;
      ColorFont:=R_BtnTB.DefaultFontColor
    end;
  if FState=1 then
    begin
      ColorBackground:=R_BtnTB.HoverColor;
      ColorFont:=R_BtnTB.HoverFontColor
    end;
  if FState=2 then
    begin
     ColorBackground:=R_BtnTB.ActiveColor;
     ColorFont:=R_BtnTB.ActiveFontColor
    end;

  FBuffer.Canvas.Brush.Color:=ColorBackground;
  FBuffer.Canvas.Font.Color:=ColorFont;
  FBuffer.Canvas.FillRect(ClientRect);

  if ((Assigned(FIconList)) and (FIconIndex>-1)) then
    begin
      FIconList.Draw(FBuffer.Canvas,FIconLeftMargin,(ClientHeight div 2)-(FIconList.Height div 2),FIconIndex);
    end;
  R2.Top:=(ClientHeight div 2)-(FBuffer.Canvas.TextHeight(FCaption) div 2);
  R2.Height:=ClientHeight;
  R2.Left:=FIconLeftMargin+FIconWidth+FIconRightMargin;
  R2.Width:=FCaptionWidth;
  DrawText(FBuffer.Canvas.Handle, PChar(FCaption), -1, R2,DT_LEFT);

  if Assigned(FCloseIconList) then
    begin
      R3.Top:=0;
      R3.Left:=ClientWidth-FCloseIconWidth;
      R3.Height:=ClientHeight;
      R3.Width:=FCloseIconWidth;
      FCloseIconList.Draw(FBuffer.Canvas,R3.Left+(FCloseIconList.Width div 2),(R3.Height div 2)-(FCloseIconList.Height div 2),FCurCloseIconState);
    end;

  if FFocused then
    begin
      R4.Top:=1;
      R4.Left:=1;
      R4.Width:=ClientWidth-2;
      R4.Height:=ClientHeight-2;
      DrawFocusRect(FBuffer.Canvas.Handle,R4);
    end;

  SwapBuffers;
end;

procedure TMyPCButton.SetActive(const Value: Boolean);
var
MyPoint:TPoint;
begin
  if FActive<>Value then
    begin
      FActive := Value;
      if FActive then
        begin
          CheckGroupNo;
          FState:=2;
          SetPositionInPanel;
          if Assigned(FOnActivate) then FOnActivate(Self);
        end
      else
        begin
          MyPoint := ScreenToClient(Mouse.CursorPos);
          if PtInRect(ClientRect, MyPoint) then
            FState:=1
          else
            FState:=0;
          if Assigned(FOnDeactivate) then FOnDeactivate(Self);
        end;
      paint;
    end;
end;

procedure TMyPCButton.SetAutoSize;
begin
  FCaptionWidth:=FBuffer.Canvas.TextWidth(FCaption);
  if FCaptionWidth>160 then
    FCaptionWidth:=FMaximumCaptionWidth;
  Width:=FIconLeftMargin+FIconWidth+FIconRightMargin+FCaptionWidth+FCloseIconLeftMargin+FCloseIconWidth-12+FCloseIconRightMargin;
end;

procedure TMyPCButton.SetCaption(const Value: TCaption);
begin
  inherited;
    FCaption := Value;
    SetAutoSize;
    paint;
end;

procedure TMyPCButton.SetCloseIconList(const Value: TcxImageList);
begin
   FCloseIconList := Value;
   paint;
end;

procedure TMyPCButton.SetIconIndex(const Value: Integer);
begin
  FIconIndex:=Value;
  paint;
end;

procedure TMyPCButton.SetIconList(const Value: TcxImageList);
begin
  FIconList:=Value;
  paint;
end;

procedure TMyPCButton.WndProc(var Message: TMessage);
begin
  inherited;
  case Message.Msg of
    CM_MOUSEENTER:
      begin
        if FActive=False then
          begin
            FState:=1;
            Paint;
          end;
      end;
    CM_MOUSELEAVE:
      begin
        if FActive=False then
          begin
            FState:=0;
            FCurCloseIconState:=-1;
            Paint;
          end
        else
          begin
            FState:=2;
            FCurCloseIconState:=-1;
            Paint;
          end;
      end;
    WM_ERASEBKGND:
      Message.Result := 1;
  end;
end;

procedure TMyPCButton.SwapBuffers;
begin
  BitBlt(Canvas.Handle, 0, 0, Width, Height, FBuffer.Canvas.Handle, 0, 0, SRCCOPY);
end;

end.

MyPanel.pas

unit MyPanel;

interface

uses
  System.SysUtils, System.Classes, Vcl.Controls, Vcl.ExtCtrls;

type
  TMyPanel = class(TPanel)
  private
    { Private declarations }
  protected
    { Protected declarations }
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    { Published declarations }
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('MyComponents', [TMyPanel]);
end;

constructor TMyPanel.Create(AOwner: TComponent);
begin
  inherited;
end;

destructor TMyPanel.Destroy;
begin
  inherited;
end;

end.

【问题讨论】：

    标签： delphi components packages


    【解决方案1】：

    您尝试做的事情并没有什么特别之处，但您的实现以及您描述将pas 文件安装到包中的方式表明您可能不清楚如何去做。

    首先，将组件和 IDE 注册组合在同一个包中一直被认为是不好的做法。

    您应该在仅运行时包（或多个包）中实现您的组件。然后，您就有了一个 Design-Time 包，它的 requires 列表中包含相应的 Runtime 包。

    Design-Time Package 还包含（通常）一个单元，该单元使用包含您的组件的单元并实现 Register 功能。

    然后您将 Design-Time Package 安装到 IDE 中，IDE 将根据需要加载 Runtime Packages 以注册组件。

    在这种整体方法中，您仍然可以选择多种方式来组织您的包。

    您可以为每个控件使用单独的运行时包，并使用单独的设计时包来单独安装每个控件，但听起来您的包之间会有很多依赖关系，这些依赖关系很快就会成为问题，无法按顺序解开和创建依赖关系在其中构建和安装包。

    在您的情况下，由于您的两个组件相互依赖，因此将这些组件保存在一个运行时包中并有一个 single 设计时包来安装所有组件听起来最有意义该运行时包中的组件。

    如果您真的想要，您仍然可以使用单独的设计时包来从单个运行时包中单独安装每个控件，但在您的情况下，我真的看不出这样做有什么好处（除非您的问题中没有明显的其他复杂情况或考虑）。

    【讨论】：

    • 感谢 deltics 关于运行时和设计时包的信息并指出我的错误，我对组件还是很陌生，我必须研究设计时和运行时包，我有很多东西要学，唯一的原因是我想把它们放在不同的包中我不希望一个包在我添加新的单元文件后编译其中的所有单元文件，关于依赖项（稍后）我希望能够将我的控件与表单上的标准控件分开，所以就是为什么我想创建例如我的面板作为某些（我的）控件的容器，它不是必需的，但总是同样的问题“如果”
    • 构建一个包非常快（就像所有编译都在 Delphi 中:)）所以我不会太担心需要重新编译一个包。通过将组件分成完全独立的包，您可能会解决 感知 问题，但可能会遇到大量相互依赖的包的更大问题。如果您需要重新编译您的面板包，那么您可能需要重新编译依赖它的所有其他包（如果接口发生更改）。就像所有组件都在一个包中一样，您只需要编译那个。但最终取决于你。 :)
    • :) 你是对的，为什么我还要担心构建过程？我认为当你指出正确的方法是将它们收集在一个包中，并避免以后可能发生的与单个包相关的其他问题，谢谢你的警告
    【解决方案2】：

    这是我的错

    我更改了默认的 dcp 输出目录，显然我必须在库路径中添加新路径，所以现在我可以将 .pas 文件放入/安装到他们自己的包中

    【讨论】：

      猜你喜欢
      • 1970-01-01
      • 2022-01-22
      • 2011-05-03
      • 2017-09-30
      • 1970-01-01
      • 2012-09-21
      • 1970-01-01
      • 2012-05-15
      • 2013-04-11
      相关资源
      最近更新 更多
      热门标签
      Java Python linux javascript Mysql C# Docker 算法 前端 SpringBoot Redis Vue spring 设计模式 .net core .net kubernetes c++ 数据库 数据结构 大数据 js 机器学习 微服务 Android Go 程序员 面试 JVM ASP.net core 云原生 人工智能 后端 PHP git CSS golang k8s Nginx Django mybatis 深度学习 多线程 React 架构 devops 爬虫 云计算 Spring Boot LeetCode