curry 时的 Groovy 错误

Question

给出错误的代码在ideone here，抱歉我没能给出一个更简单的例子。

因为有点长，我来解释一下。

Unfoldr 类和 unfoldr 函数基本上与 unfoldr 在 Haskell 中所做的一样，创建列表。但在这种情况下，我创建了一个迭代器。

map 函数再次出现，很像 Haskell 中的 map。它传递了一个迭代器，调用 unfoldr 并将迭代器作为“状态”，并创建一个新的迭代器，它给出与旧迭代器相同的结果，但应用了给定的函数。

splitlist 将一个列表分解为多个列表n long，即 splitlist(2)([1,2,3,4]) 导致一个迭代器首先给出 [1,2] 然后 [3,4] .

currify 接受一个函数并允许部分应用它。例如，

f = currify { a, b -> a + b }

表示 f(2,3) = 5，f(2)(3) = 5，而 f(2) 是一个加 2 的闭包。我从this question 得到这个答案。

currifying 单参数闭包实际上应该对它没有任何作用，并且就像它上面的识别函数一样。

最后，我覆盖了迭代器上的 >> 运算符，因此我可以像使用管道一样使用它。

我的问题是为什么F: 行失败，而A-E 行都成功了？

代码（很长）在这里，就像我说的，也在ideone。

@groovy.transform.TypeChecked

class Unfoldr<A,B> implements java.util.Iterator<A>
{
  public Unfoldr(Closure<Object[]> f, B init) 
  {
    this.f = f;
    this.state = f(init);
  }

  public synchronized A next() throws java.util.NoSuchElementException
  {
    if (hasNext())
    {
      A curr = state[0];
      state = f(state[1]);
      return curr;
    }
    else
    {
      throw new java.util.NoSuchElementException();
    }
  }

  public synchronized boolean hasNext() 
  {
    return state != null;
  }

  public void remove() { throw UnsupportedOperationException; }

  private Closure<Object[]> f;

  private Object[] state;
}

def currify(fn) {
    { Object... args ->
        if (args.size() == fn.maximumNumberOfParameters) {
            fn(*args)
        } else {
            currify(fn.curry(*args))
        }
    }
};

def unfoldr = currify { f, init -> new Unfoldr(f, init) };

def map = currify { f, l -> unfoldr({ l2 -> if (l2.hasNext()) { def e = l2.next(); return [f(e), l2]} else { return null; } } , l.iterator())}

def splitlist = currify {
n, l ->
  unfoldr(
    { 
      l2 -> 
        try 
        { 
          def a = new Object[n];
          for (i in 0..(n-1))
          {
            a[i] = l2.next();
          }
          return [a, l2]; 
        } 
        catch (java.util.NoSuchElementException e) 
        {
          return null;
        }
    }, 
    l
  )
};

Iterator.metaClass.rightShift = { PrintStream os -> delegate.each({ x -> os.println(x) }) }
Iterator.metaClass.rightShift = { Closure f -> f(delegate) }

id = { x -> x }
f = currify { x -> x }

println "A: "
[[1,2],[3,4]].iterator() >> System.out
println "B: "
[1,2,3,4].iterator() >> splitlist(2) >> System.out
println "C: "
[[1,2],[3,4]].iterator() >> map(id) >> System.out
println "D: "
[1,2,3,4].iterator() >> splitlist(2) >> map(id) >> System.out
println "E: "
[[1,2],[3,4]].iterator() >> map(f) >> System.out
println "F: "
[1,2,3,4].iterator() >> splitlist(2) >> map(f) >> System.out

输出：

A: 
[1, 2]
[3, 4]
B: 
[1, 2]
[3, 4]
C: 
[1, 2]
[3, 4]
D: 
[1, 2]
[3, 4]
E: 
[1, 2]
[3, 4]
F: 
Caught: java.lang.IllegalArgumentException: Can't curry 2 arguments for a closure with 1 parameters.
java.lang.IllegalArgumentException: Can't curry 2 arguments for a closure with 1 parameters.
    at prog$_currify_closure8.doCall(prog.groovy:42)
    at prog$_run_closure2_closure9.doCall(prog.groovy:49)
    at Unfoldr.<init>(prog.groovy:8)
    at prog$_run_closure1.doCall(prog.groovy:47)
    at prog$_currify_closure8.doCall(prog.groovy:40)
    at prog$_run_closure2.doCall(prog.groovy:49)
    at prog$_currify_closure8.doCall(prog.groovy:40)
    at prog$_run_closure5.doCall(prog.groovy:75)
    at prog.run(prog.groovy:91)

Answer 1

看起来F行失败原因

def e = l2.next() 

返回 Object[] 而不是 ArrayList