Spock 使用 Mockito 测试 Kotlin 类

Question

我有一些用 Spock 编写的测试，涵盖了我的 Java 代码。现在我迁移到 Kotlin，问题是我无法模拟最终课程，所以我决定使用此处描述的 Mockito 插件：https://github.com/mockito/mockito/wiki/What%27s-new-in-Mockito-2#unmockable

问题是我需要用 Mockitos 的 any()、anyString()、when()、then() 等替换每个 '_' '>>' 吗？我尝试使用 Mockito 模拟最终课程，但它似乎不起作用。

如果我必须替换在这种情况下使用 Spock 测试框架的优势是什么？也许我应该删除它并只使用 Mockito？

Answer 1

我不使用 Kotlin，但我之前使用过 PowerMock 来模拟最终类/方法和静态方法。我想知道是否可以使用 Spock 的 GroovyMock 和全局 GroovySpy 功能，并使用 Spock 1.1-groovy-2.4 对 Java 代码进行测试。在第一个快速而肮脏的测试场景中，它似乎可以工作：

正在测试的 Java 类：

package de.scrum_master.stackoverflow;

public final class FinalClass {
  public static final String finalStaticMethod() {
    return "x";
  }

  public final String finalMethod() {
    return "x";
  }
}

Spock 测试：

package de.scrum_master.stackoverflow

import spock.lang.Specification

/**
 * See https://stackoverflow.com/q/48391716/1082681
 * See http://spockframework.org/spock/docs/1.1/all_in_one.html#GroovyMocks
 */
class FinalClassTest extends Specification {
  def "use GroovyMock for final method in final class"() {
    given:
    FinalClass finalClass = GroovyMock() {
      finalMethod() >> "mocked"
    }

    expect:
    finalClass.finalMethod() == "mocked"
  }

  def "use global GroovySpy for final static method in final class"() {
    given:
    GroovySpy(FinalClass, global: true)
    FinalClass.finalStaticMethod() >> "mocked"

    expect:
    FinalClass.finalStaticMethod() == "mocked"
  }
}

对我来说，运行测试时这两种功能方法都是绿色的。也许您想尝试一下我的示例，然后尝试使用您的 Kotlin 类 - 不过我不保证后者。

---

注意：Spock manual 说：

当从 Java 代码调用时，Groovy 模拟将表现得像常规模拟。

因此，将 Groovy Mocks 作为依赖项注入到被测 Java 类中时，您可能会感到失望。

---

更新：好的，我用另一个 Java 类使用那些花哨的 GroovyMocks 对其进行了测试 - 如上所述 - 它不起作用：

使用模拟类作为依赖的 Java 类：

package de.scrum_master.stackoverflow;

public class AnotherClass {
  public String doSomething(FinalClass finalClass) {
    return finalClass.finalMethod();
  }

  public String doSomethingElse() {
    return FinalClass.finalStaticMethod();
  }
}

Spock 测试：

package de.scrum_master.stackoverflow

import spock.lang.Specification

/**
 * See https://stackoverflow.com/q/48391716/1082681
 * See http://spockframework.org/spock/docs/1.1/all_in_one.html#GroovyMocks
 */
class AnotherClassTest extends Specification {
  def "indirectly use GroovyMock for final method in final class"() {
    given:
    FinalClass finalClass = GroovyMock() {
      finalMethod() >> "mocked"
    }

    expect:
    new AnotherClass().doSomething(finalClass) == "mocked"
  }

  def "indirectly use global GroovySpy for final static method in final class"() {
    given:
    GroovySpy(FinalClass, global: true)
    FinalClass.finalStaticMethod() >> "mocked"

    expect:
    new AnotherClass().doSomethingElse() == "mocked"
  }
}

很遗憾，两个测试都失败，因为这些方法在从 Java 类中使用时不会被存根。即你被 PowerMock 或 Mockito 困住了。但是您仍然可以使用所有其他不错的 Spock 功能，例如数据表、@Unroll 等等。

---

更新 2：解决方案

将此添加到您的 Maven 构建中（如果您使用 Gradle，请执行类似操作）：

<dependency>
  <groupId>de.jodamob.kotlin</groupId>
  <artifactId>kotlin-runner-spock</artifactId>
  <version>0.3.1</version>
  <scope>test</scope>
</dependency>

现在您可以将项目kotlin-testrunner 中的SpotlinTestRunner 与类似注释结合使用

• @OpenedClasses([Foo, Bar, Zot])
• @OpenedPackages(["de.scrum_master.stackoverflow", "my.other.package"])

当然，这不适用于静态方法（您仍然需要 PowerMock），但您的问题是关于封闭 Kotlin 类中的非静态方法。使用这个测试运行器，您可以模拟它们，因为一个特殊的类加载器会在测试执行之前通过 Javassist 打开它们：

package de.scrum_master.stackoverflow

import de.jodamob.kotlin.testrunner.OpenedClasses
import de.jodamob.kotlin.testrunner.OpenedPackages
import de.jodamob.kotlin.testrunner.SpotlinTestRunner
import org.junit.runner.RunWith
import spock.lang.Specification

/**
 * See https://stackoverflow.com/q/48391716/1082681
 * See https://github.com/dpreussler/kotlin-testrunner
 */
@RunWith(SpotlinTestRunner)
@OpenedClasses(FinalClass)
//@OpenedPackages("de.scrum_master.stackoverflow")
class AnotherClassSpotlinRunnerTest extends Specification {
  def "use SpotlinRunner to stub final method in final class"() {
    given:
    FinalClass finalClass = Stub() {
      finalMethod() >> "mocked"
    }

    expect:
    new AnotherClass().doSomething(finalClass) == "mocked"
  }
}