是否有 CPAN 方法来解析随机命令行选项？

Question

有没有一种好的（理想情况下是 CPAN）方法可以用 Perl 处理 任意 命令行选项？

例如，取一个字符串"-a 1 -b 'z -x' -c -d 3 4" 并生成一个GetOpt::Long - 类似数据结构：

 { a=>1, b=>"z -x", c=>1, d=>[3,4] }  # d=>"3 4" is acceptable

需要注意的是

1. 事先不知道选项集；所以我们似乎不能按原样使用GetOpt::Long。

1234563 ，一些=s@，一些“-xabc”类型。

2. 此外，即使我们可以执行 #2，GetOptionsFromString 是否支持尊重引用值的正确标记？

---

注意：为了练习的目的，假设所有参数都是“选项”，换句话说，如果您将字符串拆分为（可能带引号的）标记，您的结构总是

 "-opt1 arg1a [arg1b] -opt2 ....".

换句话说，任何以破折号开头的单词/标记都是一个新选项，所有后续不以破折号开头的单词/标记都是该选项的值。

Answer 1

在我了解Getopt::Long 和使用它的智慧之前，我推出了自己的命令行选项处理器，它可以接受任意参数并填充一个全局哈希表。规则是

用单个字母切换（-A .. -Z，-a .. -z）

-n               sets  $args{"n"} = 1
-nfoo            sets  $args{"n"} = "foo"

多于一个字母的开关

--foo            sets  $args{"foo"} = 1
--foo=bar        sets  $args{"foo"} = "bar"

这种方法的好处和坏处在于，您可以快速尝试新的命令行选项，在使用该选项时更改代码，而无需编辑对 GetOptions 的调用或分配另一个变量：

 ... line 980 ...
 if ($args{"do-experimental-thing"}) {
     # new code
     do_experimental_thing();
 } else {
     do_normal_thing();
 }

这是我上传到 CPAN 的第一个模块，后来我删除了它，但 BackPAN 的记忆力很长。

Answer 2

使用 Text::Parsewords 和简单状态机的快速示例。

#!/usr/bin/env perl

use strict;
use warnings;

use Text::ParseWords qw/shellwords/;

my $str = q{-a 1 -b 'z -x' -c -d 3 4};
my $data = parse($str);

use Data::Printer;
p $data;

sub parse {
  my $str = shift;

  my @tokens = shellwords $str;

  my %data;
  my @keys;
  my $key = '_unknown';
  foreach my $token (@tokens) {
    if ($token =~ s/^\-//) {
      $key = $token;
      push @keys, $key;
      next;
    }

    if ( ref $data{$key} ) {
      push @{ $data{$key} }, $token;
    } elsif (defined $data{$key}) {
      $data{$key} = [ $data{$key}, $token ];
    } else {
      $data{$key} = $token;
    }
  }

  foreach my $key (@keys) {
    next if defined $data{$key};
    $data{$key} = 1;
  }

  return \%data;
}