在 Elixir 中使用 pin 运算符匹配位串的模式

Question

# Erlang/OTP 24, Elixir 1.12.3

bmp_signature = <<66, 77>>
#=> "BM"

<<^bmp_signature, _::binary>> = <<66, 77, 30, 0>>
#=> ** (MatchError) no match of right hand side value: <<66, 77, 30, 0>>

为什么会这样？

简而言之，我想在一个循环中对位串进行模式匹配，而不是手动编写方法定义。所以不要这样：

@bmp_signature <<66, 77>>
…

def type(<<@bmp_signature, _::binary>>), do: :bmp
…

……类似这样的：

@signatures %{
  "bmp" => <<66, 77>>,
  …
}

def detect_type(file) do
  find_value_func = fn {extension, signature} ->
    case file do
      <<^signature, _::binary>> -> extension
      _ -> false
    end
  end

  Enum.find_value(@signatures, find_value_func)
end

没有元编程可以解决吗？

Answer 1

询问这在没有元编程的情况下是否可行，就像要求在没有Enum 模块和递归的情况下解决列表反向问题。

在elixir 中，有 元编程来解决这类任务。它使代码干净、简洁且易于管理。

defmodule Type do
  @signatures %{
    bmp: <<66, 77>>
  }

  Enum.each(@signatures, fn {name, bom} ->
    def detect(<<unquote(bom), _::binary>>), do: unquote(name)
  end)
  def detect(_), do: nil
end

Type.detect(<<66, 77, 30, 0>>)
#⇒ :bmp
Type.detect(<<66, 30, 0>>)
#⇒ nil

---

不过，如果没有元编程，它仍然可以以一种丑陋而不是惯用的方式完成。

defmodule Type do
  @signatures [
    {<<66, 77>>, :bmp},
    {<<77, 66>>, :pmb}
  ]
  
  def detect(signature, candidates \\ @signatures) do
    for <<c <- signature>>, reduce: @signatures do
      acc -> 
        Enum.reduce(acc, [], fn
          {"", name}, acc -> [{"", name} | acc]
          {<<^c, rest::binary>>, name}, acc -> [{rest, name} | acc]
          _, acc -> acc
        end)
    end
  end
end

case Type.detect(<<66, 77, 30, 0>>) do
  [{"", type}] -> {:ok, type}
  [] -> {:error, :none}
  [few] -> {:error, few: few}
end
#⇒ {:ok, :bmp}

Answer 2

你的语法有点不对劲。请记住 pin 运算符 ^ 仅固定一个值。在您的示例中，您试图将其固定为 2 个值。

因此，如果您尝试匹配的对象是具有 2 个您知道的值的二进制文件，那么您需要将它们都固定，例如

iex> <<bmp_sig1, bmp_sig2>> = <<66, 77>>
iex> <<^bmp_sig1, ^bmp_sig2, rest::binary>> = <<66, 77, 88, 23, 44, 89>>
<<66, 77, 88, 23, 44, 89>>
iex> rest
<<88, 23, 44, 89>>

二进制语法<<>> 并不是唯一的方法——你可以用普通字符串来完成同样的事情（假设值实际上是字符串）：

iex> x = "apple"
"apple"
iex> "ap" <> rest = x
"apple"
iex> rest
"ple"

这里的问题是您不能 pin 前缀，因为您需要一个 literal 值才能进行匹配。这是因为事先不知道二进制文件的长度。

如果您知道您的“签名”总是有 2、3 或 4 个字符，则可以对变量进行编码以适当地固定。但是，如果您必须处理未知长度，那么您可能需要依赖更类似于正则表达式或 String.starts_with?/2 或类似的东西。

Answer 3

Erlang 的 :binary.match/2 是适合这项工作的工具：

defmodule Type do
  @signatures [
    {"bmp", <<66, 77>>},
    {"jpg", <<255, 216, 255>>},
  ]

  def detect(file_binary) do
    find_value_func = fn {extension, signature} ->
      case :binary.match(file_binary, signature) do
        {0, _} -> extension
        _ -> nil
      end
    end

    Enum.find_value(@signatures, find_value_func)
  end
end

Type.detect(<<66, 77, 0, 0>>) #=> "bmp"
Type.detect(<<55, 66, 0, 0>>) #=> nil
Type.detect(<<255, 216, 255, 0>>) #=> "jpg"

非常感谢@Everett 提出的另寻他处的建议。