如果找到，则使用 awk 替换特定列值

Question

如何使用awk 查找和替换特定列的值？

比如说 -> 我有一个包含以下内容的文件测试：

"abc":"100"::"新"

"xyz":"200":"mob":"old"

"lmn":"300"::"新"

"pqr":"400":"mob2":"新"

现在，如果第 3 列为空白，那么我想替换 "N/A" 中的空白值，否则按原样打印该行，以便输出如下：

"abc":"100":"N/A":"新"

"xyz":"200":"mob":"old"

"lmn":"300":"N/A":"新"

"pqr":"400":"mob2":"新"

虽然我通过以下命令使用 awk 获得了输出：

awk -F":" '{
    if ( $3 == "")
        print $1":"$2":\"N\/A\":"$4
    else
        print $0
}' test

但在这里我使用了每个列的硬编码值，例如$1、$2，因此如果其他示例中的空白列从第 3 列更改为 xyz，则必须再次在命令中更改相同的值。有没有其他方法可以使用 awk 而不使用列的硬编码值来获得相同的输出？感谢您的帮助。

Answer 1

首先，让我们稍微简化一下你现在的程序：

awk -F: 'BEGIN {OFS=FS} {       
  if ( $3 == "") $3="N/A"
  print $0
}' test

现在我们可以使两件事可变：要测试的列和替换字符串。因此，程序的主体看起来像

if ( $fieldnumber == "" ) $fieldnumber=replacement

剩下要做的就是填写变量。如果您查看 awk 的手册页，您会看到选项 -v 允许我们为 awk 变量指定初始值。

awk -F: -v fieldnumber=... -v replacement=...

这允许你从任何你喜欢的地方填充这个变量 - 你的 shell 脚本的参数、环境变量等。

更新： 修复输出字段分隔符 (OFS) 更新：修复语法错误

Answer 2

正确的方法是使用 GNU awk 进行 FPAT 和修改后的输入文件，以证明即使在引号字段中存在冒号时它也能正常工作：

$ cat tst.awk
BEGIN {
    FPAT = "([^:]*)|(\"[^\"]+\")"
    OFS = ":"
}
$3 == "" { $3 = "\"N/A\"" }
{ print }

$ cat file
"abc:def":"100"::"new"
"xyz":"200":"mob":"old"
"lmn":"123:456:300"::"new"
"pqr":"400":"mob2":"new"
"stu":"600":"foo::bar":"more"

$ awk -f tst.awk file
"abc:def":"100":"N/A":"new"
"xyz":"200":"mob":"old"
"lmn":"123:456:300":"N/A":"new"
"pqr":"400":"mob2":"new"
"stu":"600":"foo::bar":"more"

Answer 3

下面的 gawk 代码怎么样：

BEGIN {
    FS=":"
    OFS=":"
}
{
    for(i=1; i<=4; i++) {
        if ($(i) == "") field[i] = "N/A"
        else field[i] = $(i)
    }
    if ($0 != "") print field[1],field[2],field[3],field[4]
}

-- 或者--
也许下面的 bash 脚本要简单得多：

#!/bin/bash
export IFS=":"
while read a b c d; do
    echo "${a:-N/A}:${b:-N/A}:${c:-N/A}:${d:-N/A}"
done

带有输入重定向，即this_bash_script.sh < your_test_input.txt

Answer 4

使用 GNU awk：

awk -v RS='[:\n]'  '!NF{$0="\"N/A\""}{printf "%s%s",$0,RT}' test

记录分隔符RS设置为捕获分号:之间的数据。

如果没有任何字段（!NF），则设置想要的字符串。

printf 语句为当前记录写入数据和记录分隔符RT。