VB.net 运行过程不起作用 - 命令行是？

Question

在命令行我可以运行以下命令：

openfiles /query /s \\pha-sr-myserver /v > s:\textfile.txt

这运行良好并在服务器 pha-sr-myserver 上生成一个打开文件列表并将其输出到 textfile.txt

现在我试图在代码中重现它，但它不起作用：

Dim MyProcess As Process
Dim cText As String
Dim Shellcommand As String = "c:\windows\system32\openfiles.exe"
Dim ShellArgs As String = "/query /s \\pha-sr-myserver /v > S:\textfile.txt"
MyProcess = Process.Start(Shellcommand, ShellArgs)
MyProcess.WaitForExit()

这已经过了阶段，但该文件从未产生过，对于我的生活，我看不出有什么问题。 我尝试将参数封装在双引号等中。 我已经像这样炮击了很多次，但无法缝合以使其正常工作。 任何想法都会非常感激。 谢谢 格雷厄姆

Answer 1

openfiles.exe 无法识别> S:\textfile.txt。只有 cmd.exe 才能理解。您需要使用 Process.Start 启动 cmd.exe 或直接启动您的应用程序，然后重定向其标准输出以捕获它。试试这样的：

Dim shellArgs As String = "/query /s \\pha-sr-myserver /v"
Dim output As String = runCommandLineApp("c:\windows\system32\openfiles.exe", Nothing, shellArgs)
'Do something with output here, such as write it to a file.

Private Function runCommandLineApp(appFileName As String, workingDirectory As String, Optional args As String = Nothing) As String
    Dim psi As New ProcessStartInfo(appFileName, args)
    psi.RedirectStandardOutput = True
    psi.UseShellExecute = False
    psi.CreateNoWindow = True
    psi.WindowStyle = ProcessWindowStyle.Hidden

    If workingFolder IsNot Nothing Then
        psi.WorkingDirectory = workingFolder
    End If

    Dim p As New Process()
    p.StartInfo = psi
    p.Start()

    Dim output As String = p.StandardOutput.ReadToEnd()

    p.WaitForExit()

    Return output

End Function

Answer 2

只有cmd.exe 可以将> 解释为重定向。 因此，最简单的方法是在您的程序中运行cmd.exe。

Dim MyProcess As Process
Dim cText As String
Dim Shellcommand As String = "cmd"
Dim ShellArgs As String = "/c openfiles /query /s \\pha-sr-myserver /v > S:\textfile.txt"
MyProcess = Process.Start(Shellcommand, ShellArgs)
MyProcess.WaitForExit()

Answer 3

你可以试试简单的Shell command：

Dim sComando As String
Dim Shellcommand As String = "c:\windows\system32\openfiles.exe"
sComando = """" & Shellcommand & """" & " /query /s \\pha-sr-myserver /v > S:\textfile.txt"
Shell(sComando , AppWinStyle.Normal, True)

或者这个：

Dim MyProcess As Process
Dim cText As String
Dim Shellcommand As String = "c:\windows\system32\openfiles.exe"
Dim oShellArgs As ProcessStartInfo


oShellArgs = New ProcessStartInfo(Shellcommand , " /query /s \\pha-sr-myserver /v ")  ' remove this > "  "S:\textfile.txt"" ")
oShellArgs.RedirectStandardOutput = true
oShellArgs.RedirectStandardError = true
MyProcess = Diagnostics.Process.Start(oShellArgs)

MyProcess.StandardOutput.ReadToEnd() ' read this list of string

MyProcess.WaitForExit()