如何编辑数据集？

Question

短版

我怎么称呼：

dataset1.FieldByName(fieldName).AsString := 'Something';

它工作了吗？

加长版

我有一个DataSet：

var
    ds: TDataSet;

    ds := GetSomeSortOfDataSetFromSomewhere();

此数据集将被导出（例如导出到 Excel、cSV、TSV、Markdown、HTML、XML）：

ExportDataSet(ds);

并且导出将包含所有列和所有行：

Username	Fullname
ian	IAN BOYD
MartynA	MARTIN
ngal	NASREDDINE GALFOUT
uewr	UWE RAABE

现在我想修改每一行的Fullname 字段在内存中，然后再用它做其他事情（即它永远不会回到数据库中，我不知道它来自哪里from ，它可能不是来自数据库）：

while not ds.EOF do
begin
    ds.FieldByName('Fullname').AsString := FormatNamePrettyLike(ds.FieldByName('Fullname').AsString;
    ds.Next;
end;

尝试修改字段会出现异常：

Dataset not in edit or insert mode

解决方案是将数据集克隆到内存中TClientDataset：

///<summary>Clones a dataset into a TClientDataSet; which is an editable in-memory DataSet.</summary>
function CloneDataSet(dsSource: TDataSet): TDataSet; //TDataSet > TCustomClientDataSet > TClientDataSet
var
    tempProvider: TDataSetProvider;
    data: OleVariant;
    ds: TClientDataSet;
begin
    tempProvider := TDataSetProvider.Create(nil);
    try
        tempProvider.DataSet := dsSource;
        data := tempProvider.Data;
    finally
        tempProvider.Free;
    end;

    ds := TClientDataSet.Create(nil);
    ds.Data := data;

    Result := ds;
end;

这给出了更大的代码：

var
   ds: TDataset;
   dsEditable: TDataSet;

   ds := GetDataSomeOfSomeSortFromSomewhere();

   //Clone to dataset to an in-memory dataset so we can modify it.
   dsEditable := CloneDataSet(ds);
   ds.Free;
   ds := edEditable;

   while not ds.EOF do
   begin
       ds.FieldByName('Fullname').AsString := FormatNamePrettyLike(ds.FieldByName('Fullname').AsString;
       ds.Next;
    end;

但这给出了错误：

Dataset not in edit or insert mode

解决办法是put the dataset in edit mode:

//The in-memory ClientDataSet won't be editable until you mark it editable.
ds.Edit; 

 

///<summary>Clones a dataset into a TClientDataSet; which is an editable in-memory DataSet.</summary>
function CloneDataSet(dsSource: TDataSet): TDataSet; //TDataSet > TCustomClientDataSet > TClientDataSet
var
    tempProvider: TDataSetProvider;
    data: OleVariant;
    ds: TClientDataSet;
begin
    tempProvider := TDataSetProvider.Create(nil);
    try
        tempProvider.DataSet := dsSource;
        data := tempProvider.Data;
    finally
        tempProvider.Free;
    end;

    ds := TClientDataSet.Create(nil);
    ds.Data := data;

    //The in-memory ClientDataSet won't be editable until you mark it editable.
    ds.Edit;

    Result := ds;
end;

现在重复练习会出现错误：

字段Fullname不能修改。

解决办法是set Field.ReadOnly to false:

//Even after marking the in-memory data-set as editable, you still can't edit it 
//until you mark all fields as editable.
for i := 0 to ds.FieldCount-1 do
   ds.Fields[i].ReadOnly := False;

 

///<summary>Clones a dataset into a TClientDataSet; which is an editable in-memory DataSet.</summary>
function CloneDataSet(dsSource: TDataSet): TDataSet; //TDataSet > TCustomClientDataSet > TClientDataSet
var
    tempProvider: TDataSetProvider;
    data: OleVariant;
    ds: TClientDataSet;
begin
    tempProvider := TDataSetProvider.Create(nil);
    try
        tempProvider.DataSet := dsSource;
        data := tempProvider.Data;
    finally
        tempProvider.Free;
    end;

    ds := TClientDataSet.Create(nil);
    ds.Data := data;

    //The in-memory ClientDataSet won't be editable until you mark it editable.
    ds.Edit;

    //Even after marking the in-memory data-set as editable, you still can't edit it 
    //until you mark all fields as editable.
    for i := 0 to ds.FieldCount-1 do
        ds.Fields[i].ReadOnly := False;

    Result := ds;
end;

重复练习会出现错误：

试图修改只读字段。

所以我放弃了。如何编辑数据集字段？

克隆的内存中的TCustomClientDataSet 内容都在那里；我只是想在客户端上编辑它们以供显示。

奖金聊天

显然我不能向数据集添加新列：

Username	Fullname	PrettyFullname
ian	IAN BOYD	Ian Boyd
MartynA	MARTIN	Martin
ngal	NASREDDINE GALFOUT	Nasreddine Galfout
uewr	UWE RAABE	Uwe Raabe

显然我无法将事件处理程序附加到数据集：

• 因为当数据集传递给链中的下一个人（例如线程）时，该数据处理程序将无效，并释放原始表单
• 这也不是我要问的；这是关于修改数据集的内容
• 值的更新会影响其他系统（例如数据库、Web 服务等）。我希望更改完成一次，然后进入数据集

Answer 1

假设我实际上正确理解了您的问题，归结为将 FullName 的字段内容更改为一些格式化的字符串以供显示。

因此，由于您不想更改实际的字段内容，因此最好在字段 OnGetText 事件中执行此操作。适合您的任务的事件处理程序可能如下所示：

procedure TMyClass.MakeFullNamePrettyGetText(Sender: TField; var Text: string; DisplayText: Boolean);
begin
  Text := FormatNamePrettyLike(Sender.AsString);
end;

现在您必须将该事件处理程序连接到该字段。当您使用动态字段时，每次打开数据集后都必须这样做：

qry.FieldByName('Fullname').OnGetText := MakeFullNamePrettyGetText;

只要这发生在声明事件的类之外，您就需要在事件名称前加上 TMyClass 的类实例（或任何您可以称呼它的名称）。

Answer 2

下面是一个完全独立的从 Sql Server 编辑数据的示例 使用 ADO + TClientDataSet。所有组件都简单地从调色板中删除 到表单上，然后在SetUp 过程中的代码中设置所有必要的属性。

在每一步，我都尝试使用最简单的代码来完成这项工作，以免混淆 CDS + TDataSetProvider 如何编辑数据的优雅简单。请参阅 Provider.Pas 中的 TSqlResolver.GenUpdateSql 方法以了解如何 它为 DSP 生成必要的 Sql UPDATE 语句以发出更新 服务器表中的数据。这些通过特殊类型发送到服务器 DSP 用于在其 CDS 和源数据集之间进行通信的数据包的数量。

希望代码能够以最少的 cmets 自我解释。

正如您将看到的，绝对不要摆弄 CDS 的 TFields 的属性 有必要的。顺便说一句，我将其作为 VCL 应用程序而不是简单的控制台应用程序来完成 这样就可以轻松地从视觉上确认一切正常。

作为一种最低公分母，我使用了 D7。在后 Unicode Delphi 中， 服务器上的 FullName 字段将是 NVarChar 类型和字符串字段类型 的 CDS 会自动调整。

type
  TForm1 = class(TForm)
    ADOConnection1: TADOConnection;
    ADOQuery1: TADOQuery;
    DataSource1: TDataSource;
    CDS1: TClientDataSet;
    DataSetProvider1: TDataSetProvider;
    DBGrid1: TDBGrid;
    procedure FormCreate(Sender: TObject);
  private
    procedure SetUp;
  end;
[...]
const
  scConnString = 'Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=MATest;Data Source=MAT430\ss2014';
  scCreateTable = 'create table TestTable(ID int not null primary key, FullName varchar(40))';
  scSelectAll = 'select * from TestTable';

procedure TForm1.SetUp;
begin
  AdoConnection1.ConnectionString := scConnString;

{.$define CreateTable}  // to do a one-off creation of the server table and data
{$ifdef CreateTable}
  AdoConnection1.Execute(scCreateTable);
{$endif}

  AdoQuery1.Connection := AdoConnection1;
  AdoQuery1.SQL.Text := scSelectAll;

{$ifdef CreateTable}
  AdoQuery1.Open;
  AdoQuery1.InsertRecord([1, 'Joe Blow']);
  AdoQuery1.Close;                             
{$endif}

  DataSetProvider1.DataSet := AdoQuery1;
  CDS1.ProviderName := 'DataSetProvider1';
  DataSource1.DataSet := CDS1;
  DBGrid1.DataSource := DataSource1;

  CDS1.Open;
  CDS1.Edit;
  CDS1.FieldByName('FullName').AsString := 'Mr ' + CDS1.FieldByName('FullName').AsString;
  CDS1.Post;

  //  Post the chamges back to the server table if desired
  CDS1.ApplyUpdates(0);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  SetUp;
end;

end.

附录 在 cmets 中提出的一点是使用计算字段有效美化 FullName 字段的可能性。我无法立即想到在代码中设置它的方法 但基本上我会这样做：

• 在 CDS 上，设置持久 TField（从 CDS 的上下文菜单中）。
• 在字段编辑器中，添加一个 fkInternalCalc 类型的计算字段。对于 CDS，这 比 fkCalculated 更好用，因为 fkI​​nternalCalc 可以包含在 CDS 的索引中
• 在 CDS 的OnCalcFields 事件中进行任何必要的计算。没有遍历 （在您的代码中）CDS 记录是进行计算所必需的，因为 CDS 在其自己的机制中进行计算。

更新 事实证明，完全在代码中将 fkInternal calc 字段添加到 CDS 是很简单的，如果有点复杂的话。诀窍是从服务器检索 FieldDef，将它们保存在 CDS 中，然后重新创建其 TField 并重新打开它。像这样：

  CDS1.Open;
  CDS1.StoreDefs := True;
  CDS1.Close;
  for i := 0 to CDS1.FieldDefs.Count - 1 do begin
    Field := CDS1.FieldDefs[i].CreateField(Self, Nil, CDS1.FieldDefs[i].DisplayName);
  end;
  Field := TStringField.Create(Self);
  Field.Size := CDS1.FieldByName('FullName').Size;
  Field.FieldKind := fkInternalCalc;
  Field.FieldName := 'EnhFullName';
  Field.DataSet := CDS1;

  CDS1.Open;