如何通过 AppleScript 在 Illustrator 2020 中打开文件

Question

OSX 10.13.6、AI 2020、Applescript 编辑器版本 2.10 (194)、AppleScript 2.7

（认为这无关紧要，但我不准备升级操作系统，因为 NVidia 仍未发布系统使用的 TitanXP GPU 的驱动程序）。

在本次讨论中坚持使用 AppleScript。请不要提出“仅使用 JavaScript”的建议，除非您可以确认或否认 JavaScript 中也存在该问题。

我想知道 Adob​​e 是否已对其 Illustrator API 进行了更改，因为自从升级到新的 2020 版本以来，以前与早期版本的 Illustrator 一起使用的 Applescript 文件现在在通过别名引用时难以打开文件，或 posix 样式格式的变量。

InDesign 似乎没有受到影响，因为每次发生主要版本升级时，我都会在数百个 .INDD 文件上运行一个脚本，以防止下次使用它们时出现“另存为”对话框，这可能会搞砸脚本。该脚本仍然有效。还没有尝试过 Photoshop，但我使用的大部分自动化都是它们内部的“动作”形式。

经过一番研究，我认为他们可能已经修改了 HFS 支持，导致了意想不到的后果。

Illustrator 2020 可以打开由 posix 样式格式的硬编码字符串引用的文件，但无法从变量（HFS 样式别名或引用的 posix 样式字符串）打开同一个文件，即，

  set theHFSPath to "Mac HD:Users:Mac User:Documents:Illustrator:myFile.ai"
  set thePosixPath to quoted form of theHFSPath
  # i.e., '/Volumes/Mac HD/Users/Mac User/Documents/Illustrator/myFile.ai'

  Tell Application "Adobe Ilustrator"
    # Opens OK
    open POSIX file "/Volumes/Mac HD/Users/Mac User/Documents/Illustrator/myFile.ai" without dialogs

    # Crashes with "Adobe Illustrator got an error: The specified file could not be opened because it could not be found"
    open theHFSPath as alias without dialogs
    # open (theHFSPath as alias) also crashes

    # Crashes with "Adobe Illustrator got an error: File/Folder expected"
    open POSIX file thePosixPath without dialogs
    # open POSIX file (quoted form of thePosixPath)
    #    without quoting HFSPath above also crashes
  End Tell

我怀疑 Adob​​e 可能丢弃了一个处理 HFS 的低级例程，并且由于该例程失败，打开命令无法“看到”打开它的文件。

关于“管”的内容不多，但我遇到过：

http://forum.latenightsw.com/t/apple-script-for-illustrator-2020-javascript-code-was-missing/2167

不到一周前，这似乎描述了同样的问题。

还有其他人遇到过这个问题，或者知道如何解决吗？

Answer 1

以下示例在 macOS 10.14.6 下运行的 AI 2020（我刚刚安装）和 CC 2017 上完全符合预期：

set alis to alias "Macintosh HD:Users:foo:test.ai" -- an existing file
tell application "Adobe Illustrator" to open alis
-- AI opens test.ai document

set furl to POSIX file "/Users/foo/test.ai"
tell application "Adobe Illustrator" to open furl
-- AI opens test.ai document

这也按预期工作（尽管 AI 的错误消息质量很差）：

set furl to POSIX file "/Users/foo/xxxxx.ai" -- a non-existent file
tell application "Adobe Illustrator" to open furl
-- SE reports error "Adobe Illustrator got an error: AppleEvent handler failed." number -10000

..

但是，以下内容并不如您所愿：

set pth to "/Users/foo/test.ai"
tell application "Adobe Illustrator" to open POSIX file pth

open 命令既不会打开文件，也不会发回解释原因的错误消息。这是 AppleScript 的对象说明符的那些疯狂古怪和不直观的陷阱之一，被 AI 糟糕的错误处理弄得更加混乱。

简短说明：该脚本有效地告诉 AI 打开 POSIX file "…" of <Illustrator>，并且由于应用程序的字典不包含 POSIX file 类，因此应用程序无法解析该引用。而您需要先说POSIX file "…" of <AppleScript>，它告诉AS 建立一个POSIX file 值（它知道如何做），然后将构造的值传递给open 命令。

这就是为什么在任何 tell app… 块之外构建 alias、POSIX file、date 等值总是一个好主意。这是一个粗略的经验法则，但很容易记住。 （最好不要把 AS 的行为想得太难，因为你只会让你的head hurt。）

--

现在，如果您在 macOS 10.15 下看到不同的行为，那么这意味着其他地方发生了变化（可能是在操作系统中），这会在其他地方造成连锁反应；如果是这种情况，请使用更多详细信息更新您的原始帖子。

---

[更新添加]

这些可在 AI 2020 及更早版本 (macOS 10.14.6) 上正常工作：

