拆分字符串，然后删除 Google 表格中的前缀（再次）

Question

我的 Google 表格填充了以下格式的不同字符串：

Monday: 12:00 PM – 12:00 AM,Tuesday: 12:00 PM – 12:00 AM,Wednesday: 12:00 PM – 12:00 AM,Thursday: 12:00 PM – 12:00 AM,Friday: 12:00 PM – 12:00 AM,Saturday: 12:00 PM – 12:00 AM,Sunday: 12:00 PM – 12:00 AM

我的目标是将字符串拆分为不同的列，然后从每个单元格中删除前缀，以创建如下内容：

Monday	Tuesday	Wednesday	Thursday	Friday	Saturday	Sunday
12:00 PM – 12:00 AM	12:00 PM – 12:00 AM	12:00 PM – 12:00 AM	12:00 PM – 12:00 AM	12:00 PM – 12:00 AM	12:00 PM – 12:00 AM	12:00 PM – 12:00 AM

我使用公式 =arrayformula(REGEXEXTRACT(SPLIT(B2, ",", true), ":\s(.*)")) ，正如 Goran Here 所建议的那样，它工作得非常好，直到我每天得到多个时间范围的字符串，就像这样：

Monday: 12:00 – 4:00 PM, 6:00 PM – 12:00 AM,Tuesday: 12:00 – 4:00 PM, 6:00 PM – 12:00 AM,Wednesday: 12:00 – 4:00 PM, 6:00 PM – 12:00 AM,Thursday: 12:00 – 4:00 PM, 6:00 PM – 12:00 AM,Friday: Closed,Saturday: Closed,Sunday: 12:00 – 4:00 PM, 6:00 PM – 12:00 AM

现在公式不知道如何处理这种情况，我该如何解决它并使我的公式相应地起作用？请帮忙！

更新： 我不确定我是否成功，似乎它正在工作，但我正在分享一个link 让你仍然看看！

Answer 1

不知道是不是和beforwardsImport JSON into Google Sheets一样的问题，不过我已经准备好了答案……

function timeTable(url,e) {
  if (url.match(/http(s)?:\/\/?/g)){var data = JSON.parse(UrlFetchApp.fetch(url).getContentText())}
  else{var data = JSON.parse(url)}
  var result=[]
  for (var i=0;i<=6;i++){
    result[6-data.result.opening_hours.periods[i][e].day]=data.result.opening_hours.periods[i][e].time
  }
  return [result]
}

with e = 打开或关闭/复制https://docs.google.com/spreadsheets/d/1uvs89rcG6HkPKXXsCmNUOjy5sCQxaJMSHobQLzS-vHY/copy

Answer 2

一个解决方案，但可能需要改进......

=transpose(split(substitute(substitute(substitute(REGEXEXTRACT(A1,"Monday[:0-9\–, APM]+"),", ","|"),": ","|"),",",""),"|"))

然后将星期一替换为星期二、星期三等。

Answer 3

这应该对你有用，假设每个字符串至少包含一周中七个命名天中的每一天的内容：

=ArrayFormula(REGEXREPLACE(SPLIT(REGEXREPLACE(","&B2,"[^,]*day:\s*","~"),",~",0,1),",\s*",CHAR(10)))

如果您需要将此应用于 B2:B 中的多个原始字符串，请先确保输出范围（例如 C2:I）明确，然后使用此版本的公式：

=ArrayFormula(IF(B2:B="",,REGEXREPLACE(SPLIT(REGEXREPLACE(","&B2:B,"[^,]*day:\s*","~"),",~",0,1),",\s*",CHAR(10))))

ADDENDUM（阅读有关希伯来语内含物的评论后）：

看看这是否适用于希伯来语：

=ArrayFormula(IF(B2:B="",,REGEXREPLACE(SPLIT(REGEXREPLACE(","&B2:B,",[^,]+:\s","~"),"~",0,1),",\s*",CHAR(10))))

如果没有，请按照我在下面的附加评论，分享指向工作表副本的链接。

附录 #2（在进一步的 cmets 之后）

控制每个变量超出了任何免费论坛的范围。这将超越共享信息或推动我所谓的“实际工作”（即定制的、时间密集的、专家服务）的正确方向。不过，我将提供一个额外的公式变体来涵盖您的最新更新：

=ArrayFormula(IF(A3:A10="",,SUBSTITUTE(REGEXREPLACE(SPLIT(REGEXREPLACE(REGEXREPLACE(REGEXREPLACE(","&A3:A10,",[^,]+:\s","~"),"(\d)(\d\d)(\D)","$1:$2$3"),"(:\d\d)","$1*"),"~",0,1),",\s*",", "),"*","")))