Q.all 不调用任务

Question

所以我有这个 CoffeeScript（简化以专注于真正的问题）

Q = require 'q'
events = require 'events'

class SomeObj extends events.EventEmitter

  constructor: () ->
    setTimeout () =>
      @emit 'done'
    , 3000


class SomeObj2 extends events.EventEmitter

  constructor: () ->
    setTimeout () =>
      @emit 'done'
    , 50000

class Main

  someObj1: null
  someObj2: null
  constructor: () ->
    Q.all([
      => @task1(),
      => @task2()])
    .then (results)->
      console.log 'results'
      console.log results
    .catch((error)->
      console.log 'error'
      console.log error
    )

  task1: () ->
    console.log 'task1 started'
    defer = Q.defer()
    @someObj = new SomeObj()

    @someObj.on 'done', (err, data) =>
      console.log 'task1 done'
      defer.resolve data

    return defer.promise

  task2: () ->
    console.log 'task2 started'
    defer = Q.defer()
    @someObj2 = new SomeObj2()

    @someObj2.on 'done', (err, data) =>
      console.log 'task2 done'
      defer.resolve data

    return defer.promise


main = new Main()

输出是：

results
[ [Function], [Function] ]

在Main::constructor 中，回调@task1 和@task2 似乎没有被调用。所以为了确定这一点，我在它们的顶部添加了console.log。而且由于它们没有被打印出来，我可以确定它们没有被调用。

出于测试目的，我替换了这个块

  constructor: () ->
    Q.all([
      => @task1(),
      => @task2()])
    .then (results)->
      console.log 'results'
      console.log results
    .catch((error)->
      console.log 'error'
      console.log error
    )

在这个街区

  constructor: () ->
    Q.fcall () => @task1()
    .then ()  => @task2()
    .then (results)->
      console.log 'results'
      console.log results
    .catch((error)->
      console.log 'error'
      console.log error
    )

这实际上可以按预期工作，但这不是我想要的。目标是并行启动task1和2。

旁注：在任务内部，我希望能够将@ 用于Main 的成员变量

怎么了？

Answer 1

Q.all helper 期望解析一个数组或 promise，而不是函数数组。这意味着如果你想使用Q.all，你应该自己调用所有的任务。

在您的示例中，删除匿名函数包装就可以解决问题：

constructor: () ->
  Q.all([
    @task1()
    @task2()
  ]).then (results) ->
    // Success
  .catch (error) ->
    // Error