Perl 变量范围问题

Question

所以我有一个 Perl 类。它有一个sort() 方法，我希望它或多或少与内置的sort() 函数相同：

$object->sort(sub ($$) { $_[0] <=> $_[1] });

但我做不到：

$object->sort(sub { $a <=> $b });

因为范围。但是 List::Util 模块使用reduce() 执行此操作。我查看了 List::Util 模块，他们使用no strict 'vars' 做了一些相当讨厌的事情来实现这一点。我试过了，但没有用。

据我了解，reduce() 以它的方式工作，因为它被导出到适当的命名空间中，因此我的类不能这样做，因为该函数非常牢固地位于另一个命名空间中。这是正确的，还是在我的情况下有一些（无疑更可怕和不明智的）方法可以做到这一点？

Answer 1

嗯，其他两个答案都对了一半。这是一个实际排序的有效解决方案：

package Foo;

use strict;
use warnings;

sub sort {
    my ($self, $sub) = @_;

    my ($pkg) = caller;
    my @x = qw(1 6 39 2 5);
    print "@x\n";
    {
        no strict 'refs';
        @x = sort {
            local (${$pkg.'::a'}, ${$pkg.'::b'}) = ($a, $b);
            $sub->();
        } @x;
    }
    print "@x\n";

    return;
}


package main;

use strict;
use warnings;

my $foo = {};
bless $foo, 'Foo';

$foo->sort(sub { $a <=> $b });
# 1 6 39 2 5
# 1 2 5 6 39

大概你会对一些实际上是对象一部分的数据进行排序。

您需要caller 魔法，以便在调用者的包中本地化$a 和$b，这是Perl 将在其中寻找它们的地方。它正在创建仅在调用 sub 时才存在的全局变量。

请注意，warnings 将获得一个“仅使用一次的名称”；我敢肯定，您可以通过某种方式来避免这种情况。

Answer 2

您可以使用Sub::Identify 找出与coderef 关联的包（它称为stash_name）。然后根据需要在该包中设置 $a 和 $b。您可能需要在您的方法中使用 no strict 'refs' 才能使其正常工作。

这是修改后的 Evee 的答案以适用于一般情况：

use strict;
use warnings;

package Foo;

use Sub::Identify 'stash_name';

sub sort {
    my ($self, $sub) = @_;

    my $pkg = stash_name($sub);
    my @x = qw(1 6 39 2 5);
    print "@x\n";
    {
        no strict 'refs';
        @x = sort {
            local (${$pkg.'::a'}, ${$pkg.'::b'}) = ($a, $b);
            $sub->();
        } @x;
    }
    print "@x\n";

    return;
}


package Sorter;

sub compare { $a <=> $b }

package main;

use strict;
use warnings;

my $foo = {};
bless $foo, 'Foo';

$foo->sort(\&Sorter::compare );

$foo->sort(sub { $b <=> $a });

Answer 3

您可以使用the local operator 在子例程调用期间设置$a 和$b 的值：

sub sample
{
    my $callback = shift;
    for (my $i = 0; $i < @_; $i += 2) {
        local ($a, $b) = @_[$i, $i + 1];
        $callback->();
    }
}       

sample sub { print "$a $b\n" }, qw(a b c d e f g h i j);

如果你有一个普通的子程序，而不是一个方法，那么你可以让它更像sort，所以你不需要在你的回调函数之前使用sub。在函数上使用原型：

sub sample (&@)

那你这样称呼它：

sample { print "$a $b\n" } qw(a b c d e f g h i j);

不过，方法不受原型的影响。