复选框使 myCurrencyManager.AddNew() 无法正常工作

Question

我有一个功能齐全的 Windows 窗体应用程序，它使用绑定到 Access DB 的只读数据网格视图开发。
数据绑定文本框用于编辑字段。然后我在数据库、datagridview 和表单中添加了 3 个复选框字段。然后像文本框一样添加chkName.DataBindings.Add("Checked", DBTable,"Field")。复选框正常工作，显示正确的数据。

仅当我尝试使用 myCurrencyManager.AddNew() 添加一行时，它才不起作用。除了在 datagridview 的末尾添加一个不可访问的行之外，它什么也不做。当我注释掉 Checkbox DataBindings 行时，一切正常（没有功能复选框）。

有什么想法吗？

代码如下：

Public Class frmRoutes
    Dim RoutesConnection As OleDbConnection
    Dim JS1Adapter As New OleDbDataAdapter
    Dim JS1Table As New DataTable("JOBSITES")
    Dim JSBS As BindingSource
    Dim JS1State As String = "Edit"

    Private Sub frmRoutes_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        RoutesConnection = New OleDbConnection("Provider=Microsoft.ACE.OLEDB.12.0; Data Source = C:\Microsoft\JS1TestDB.mdb")
        RoutesConnection.Open()
        Dim JobSitesCommand = New OleDbCommand _
        ("SELECT REF, STREET, CITY, SPEC, HELPER " +
        "FROM Jobsites ORDER BY REF", RoutesConnection)

        JS1Adapter.SelectCommand = JobSitesCommand
        JS1Adapter.Fill(JS1Table)

        JSBS = New BindingSource()
        JSBS.DataSource = JS1Table
        grdJobSites.DataSource = JSBS

        txtRef.DataBindings.Add("Text", JSBS, "REF")
        txtStreet.DataBindings.Add("Text", JSBS, "STREET")
        txtCity.DataBindings.Add("Text", JSBS, "CITY")
        'chkSpecial.DataBindings.Add("Checked", JSBS, "SPEC")  'THESE 2 CHECKBOX DATABINDINGS CAUSE THE 'ADDNEW' METHOD TO FAIL
        'chkHelper.DataBindings.Add("Checked", JSBS, "HELPER")
    End Sub

    Private Sub btnAdd_Click(sender As Object, e As EventArgs) Handles btnAdd.Click
        Try
            JSBS.AddNew()
        Catch ex As Exception
            MessageBox.Show("Error Adding a New row.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
        JS1State = "Add"
    End Sub

    Private Sub btnCancel_Click(sender As Object, e As EventArgs) Handles btnCancel.Click
        JSBS.CancelEdit()
        JS1State = "View"
    End Sub
End Class

Answer 1

问题正如我已经说过的：可空数据。我刚刚测试了这段代码（一个实际的最小示例）：

Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim table As New DataTable

        With table.Columns
            .Add("Name", GetType(String))
            .Add("Flag", GetType(Boolean))
        End With

        With table.Rows
            .Add("Peter", True)
            .Add("Paul", False)
            .Add("Mary", True)
        End With

        BindingSource1.DataSource = table
        TextBox1.DataBindings.Add("Text", BindingSource1, "Name")
        CheckBox1.DataBindings.Add("Checked", BindingSource1, "Flag")
    End Sub

End Class

并且在添加新行（通过BindingNavigator）时发生无效转换异常，因为Flag 列默认包含DBNull.Value，并且不能转换为Boolean 类型，这是@ 所必需的987654326@ 财产。有两种可能的解决方案。最好的方法取决于您是否希望能够保存空值。

1. 如果您不想保存空值，请为该列指定默认的Boolean 值。那可能是False，但如果你愿意，也可能是True。这样，当添加新行时，该列已经包含与Checked 属性兼容的Boolean 值。在我的例子中，这个：

.Add("Flag", GetType(Boolean))

变成这样：

.Add("Flag", GetType(Boolean)).DefaultValue = False

在您的情况下，您必须在填充并设置该属性后从 DataTable 获取相应的列。

1. 将CheckBox 的ThreeState 属性设置为True，绑定到CheckState 属性而不是Checked 属性，并在数据源中可为空的Boolean 数据和@ 987654341@ 控件中的值。对我的示例进行更改可能如下所示：

Public Class Form1

    Private WithEvents checkStateBinding As Binding

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim table As New DataTable

        With table.Columns
            .Add("Name", GetType(String))
            .Add("Flag", GetType(Boolean))
        End With

        With table.Rows
            .Add("Peter", True)
            .Add("Paul", False)
            .Add("Mary", True)
        End With

        BindingSource1.DataSource = table
        TextBox1.DataBindings.Add("Text", BindingSource1, "Name")

        checkStateBinding = New Binding("CheckState", BindingSource1, "Flag")

        CheckBox1.DataBindings.Add(checkStateBinding)
    End Sub

    Private Sub CheckStateBinding_Format(sender As Object, e As ConvertEventArgs) Handles checkStateBinding.Format
        'Convert from nullable Boolean to CheckState.
        If TryCast(e.Value, DBNull) Is DBNull.Value Then
            e.Value = CheckState.Indeterminate
        ElseIf CBool(e.Value) Then
            e.Value = CheckState.Checked
        Else
            e.Value = CheckState.Unchecked
        End If
    End Sub

    Private Sub CheckStateBinding_Parse(sender As Object, e As ConvertEventArgs) Handles checkStateBinding.Parse
        'Convert from CheckState to nullable Boolean.
        Select Case DirectCast(e.Value, CheckState)
            Case CheckState.Indeterminate
                e.Value = DBNull.Value
            Case CheckState.Checked
                e.Value = True
            Case CheckState.Unchecked
                e.Value = False
        End Select
    End Sub

End Class

Binding 需要从控件的数据源获取数据时引发其Format 事件，当它需要从数据源的控件获取数据时引发其Parse 事件。如果两者之间的类型和/或值不匹配，您可以自己进行翻译。