set f to POSIX file "/Users/foo/test.ai" -- existing file
tell application "Adobe Illustrator" to open f
-- AI opens document

set f to POSIX file "/Users/foo/test.ai" -- existing file
tell application "Adobe Illustrator" to open f with dialogs
-- AI opens document

set f to POSIX file "/Users/foo/test.ai" -- existing file
tell application "Adobe Illustrator" to open f without dialogs
-- AI opens document

set f to POSIX file "/Users/foo/xxxxxx.ai" -- non-existent file
tell application "Adobe Illustrator" to open f without dialogs
-- AI throws File Not Found error

这也适用于 AI 2020：

set f to alias "Macintosh HD:Users:foo:test.ai" -- existing file
tell application "Adobe Illustrator" to open f

然而，虽然这些在 AI 2019 上正常工作，但在 AI 2020 上，即使文件存在，它们不正确会引发 File Not Found 错误：

set f to alias "Macintosh HD:Users:foo:test.ai" -- existing file
tell application "Adobe Illustrator" to open f with dialogs
-- error "Adobe Illustrator got an error: The specified file could not be opened because it could not be found" number 9032

set f to alias "Macintosh HD:Users:foo:test.ai" -- existing file
tell application "Adobe Illustrator" to open f without dialogs
-- error "Adobe Illustrator got an error: The specified file could not be opened because it could not be found" number 9032

set f to alias "Macintosh HD:Users:foo:test.ai" -- existing file
tell application "Adobe Illustrator" to open f with options {class:open options, add to recent files:true}
-- error "Adobe Illustrator got an error: The specified file could not be opened because it could not be found" number 9032

因此，可以确认AI 2020的open命令中有一个[非崩溃] BUG，当其直接参数是别名值和 还给出了一个或多个位置参数。

目前，您需要通过将别名值强制为 POSIX file 值[1] 来解决此错误，然后再将其传递给 AI 2020 的 open 命令：

set f to alias "Macintosh HD:Users:foo:test.ai" -- existing file
tell application "Adobe Illustrator" to open (f as «class furl») with options {class:open options, add to recent files:true}

或者，现在可能是重新编写 AppleScript 代码以消除使用别名值并在整个过程中使用 POSIX 文件值的好时机。古老的（OSX 之前）alias 值类型早已在 macOS 的其余部分中被弃用，取而代之的是现代安全范围的书签，may be why 它突然闯入了像 AI 2020 这样的最新更新的应用程序。

唉，AppleScript 几年前被降级为维护模式，所以我怀疑 Apple 是否会彻底解决旧/新/工作/损坏文件类型的绝对混乱；它们只是您需要了解并在您自己的代码中解决的问题。 （即不要费心向 Apple 提交 AppleScript 功能请求；除非这是一个安全漏洞，否则他们可能会忽略它。）

如果您想提交有关 AI 2020 的 open 命令的 Adob​​e 错误报告，您可以这样做。不保证他们会修复它；他们可能只是告诉你同样的事情——停止传递它 [deprecated] 别名值并改用 [supported] POSIX 文件值——但至少它会记录在案，因为 WontFix 可以让用户知道它。

--

[1] 请注意，在将值强制为 POSIX 文件时，您必须写成 f as «class furl»，不 f as POSIX file。这是由于 AS 中长期存在的缺陷，Apple 永远不会修复。

Answer 2

'k，问题本身似乎与 HFS 或 POSIX 路径无关。非常感谢大家的回复和cmets，仍然相信AI 2020的open命令有bug；将前往 Adob​​e 看看是否有其他人举报。

如果对路径进行硬编码，即

Tell Adobe Illustrator
   open POSIX file "/Users/Mac User/Documents/Illustrator/myFile.ai" without dialogs
End Tell

它会工作。

然而，事实证明，在 AI 2020 中，罪魁祸首是可选的“无对话框”参数以及对文件的别名或 POSIX 样式变量引用。

根据字典会追加一个

without dialogs

打开命令以绕过 AI 在打开文件时可能出现的任何常规对话框。

尽管这在 AI 2019 中运行良好，但它导致打开命令在 AI 2020 中崩溃，即使 AI 2020 字典仍将“对话框”显示为可选布尔参数，其语法与 2019 版本相同。

为了验证这个假设，我启动了一个仍然有 AI 2019 的旧 Mini，然后尝试：

set theFile to "Users:Mac User:Documents:Illustrator:myFile.ai"
open theFile as alias without dialogs

正如预期的那样，这工作得很好，多年来一直如此。

在 AI 2020 中，具有相同的文件引用，

open theFile as alias without dialogs

使打开命令崩溃。

删除without dialogs，它会按预期打开。

因此，目前唯一的解决方法似乎是忽略对话框参数。

希望 Adob​​e 更新他们的 AS 字典或修复错误。

保重！