如何使用VBA从光标位置选择文本到段落的开头

Question

我正在格式化大型文档中的特定类型名称。正确的格式是“术语名称 (REC) [日期]”，其中除日期外，整个短语都是斜体。我目前正在使用以下代码：

Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            .Text = "(REC)"
            .Replacement.Text = "*"
            .Forward = True
            .Wrap = wdFindStop
            .Format = True
            .MatchCase = False
            .MatchWholeWord = False
            .MatchWildcards = False
            .MatchSoundsLike = False
            .MatchAllWordForms = False
        End With
        Do While Selection.Find.Execute = True
            Selection.MoveRight Unit:=wdCharacter, Count:=1
            Selection.HomeKey Unit:=wdLine, Extend:=wdExtend
            Selection.Font.Italic = wdToggle
            Selection.EndKey Unit:=wdLine, Extend:=wdMove
        Loop

除非斜体短语超过两行，否则这很好用。我得到如下内容： "期限名称 期限 期限 期限 期限
期限 期限 期限 (REC) [日期]"
第一行没有斜体的地方。 VBA 是否有办法只在光标位置选择当前段落的开头？
请随时提出更好的方法。

Answer 1

这会选择从插入点到段落开头的所有内容。这在文档的最开头不起作用，因为没有前面的返回：

Selection.MoveStartUntil Cset:=vbCr, Count:=wdBackward

Answer 2

是的，这是可能的。有多种方法可以解决，但一种相当直接的方法是使用Range 或Selection 对象的MoveStart 方法。

就个人而言，我更喜欢使用Range 而不是Selection，因为它更灵活、更快并且“屏幕闪烁”更少。但是下面显示的方法对两者都适用，只是一样。

Dim rngFind As Range

Set rngFind = ActiveDocument.Content 'search the document body

rngFind.Find.ClearFormatting
rngFind.Find.Replacement.ClearFormatting
    With rngFind.Find
        .Text = "(REC)"
        .Replacement.Text = "*"
        .Forward = True
        .Wrap = wdFindStop
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Do While rngFind.Find.Execute = True
        rngFind.MoveRight Unit:=wdCharacter, Count:=1
        rngFind.MoveStart Unit:=wdParagraph, Count:=-1
        rngFind.Font.Italic = wdToggle
        rngFind.Collapse wdCollapseEnd
    Loop