如何在 Delphi 的 TFrame 上模拟 OnDestroy 事件？

Question

如何在 Delphi 中为 TFrame 模拟 OnDestroy 事件？

---

我在我的框架中添加了 constructor 和 destructor，认为这就是 TForm 所做的：

TframeEditCustomer = class(TFrame)
...
public
   constructor Create(AOwner: TComponent); override;
   destructor Destroy; override;
   ...
end;

constructor TframeEditCustomer.Create(AOwner: TComponent)
begin
    inherited Create(AOwner);

    //allocate stuff
end;

destructor TframeEditCustomer.Destroy;
begin
   //cleanup stuff

   inherited Destroy;
end;

问题在于，当我的析构函数运行时，框架上的控件已被销毁并且不再有效。

原因在于包含表单的析构函数，它用于触发OnDestroy 事件：

destructor TCustomForm.Destroy;
begin
   ...
   if OldCreateOrder then DoDestroy; //-->fires Form's OnDestroy event; while controls are still valid
   ...
   if HandleAllocated then DestroyWindowHandle; //-->destroys all controls on the form, and child frames
   ...
   inherited Destroy; //--> calls destructor of my frame
   ...
end;

当窗体的析构函数运行时，我的框架对象的析构函数被调用。问题在于为时已晚。窗体调用DestroyWindowHandle，它要求Windows 销毁窗体的窗口句柄。这会递归地破坏所有子窗口 - 包括我框架上的那些。

所以当我的框架的destructor 运行时，我尝试访问不再处于有效状态的控件。

---

如何在 Delphi 中为 TFrame 模拟 OnDestroy 事件？

另见

• Simulating OnCreate and OnDestroy for a Frame?
• How to Implement the OnCreate event for a Delphi TFrame object
• Embargadero QC#1767: TFrame misses OnCreate, OnDestroy, OnShow

Answer 1

您需要添加一个 WM_DESTROY 处理程序并检查 ComponentState 中的 csDestroying，以便它仅在实际销毁时被捕获，而不是在重新创建句柄时被捕获。

type
  TCpFrame = class(TFrame)
  private
    FOnDestroy: TNotifyEvent;
    procedure WMDestroy(var Msg: TWMDestroy); message WM_DESTROY;
  published
    property OnDestroy: TNotifyEvent read FOnDestroy write FOnDestroy;
  end;

procedure TCpFrame.WMDestroy(var Msg: TWMDestroy);
begin
  if (csDestroying in ComponentState) and Assigned(FOnDestroy) then
    FOnDestroy(Self);
  inherited; 
end;

只有当框架的窗口句柄已经被创建时才会起作用。没有另一个很好的挂钩点，所以如果你想确保它总是被调用，你需要在 WMDestroy 中设置一个标志，如果没有被命中则回退到在析构函数中调用它。

窗口句柄本身都在 WM_NCDESTROY 中被清除，在所有后代 WM_DESTROY 消息返回后调用，因此此时窗体及其所有子句柄应该仍然有效（忽略在表单的 OnDestroy)。

Answer 2

听起来更像OnClose 而不是OnDestroy。

无论如何，我只是从一个基本祖先继承了我的所有框架和窗体，然后窗体的 onclose 调用组件层次结构中的所有框架。

Answer 3

（这只是一个想法，但我现在没有时间构建概念证明，但我还是会分享它：）

如果 Windows 句柄有问题，您应该检查是否能够附加 Windows 的事件回调指针，当框架的 Windows 句柄不再存在时，该指针会被调用。也许有像RegisterWaitForSingleObject这样的函数

Answer 4

另一种选择是覆盖AfterConstruction 和BeforeDestruction

类似这样的：

  TMyFrame = class(TFrame)
  private
    FOnCreate: TNotifyEvent;
    FOnDestroy: TNotifyEvent;
  protected
    procedure DoCreate; virtual;
    procedure DoDestroy; virtual;
  public
    procedure AfterConstruction; override;
    procedure BeforeDestruction; override;
    property OnCreate: TNotifyEvent read FOnCreate write FOnCreate;
    property OnDestroy: TNotifyEvent read FOnDestroy write FOnDestroy;
  end;

  implementation

  procedure TMyFrame.AfterConstruction;
  begin
    inherited;
    DoCreate;
  end;

  procedure TMyFrame.BeforeDestruction;
  begin
    inherited;
    DoDestroy;
  end;

  procedure TMyFrame.DoCreate;
  begin
    if Assigned(FOnCreate) then
      FOnCreate(Self);
  end;

  procedure TMyFrame.DoDestroy;
  begin
    if Assigned(FOnDestroy) then
      FOnDestroy(Self);
  end;