有没有一种简单的方法可以在 VB.NET 中随机化一个列表？

Question

我有一个System.IO.FileInfo 类型的列表，我想随机化该列表。我想我记得不久前看到过类似list.randomize() 的东西，但我找不到我可能在哪里看到过。

我的第一次尝试让我有了这个功能：

Private Shared Sub GetRandom(ByVal oMax As Integer, ByRef currentVals As List(Of Integer))
    Dim oRand As New Random(Now.Millisecond)
    Dim oTemp As Integer = -1
    Do Until currentVals.Count = IMG_COUNT
        oTemp = oRand.Next(1, oMax)
        If Not currentVals.Contains(oTemp) Then currentVals.Add(oTemp)
    Loop
End Sub

我向它发送我希望它迭代的最大 val，以及对我想要随机化内容的列表的引用。变量 IMG_COUNT 在脚本中设置得更远，指定我想要多少随机图像显示出来。

谢谢大家，我很感激：D

Answer 1

在此处查看 Fisher-Yates 洗牌算法：http://en.wikipedia.org/wiki/Knuth_shuffle

这个网站的主要霸主在这里进行了更简洁的讨论： http://www.codinghorror.com/blog/archives/001015.html

博客条目中有一个简单的 C# 实现，应该很容易更改为 VB.NET

Answer 2

我使用以下 Randomize() 函数扩展了 List 类以使用 Fisher-Yates shuffle 算法：

''' <summary>
''' Randomizes the contents of the list using Fisher–Yates shuffle (a.k.a. Knuth shuffle).
''' </summary>
''' <typeparam name="T"></typeparam>
''' <param name="list"></param>
''' <returns>Randomized result</returns>
''' <remarks></remarks>
<Extension()>
Function Randomize(Of T)(ByVal list As List(Of T)) As List(Of T)
    Dim rand As New Random()
    Dim temp As T
    Dim indexRand As Integer
    Dim indexLast As Integer = list.Count - 1
    For index As Integer = 0 To indexLast
        indexRand = rand.Next(index, indexLast)
        temp = list(indexRand)
        list(indexRand) = list(index)
        list(index) = temp
    Next index
    Return list
End Function

Answer 3

构建一个比较器：

Public Class Randomizer(Of T)
    Implements IComparer(Of T)

    ''// Ensures different instances are sorted in different orders
    Private Shared Salter As New Random() ''// only as random as your seed
    Private Salt As Integer
    Public Sub New()
        Salt = Salter.Next(Integer.MinValue, Integer.MaxValue)
    End Sub

    Private Shared sha As New SHA1CryptoServiceProvider()
    Private Function HashNSalt(ByVal x As Integer) As Integer
      Dim b() As Byte = sha.ComputeHash(BitConverter.GetBytes(x))
      Dim r As Integer = 0
      For i As Integer = 0 To b.Length - 1 Step 4
          r = r Xor BitConverter.ToInt32(b, i)
      Next

      Return r Xor Salt
    End Function

    Public Function Compare(x As T, y As T) As Integer _
        Implements IComparer(Of T).Compare

        Return HashNSalt(x.GetHashCode()).CompareTo(HashNSalt(y.GetHashCode()))
    End Function
End Class

像这样使用它，假设你的意思是一个通用的List(Of FileInfo)：

list.Sort(New Randomizer(Of IO.FileInfo)())

您也可以使用闭包使随机值“粘性”，然后在其上使用 linq 的 .OrderBy()（这次是 C#，因为 VB lambda 语法很难看）：

list = list.OrderBy(a => Guid.NewGuid()).ToList();

在此解释，以及为什么它甚至可能不如真正的随机播放快：
http://www.codinghorror.com/blog/archives/001008.html?r=31644

Answer 4

有几种合理的洗牌方法。

已经提到过一个。 （Knuth Shuffle。）

另一种方法是为每个元素分配一个“权重”并根据该“权重”对列表进行排序。这种方法是可行的，但会很笨拙，因为您不能从 FileInfo 继承。

最后一种方法是在原始列表中随机选择一个元素并将其添加到新列表中。当然，也就是说，如果您不介意创建一个新列表。 （尚未测试此代码...）

        Dim rnd As New Random
        Dim lstOriginal As New List(Of FileInfo)
        Dim lstNew As New List(Of FileInfo)

        While lstOriginal.Count > 0
            Dim idx As Integer = rnd.Next(0, lstOriginal.Count - 1)
            lstNew.Add(lstOriginal(idx))
            lstOriginal.RemoveAt(idx)
        End While

Answer 5

您也可以实现随机播放，有很多方法可以做到这一点，最简单的方法是随机选择一个项目并将其多次插入新位置。

Answer 6

如果您有元素数量，则可以使用伪随机方法，您可以随机选择第一个元素（例如使用内置随机数函数），然后添加一个素数并在除以数后取余数价值观。例如对于 10 个列表，您可以执行 i = (i + prime) % 10 从某个起始值生成索引 i 。只要素数大于列表中值的数量，那么您就可以创建一个序列，该序列贯穿所有数字 0...n，其中 n 是值的数量 - 1，但以伪随机顺序排列。

Answer 7

Dim oRand As New Random() 'do not seed!!!!
Private Sub GetRandom(ByRef currentVals As List(Of Integer))
    Dim i As New List(Of Integer), j As Integer
    For x As Integer = 0 To currentVals.Count - 1
        j = oRand.Next(0, currentVals.Count)
        i.Add(currentVals(j))
        currentVals.RemoveAt(j)
    Next
    currentVals = i
End Sub

Answer 8

您可以创建只返回随机数的自定义比较器，然后使用此比较器对列表进行排序。它可能效率极低并导致几乎无限循环，但可能值得一试。