【问题标题】:Accessing parent daemon from container in Jenkins从 Jenkins 中的容器访问父守护进程
【发布时间】:2019-06-10 20:01:49
【问题描述】:

我们有一堆节点在 Jenkins 中运行我们的工作。我需要从 Jenkins 工作中构建两个图像。为此,我读到您应该使用绑定安装来共享 unix 套接字,我已经这样做了:

agent {
    docker {
        image 'custom-alpine-with-docker'
        args '-v /var/run/docker.sock:/var/run/docker.sock'
    }
}

然后我想按如下方式使用它:

stage('Build and push image(s)') {
    steps {
        dir("${WORKING_DIRECTORY}") {
            script {
                echo 'Building amd64 image'
                amd64image = docker.build("${IMAGE_NAME}:${BUILD_NUMBER}-amd64", "-f ./Dockerfile.amd64 .")
                echo 'Building arm32v7 image'
                arm32v7image = docker.build("${IMAGE_NAME}:${BUILD_NUMBER}-arm32v7", "-f ./Dockerfile.arm32v7 .")
            }
            script {
                docker.withRegistry("${DOCKER_REGISTRY_URL}", "${REPOSITORY_CREDENTIALS}") {
                    amd64image.push()
                    arm32v7image.push()
                }
            }
        }
    }
}

但是,一旦在 jenkins 作业中发出构建命令,我就会收到以下错误:

time="2019-01-16T16:55:33Z" level=error msg="failed to dial gRPC: cannot connect to the Docker daemon. is 'docker daemon' running on this host?: dial unix /var/运行/docker.sock:连接:权限被拒绝” 17:56:59 尝试在 unix:///var/run/docker.sock 连接到 Docker 守护进程套接字时获得权限被拒绝:

所以一个简单的搜索显示此错误的来源是尝试访问守护程序的用户不在 docker 组中,但我不明白在共享这样的守护程序时这些组成员身份是如何工作的。

如果我转到构建失败的节点,并检查 docker 组中的用户,我会得到以下信息:

$ getent group docker
docker:x:126:inst,jenkins

那么我如何允许在该主机上的容器中运行的用户访问相同的守护进程?

小更新

只是在本地使用docker run -v /var/run/docker.sock:/var/run/docker.sock -ti docker 完成,当我在容器和主机上写入docker ps 时,我看到相同的容器正在运行。

在我的开发机器上获取所有用户,它看起来像这样:

docker:x:999:overlord

所以我猜我需要一些特殊的 jenkins 解决方案才能使其工作..

【问题讨论】:

    标签: docker jenkins


    【解决方案1】:

    我想我已经以令人满意的方式解决了这个问题。这是一个分步指南:

    1. 确保 docker 安装在需要运行它的容器中
    2. 创建 docker 组和 jenkins 用户:
    CMD DOCKER_GID=$(stat -c '%g' /var/run/docker.sock) && \
        groupmod --gid ${DOCKER_GID} ${DOCKER_GROUP} && \
        usermod -a -G ${DOCKER_GROUP} ${JENKINS_USER} && \
        gosu jenkins sh
    

    需要注意的是,这里我获取了运行 docker 的底层系统的组 ID。由于我已经在容器中安装了 docker 并且该组已经存在,因此我修改了现有组以匹配系统的组 ID。最后,我将 jenkins 用户添加到 docker 组。您的 /etc/group 运行后在容器中应该如下所示:

    码头工人:x:999:詹金斯

    1. 在您的管道中,按如下方式启动代理:
    agent {
        docker {
            image 'storemanager-build'
            args '-u root -v /var/run/docker.sock:/var/run/docker.sock'
        }
    }
    

    通过提供-u root 标志,您可以覆盖用户jenkins,当您使用声明性管道时,jenkins 会强制您使用。您必须使用 root 才能使用 CMD 命令才能工作并能够创建组。

    当镜像运行时,该命令将切换到允许访问底层 unix 套接字的 jenkins 用户。

    这是我的 Jenkinsfile 的摘录:

    pipeline {
    
        agent {
            docker {
                image 'build-image'
                args '-u root -v /var/run/docker.sock:/var/run/docker.sock'
            }
        }
    
        stages {
    
            stage('Build jar') {
                steps {
                    dir("${WORKING_DIRECTORY}") {
                        script {
                            if (isUnix()) {
                                sh './mvnw --batch-mode clean install'
                            } else {
                                bat 'mvnw.cmd --batch-mode clean install'
                            }
                        }
                    }
                }
            }
    
            stage('Build and push image(s)') {
                steps {
                    dir("${WORKING_DIRECTORY}") {
                        script {
                            amd64image = docker.build("${IMAGE_NAME}", "-f ./Dockerfile.amd64 .")
                            arm32v7image = docker.build("${IMAGE_NAME}", "-f ./Dockerfile.arm32v7 .")
                        }
                        script {
                            docker.withRegistry("${DOCKER_REGISTRY_URL}", "${STOREMANAGER_REPOSITORY_CREDENTIALS}") {
                                amd64image.push("${BUILD_NUMBER}-amd64")
                                arm32v7image.push("${BUILD_NUMBER}-arm32v7")
                            }
                        }
                    }
                }
            }
        }
    
        post {
            always {
                sh "chmod -R 777 ." // Jenkins can't clean built resources without this as we run the container as root
                cleanWs()
            }
        }
    }
    

    以及帮助我​​的资源:

    https://jpetazzo.github.io/2015/09/03/do-not-use-docker-in-docker-for-ci/ https://github.com/jenkinsci/docker/issues/196

    希望这会有所帮助。

    【讨论】:

      猜你喜欢
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 2017-08-07
      • 1970-01-01
      • 2021-08-07
      • 2014-12-11
      • 1970-01-01
      • 2018-04-05
      相关资源
      最近更新 更多