在 minizinc 中使用 forall() 谓词作为没有“约束”的赋值语句

Question

我有一个 Minizinc 程序，用于为并网电池生成最佳充电/放电时间表，给定一组按时间间隔排列的价格。

我的程序有效（有点；但有一些注意事项），但我的问题是关于两个“约束”语句，它们实际上只是赋值语句：

constraint forall(t in 2..T)(MW_SETPOINT[t-1] - SALE[t] = MW_SETPOINT[t]);
constraint forall(t in 1..T)(PROFIT[t] = SALE[t] * PRICE[t]);

这些只是意味着能量SALES 是MW_SETPOINT 从t-1 到1 的增量，PROFIT 是每个间隔的SALE * PRICE。因此，将它们声明为“约束”对我来说似乎违反直觉。但是我一直无法将它们表述为赋值语句而不会引发语法错误。

问题：

• 是否有更惯用的方式来为作为其他参数/​​变量函数的数组声明此类赋值语句？还是在 Minizinc 中为 constraints 中的数组分配是推荐/惯用的方式？

上下文的完整程序：

% PARAMS
int: MW_CAPACITY = 10;
array[int] of float: PRICE; 

% DERIVED PARAMS
int: STARTING_MW = MW_CAPACITY div 2;  % integer division
int: T = length(PRICE);

% DECISION VARIABLE - MW SETPOINT EACH INTERVAL
array[1..T] of var 0..MW_CAPACITY: MW_SETPOINT;

% DERIVED/INTERMEDIATE VARIABLES
array[1..T] of var -1*MW_CAPACITY..MW_CAPACITY: SALE;  
array[1..T] of var float: PROFIT;
var float: NET_PROFIT = sum(PROFIT);

% CONSTRAINTS
%% If start at 5MW, and sell 5 first interval, setpoint for first interval is 0 
constraint MW_SETPOINT[1] = STARTING_MW - SALE[1];  

%% End where you started; opt schedule from arbitrage means no net MW over time
constraint MW_SETPOINT[T] = STARTING_MW;            

%% these are really justassignment statements for SALE & PROFIT
constraint forall(t in 2..T)(MW_SETPOINT[t-1] - SALE[t] = MW_SETPOINT[t]);
constraint forall(t in 1..T)(PROFIT[t] = SALE[t] * PRICE[t]);

% OBJECTIVE: MAXIMIZE REVENUE
solve maximize NET_PROFIT;

output["DAILY_PROFIT: " ++ show(NET_PROFIT) ++ 
      "\nMW SETPOINTS: " ++ show(MW_SETPOINT) ++ 
      "\nMW SALES: " ++ show(SALE) ++
      "\n$/MW PRICES: " ++ show(PRICE)++
      "\nPROFITS: " ++ show(PROFIT)
      ]; 

可以运行

minizinc opt_sched_hindsight.mzn --solver org.minizinc.mip.coin-bc -D "PRICE = [29.835, 29.310470000000002, 28.575059999999997, 28.02416, 28.800690000000003, 32.41052, 34.38542, 29.512390000000003, 25.66587, 25.0499, 26.555529999999997, 28.149440000000002, 30.216509999999996, 32.32415, 31.406609999999997, 36.77642, 41.94735, 51.235209999999995, 50.68137, 64.54481, 48.235170000000004, 40.27663, 34.93675, 31.10404];"```

Answer 1

你可以玩Array Comprehensions：（引用自文档）

数组推导具有以下语法：

<array-comp> ::= "[" <expr> "|" <comp-tail> "]"

例如（右边的文字等价物）：

[2*i | i in 1..5]       % [2, 4, 6, 8, 10]

数组推导比集合推导具有更灵活的类型和 inst 要求（请参阅Set Comprehensions）。

允许对有限类型的变量集进行数组推导， 结果是一个可选类型的数组，长度等于 变量集上界的基数。例如：

var set of 1..5: x;
array[int] of var opt int: y = [ i * i | i in x ];

数组的长度为5。

在 where 表达式的地方允许数组推导 是var bool。同样，结果数组是可选的 类型，并且长度等于生成器表达式给出的长度。例如：

var int x;
array[int] of var opt int: y = [ i | i in 1..10 where i != x ];

数组的长度为 10。

求值的简单数组推导的索引是 隐含1..n，其中n 是评估的长度 理解。

示例：

int: MW_CAPACITY = 10;
int: STARTING_MW = MW_CAPACITY div 2;

array [int] of float: PRICE = [1.0, 2.0, 3.0, 4.0];
int: T = length(PRICE);

array [1..T] of var -1*MW_CAPACITY..MW_CAPACITY: SALE;

array [1..T] of var 0..MW_CAPACITY: MW_SETPOINT = let {
        int: min_i = min(index_set(PRICE));
    } in  
        [STARTING_MW - sum([SALE[j] | j in min_i..i])
         | i in index_set(PRICE)];

array [1..T] of var float: PROFIT =
        [SALE[i] * PRICE[i]
         | i in index_set(PRICE)];

solve satisfy;

输出：

~$ minizinc test.mzn 
SALE = array1d(1..4, [-10, -5, 0, 0]);
----------

注意index_set(PRICE) 只不过是1..T 而min(index_set(PRICE)) 只不过是1，所以可以将上述数组推导写成

array [1..T] of var 0..MW_CAPACITY: MW_SETPOINT =
        [STARTING_MW - sum([SALE[j] | j in 1..i])
         | i in 1..T];

array [1..T] of var float: PROFIT =
        [SALE[i] * PRICE[i]
         | i in 1..T];