Azure APIM 中的 XML 转换答案

【问题标题】：XML Transformation in Azure APIMAzure APIM 中的 XML 转换
【发布时间】：2021-09-22 12:28:24
【问题描述】：

假设我有一个类似的 XML：

<A>
<B n='key1' v='value1'/>
<B n='key2' v='value2'/>
<B n='key3' v='value3'/>
<B n='key4' v='value4'/>
</A>

注意：这只是我提供的 4 行，但它有这么多行（B 标记）。

我想把它变成：

<XYZ name='value1'>
<MNP>value2</MNP>
</XYZ>
<XYZ name='value3'>
<MNP>value4</MNP>
</XYZ>

我需要在 azure apim 中做。

【问题讨论】：

怎么知道哪些B节点转化为XYZ节点，哪些转化为MNP子节点？
@PierreFrançois 只假设 value1 ，value 3 然后 value10 -> xyz 值 b/w 值 1 和 value3 ，值 b/w 值 3 和 value10 和值 b/w 值 10 直到结束 - > MNP
您想要的输出 XML 格式不正确。
我还是不明白你的代码怎么知道只有包含value1、value3和value10的B节点必须经过不同的处理。是否存在包含序列 value1、value3 和 value10 的变量？请编辑您的问题以完成它。 Martin Honnen（下）假设只有不均匀位置的 B 节点必须变成 XYZ 节点。
一旦我们得到 value1,3 和 10 之类的值，它将转到 XYZ 标签。这是一种检查值，如果值为 value1 或 3 或 10，那么它将转到 XYZ，否则在 MNP 标签中。

标签： xml azure xslt apim xmltransient

【解决方案1】：

使用 XSLT 2 或 3 中的位置分组，您可以解决它

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  expand-text="yes">

  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="A">
    <xsl:copy>
      <xsl:for-each-group select="B" group-adjacent="(position() - 1) idiv 2">
        <XYZ name="{@v}">
          <MPN>{current-group()[2]/@v}</MPN>
        </XYZ>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

使用 XSLT 1，您可以处理 B[position() mod 2 = 1] 以创建 XYZ 元素，然后导航到 following-sibling::B[1] 以创建 MPN 元素：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="A">
    <xsl:copy>
      <xsl:for-each select="B[position() mod 2 = 1]">
        <XYZ name="{@v}">
          <MPN>
            <xsl:value-of select="following-sibling::B[1]/@v"/>
          </MPN>
        </XYZ>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

【讨论】：