VB.NET 如何正确循环遍历结果集

Question

我在这个网站上查看了许多不同的代码 sn-ps，看起来这些代码会告诉我如何做一些在我掌握了知识后应该相当简单的事情。

我想在数据库表中查询一组值，然后用这些结果填充组合框。

这是我目前所拥有的：

Public Sub getMachines()
    Try

            Dim SQL As String = "SELECT MachineName from machine"


            Form1.machineName.DisplayMember = "Text"
            Dim tb As New DataTable
            tb.Columns.Add("Text", GetType(String))

            Using cn As New MySqlConnection(ConnectionString)
                Using cmd As New MySqlCommand(SQL, cn)

                    For Each cmd As String In cmd
                        'I want to add each value found in the database to "tb.Rows.Add"
                        'tb.Rows.Add(???)
                    Next

                    Form1.machineName.DataSource = tb

                    cn.Open()
                    cmd.ExecuteNonQuery()
                End Using
                cn.Close()
            End Using

    Catch ex As MySqlException
        MsgBox(ex.Message)
    End Try
End Sub

Answer 1

我的做法和你一样。我使用了 DataTable 的 Load 方法。不必设置列名和类型。列名取自 Select 语句，数据类型由 ADO.net 从前几条记录中推断出来。

幸运的是，DataTable 可以使用 .AsEnumnerable 方法成为 Enumerable。然后我们可以使用 Linq 从 MachineName 列中获取所有值。调用 .ToArray 会导致 Linq 执行。如果您将光标悬停在这一行的名称上，您将看到数据类型是 String()。正是我们需要填充组合框。

DataAccess 类的代码

Private ConnectionString As String = "Your Connection String"

Public Function GetMachineNames() As String()
    Dim tb As New DataTable
    Dim SQL As String = "SELECT MachineName from machine;"
    Using cn As New MySqlConnection(ConnectionString)
        Using cmd As New MySqlCommand(SQL, cn)
            cn.Open()
            dt.Load(cmd.ExecuteReader)
        End Using
    End Using
    Dim names = dt.AsEnumerable().Select(Function(x) x.Field(Of String)("MachineName")).ToArray()
    Return names
End Function

在表单中加载你这样的组合框。

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim DatAcc As New DataAccess() 
    Dim arr = DatAcc.GetMachineNames()
    machineName.DataSource = arr
End Sub

Answer 2

如果您只想将 MachineName 显示在 ComboBox 中，那么只需将其用作 DisplayMember；不要费心创建另一个名为 Text 的列。

Public Sub getMachines()
    Try
        Dim cmd As String = "SELECT MachineName from machine"
        Dim ds As New DataSet()
        Using con As New MySqlConnection(ConnectionString)
            Using da As New MySqlDataAdapter(cmd, con)
                da.Fill(ds)
                With Form1.machineName
                    .DisplayMember = "MachineName"
                    .ValueMember = "MachineName"
                    .DataSource = ds
                End With
            End Using
        End Using
    Catch ex As MySqlException
        MsgBox(ex.Message)
    End Try
End Sub

Answer 3

我将展示一些示例，包括使用参数，因为这很重要。

首先，快速翻译运行现有查询并循环遍历结果：

Public Sub getMachines()
    Try    
        Dim SQL As String = "SELECT MachineName from machine"

        Using cn As New MySqlConnection(ConnectionString), _
              cmd As New MySqlCommand(SQL, cn)

            cn.Open()
            Using rdr As MySqlDatareader = cmd.ExecuteReader
                While rdr.Read()
                    Form1.machineName.Items.Add(rdr("MachineName"))
                End While
            End Using
        End Using
    Catch ex As MySqlException
        MsgBox(ex.Message)
    End Try
End Sub

但对于这种方法，更好的做法是隔离 UI 的数据访问。这个方法应该返回结果给调用者，调用者可以决定如何处理它们。所以我将展示两种方法：一种是获取数据，另一种是循环并设置组合框：

Private Function GetMachines() As DataTable
    'No try/catch needed here. Handle it in the UI level, instead
    Dim SQL As String = "SELECT MachineName from machine"
    Dim result As New DataTable

    Using cn As New MySqlConnection(ConnectionString), _
          cmd As New MySqlCommand(SQL, cn),
          da As New MySqlDataAdapter(cmd)

          da.Fill(result)
   End Using
   Return result
End Function

Public Sub LoadMachines()
    Try
        For Each item As DataRow in getMachines().Rows
            Form1.machineName.Items.Add(item("MachineName"))
        Next
    Catch ex As MySqlException
        MsgBox(ex.Message)
    End Try
End Sub

或者，我们可以使用 DataBinding：

Private Function GetMachines() As DataTable
    Dim SQL As String = "SELECT MachineName from machine"
    Dim result As New DataTable

    Using cn As New MySqlConnection(ConnectionString), _
          cmd As New MySqlCommand(SQL, cn),
          da As New MySqlDataAdapter(cmd)

          da.Fill(result)
   End Using
   Return result
End Function

Public Sub LoadMachines()
    Try
        Form1.machineName.DisplayMember = "FirstName";  
        Form1.machineName.ValueMember = "City" 
        Form1.machineName.DataSource = GetMachines()  
    Catch ex As MySqlException
        MsgBox(ex.Message)
    End Try
End Sub

如果你想使用过滤器，你可以这样做（注意重载）：

Private Function GetMachines(ByVal machineFilter As String) As DataTable
    Dim SQL As String = "SELECT MachineName from machine WHERE MachineName LIKE @Filter"

    Dim result As New DataTable

    Using cn As New MySqlConnection(ConnectionString), _
          cmd As New MySqlCommand(SQL, cn),
          da As New MySqlDataAdapter(cmd)

        'Match the MySqlDbType to your actual database column type and length
        cmd.Parameters.Add("@Filter", MySqlDbType.VarString, 30).Value = machineFilter

       da.Fill(result)
   End Using
   Return result
End Function

Private Function GetMachines(ByVal machineFilter As String) As DataTable
    Return GetMachines("%")
End Function

这样的查询参数非常重要，如果您在旧平台上进行字符串连接来完成这种事情，那么您在那儿做了非常糟糕的事情 ，也是。

最后，让我们来看看吧。很多时候，您真的不想将整个结果集加载到 RAM 中，就像 DataTable 所做的那样。那可能很糟糕。相反，您希望能够将结果流式传输到内存中，并且一次只能使用一个，从而最大限度地减少 RAM 的使用。在这些情况下，您可以使用DataReader... 但从Using 块（这很重要）中返回一个DataReader 对象并不能很好地工作。为了解决这个问题，我们可以使用函数式编程概念和高级语言特性：

Private Iterator Function GetMachines(ByVal machineFilter As String) As IEnumerable(Of String)
    Dim SQL As String = "SELECT MachineName from machine WHERE MachineName LIKE @Filter"

    Using cn As New MySqlConnection(ConnectionString), _
          cmd As New MySqlCommand(SQL, cn)

        'Match the MySqlDbType to your actual database column type and length
        cmd.Parameters.Add("@Filter", MySqlDbType.VarString, 30).Value = machineFilter
        cn.Open()
        Using rdr As MySqlDatareader = cmd.ExecuteReader
            While rdr.Read()
                Dim result As String = rdr("MachineName")
                Yield Return result
            End While
        End Using
   End Using
   Return result
End Function

Private Function GetMachines() As IEnumerable(Of String)
    Return GetMachines("%")
End Function