对 Scheme 中 let 和 let* 的区别感到困惑

Question

谁能简单解释一下区别？我认为我没有从我咨询过的教科书/网站中理解这个概念。

Answer 1

Let 是并行的，^{（有点；见下文）}let* 是连续的。 Let 翻译为

((lambda(a b c)  ... body ...)
  a-value
  b-value
  c-value)

但是let*作为

((lambda(a)
    ((lambda(b)
       ((lambda(c) ... body ...)
        c-value))
     b-value))
  a-value)

因此创建了嵌套范围块，其中b-value 表达式可以引用a，而c-value 表达式可以同时引用b 和a。 a-value 属于外部范围。这也相当于

(let ((a a-value))
  (let ((b b-value))
    (let ((c c-value))
      ... body ... )))

还有 letrec，允许递归绑定，其中所有变量和表达式属于一个共享范围并且可以相互引用（有一些关于初始化的警告）。它相当于

(let ((a *undefined*) (b *undefined*) (c *undefined*))
  (set! a a-value)
  (set! b b-value)
  (set! c c-value)
  ... body ... )

(in Racket，也可以在 Scheme 中以 letrec* 的形式使用，因为 R6RS)，或者

(let ((a *undefined*) (b *undefined*) (c *undefined*))
  (let ((_x_ a-value) (_y_ b-value) (_z_ c-value))   ; unique identifiers
    (set! a _x_)
    (set! b _y_)
    (set! c _z_)
    ... body ... ))

(in Scheme)。

更新：let 实际上并没有并行评估其值表达式，只是它们都在出现let 表单的相同初始环境中进行评估。从基于lambda 的翻译中也可以清楚地看到这一点：首先在相同的外部环境中评估值表达式每个，然后收集结果值，然后只有 为每个 id 创建新位置，并将值放在每个位置中。如果其中一个值表达式改变了由后续存储访问的存储（即数据，如列表或结构），我们仍然可以看到顺序性。

Answer 2

如果您使用let，则不能引用出现在同一let 表达式中的其他 绑定。

例如，这是行不通的：

(let ((x 10)
      (y (+ x 6))) ; error! unbound identifier: x
  y)

但如果您使用let*，则可以引用出现在同一let* 表达式中的previous 绑定：

(let* ((x 10)
       (y (+ x 6))) ; works fine
  y)
=> 16

文档中都是here。