在两个元素之后插入列表中的项目

Question

我有清单

[%{A: %{}}, %{B: %{}}, %{C: %{}}]

如何在B 和C 之间添加%{D: %{}}，而不是在索引中，如下所示：

[%{A: %{}}, %{B: %{}}, %{D: %{}}, %{C: %{}}]

Answer 1

List.insert_at/3 看起来很传统。如果不能使用索引，使用模式匹配怎么样？

iex> [a, b, c] = [%{A: %{}}, %{B: %{}}, %{C: %{}}]
[%{A: %{}}, %{B: %{}}, %{C: %{}}]
iex> d = %{D: %{}}
%{D: %{}}
iex> [a, b, d, c]
[%{A: %{}}, %{B: %{}}, %{D: %{}}, %{C: %{}}]

我猜这个答案假设您知道要插入项目的位置。但它不会在函数中使用该信息。

Answer 2

如果我理解正确，您想在两个具有特定键的映射之间插入一些值，而不是基于索引。如果是这样，您将需要使用递归。像下面这样的东西应该会给你你正在寻找的东西。

def insert_between(value, [a, b | rest], key1, key2) do
  if Map.has_key?(a, key1) and Map.has_key?(b, key2) do
    [a, value, b | rest]
  else
    [a | insert_between(value, [b | rest], key1, key2)]
  end
end
# This is the catch all for the scenario where key1 and key2 are not found
# directly next to each other.
def insert_between(_value, list, _key1, _key2) do
  list
end

iex(2)> insert_between(%{d: :d}, [%{a: :a}, %{b: :b}, %{c: :c}], :b, :c)
[%{a: :a}, %{b: :b}, %{d: :d}, %{c: :c}]

当您找不到彼此直接相邻的键时，我不知道您想做什么，所以我的版本在这种情况下什么都不做。

Answer 3

由于问题被标记为list-comprehension，因此这里是Kernel.SpecialForms.for/1 列表理解的答案。

input = ~w|a b c|a

for e <- input, reduce: [] do
  acc -> if e == :b, do: [:d, :b | acc], else: [e | acc]
end |> :lists.reverse()
#⇒ [:a, :b, :d, :c]

---

或者，不减少：

for e <- input do
  if e == :b, do: [:d, :b], else: e
end |> :lists.flatten()

Answer 4

  def insert_between(a, b, list, x), do: insert_between(a, b, list, x, [])

  def insert_between(a, b, [a,b|tail], x, acc) do
    insert_between(a, b, tail, x, [b, x, a | acc])
  end
  def insert_between(a, b, [head|tail], x, acc) do
    insert_between(a, b, tail, x, [head|acc])
  end
  def insert_between(_, _ ,[], _, acc) do
    Enum.reverse(acc)
  end