使用函数哈希作为参数的 Javascript/Coffeescript

Question

我有一些看起来像这样的 Coffeescript（提前为复杂性道歉）：

doc = new ChargerServerDoc(Chargers.find({id:site.id}), site)

doc.set_defaults().merge().needs_update
  update: (id, doc) ->
    Chargers.update id, $set: doc, (error, result) ->
      if error
        run_stats.error_count += 1
        "error"
      else
        run_stats.update_count += 1
        "update"

    return

  insert: (doc) ->
    Chargers.insert doc, (error, result) ->
      if error
        run_stats.error_count += 1
        "error"
      else
        run_stats.insert_count += 1
        "insert"

    return

它应该创建某种文档并作为回调实现对数据库的插入或更新。

needs_update: (callbacks = null) ->

  console.log inspect arguments

  if callbacks is null
    return true unless @is_equal(@working_document, @retrieved_document)
    return false
  else
    console.log """
    callbacks not null:
    insert: #{inspect callbacks['insert']}
    update: #{inspect callbacks['update']} 
    """
    data = @get()
    if @is_equal(@working_document, @retrieved_document)
      throw 'requires update callback' if _.isEmpty(callbacks.update)
      return callbacks.update.call(this, data._id, _.omit(data, '_id'))
    else
      throw 'require insert callback' if _.isEmpty(callbacks.insert)
      return callbacks.insert.call(this, _.omit(data, '_id'))

如您所见，needs_update 函数中充斥着console.log 语句。这是在 node.js 中运行的，它是在启动时运行一次的事情。所以在节点检查器中观察并不容易。至少我还没弄清楚怎么做。

无论如何，这其中有趣的部分是console.log inspect arguments。 inspect 只是将对象转换为 JSON 字符串，以便我可以读取它。结果总是{"0":{}}。

这就是我卡住的地方。我可以看到它正在传递一个哈希，但哈希中没有任何内容。更奇怪的是，当我用纯 Javascript 手写它时，也会发生同样的行为。

我试图减少它并重现它无济于事。此代码有效：

h =
  f1: (a) -> 'one'
  f2: (b) -> 'two'

test = (fn) ->
  console.log fn.f1.call()
  console.log fn.f2.call()

test(h)

有人知道为什么第一个代码失败而简化的示例有效吗？

谢谢！

Answer 1

你没有正确使用_.isEmpty。来自fine manual：

isEmpty _.isEmpty(object)

如果可枚举的对象不包含任何值（没有可枚举的自身属性），则返回true。对于字符串和类数组对象_.isEmpty 检查长度属性是否为0。

函数不是可枚举的对象，也不是字符串或类似数组的对象。你给_.isEmpty 一些它不理解的东西，所以你正在调用未指定的行为。原来_.isEmpty 会返回true 任何它不理解的东西。

如果你想看看某个东西是否是一个函数，_.isFunction 可能会更好地为你服务：

throw 'requires update callback' unless _.isFunction(callbacks.update)