使用 VBA 从表中提取详细信息获取对象变量或未设置块变量

Question

我的脚本运行了几行，然后我获取对象变量或块变量未设置错误。

我正在使用以下脚本从 NSEIndia 网站中提取 5、6、7 值。

我从同一个 Excel 中获取股票的价值，并使用来自 nseindia 网站的值更新同一个 Excel。

Sub Stock_Basic_Update_NSE()
    Dim ie As InternetExplorer
    Dim webpage As HTMLDocument
    
    Dim ws As Worksheet
    
        
    For Item = 23 To 1505
    Set ws = ThisWorkbook.Worksheets("NSE Stocks Details")
       sSearch = ws.Range("A" & Item).Value
        'sSearch = Filestk.Worksheets("Sheet1").Range("E1").Value
        Set ie = New InternetExplorer
        'ie.Visible = True
        ie.navigate ("https://www.nseindia.com/get-quotes/equity?symbol=" & sSearch)
        Do While ie.readyState = 4: DoEvents: Loop
        Do Until ie.readyState = 4: DoEvents: Loop
        
        While ie.Busy
            DoEvents
        Wend
        Set webpage = ie.document
        ws.Cells(Item, 3).Value = webpage.getElementsByClassName("eq-series table-fullwidth w-100")(0).getElementsByTagName("td")(5).innerText
        ws.Cells(Item, 4).Value = webpage.getElementsByClassName("eq-series table-fullwidth w-100")(0).getElementsByTagName("td")(6).innerText
        ws.Cells(Item, 5).Value = webpage.getElementsByClassName("eq-series table-fullwidth w-100")(0).getElementsByTagName("td")(7).innerText
        ie.Quit
        Set ie = Nothing
    Next Item
End Sub

Answer 1

您的代码中有一些错误，您没有等待完整的文档加载。试试下面的代码。我已经评论过了。所以你可以看到，我改变了什么以及为什么。我已经尝试了前 50 个符号。

Sub Stock_Basic_Update_NSE()
  'Declare always all variables
  Dim ie As Object 'I switched this from early to late binding (not required)
  Dim nodeTable As Object
  Dim ws As Worksheet
  Dim item As Long
  Dim sSearch As String
  
  'Use this outside the loop. You only need it once
  Set ws = ThisWorkbook.Worksheets("NSE Stocks Details")
  
  For item = 23 To 1505
    sSearch = ws.Range("A" & item).Value
    Set ie = CreateObject("internetexplorer.application")
    ie.Visible = False
    'Encode symbols that are restricted for using in URLs. Like &, : or ?
    ie.navigate ("https://www.nseindia.com/get-quotes/equity?symbol=" & WorksheetFunction.EncodeURL(sSearch))
    'It's not "While = 4" because 4 stands for "readystate = complete"
    'If you want to use "= 4" you must use "Until" instead of "While"
    'It doesn't matter what you use
    Do While ie.readyState <> 4: DoEvents: Loop
    'Manual break to load dynamic content after the IE reports the page load was complete
    'This was your main problem
    Application.Wait (Now + TimeSerial(0, 0, 2))
    
    'The needed html table has an ID. If possible use always that instead of class names
    'because an html ID is unique if the standard is kept
    'Also use a variable to save the elements
    'So you don't need to shorten the html document string in most cases because
    'it's only needed one time
    Set nodeTable = ie.document.getElementByID("equityInfo")
    ws.Cells(item, 3).Value = nodeTable.getElementsByTagName("td")(5).innerText
    ws.Cells(item, 4).Value = nodeTable.getElementsByTagName("td")(6).innerText
    ws.Cells(item, 5).Value = nodeTable.getElementsByTagName("td")(7).innerText
    
    'Clean up
    ie.Quit
    Set ie = Nothing
  Next item
End Sub