用户窗体中的 DateDiff 公式

Question

我有两个包含开始日期和结束日期的文本框。

我想得到一个数字，代表这两者之间的天数。

Private Sub TextBox20_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    'check date format
    With TextBox20
        If IsDate(TextBox20.Text) Then 'Format as desired.
            TextBox20.Text = Format(CDate(TextBox20.Text), "Dddd, d Mmm yyyy", vbMonday)
        Else
            TextBox20.Text = "" 'Clear the TextBox
            MsgBox "Por favor, ingresar una fecha valida."
            Cancel = True
            Exit Sub
        End If
    End With
End Sub

Private Sub TextBox21_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    'check date format
    With TextBox21
        If IsDate(TextBox21.Text) Then 'Format as desired.
            TextBox21.Text = Format(CDate(TextBox21.Text), "Dddd, d Mmm yyyy", vbMonday)
        Else
            TextBox21.Text = "" 'Clear the TextBox
            MsgBox "Por favor, ingresar una fecha valida."
            Cancel = True
            Exit Sub
        End If    
    End With
End Sub

Private Sub TextBox22_AfterUpdate()
TextBox22.Value = DateDiff("d", CDate(TextBox20.Value), CDate(TextBox21.Value), vbMonday)    
End Sub

我认为这是因为我将 TextBoxes 设置为 .Text 而不是 .Value，但没有任何变化。

Answer 1

根据文本框字符串正确计算DateDiff

虽然我通常做建议不要将原始控件条目（日期）覆盖为文本框中重新格式化的（日期）字符串，但我展示了一种非常接近于你的方法。这包括对可读日期字符串的一些规定，以便允许DateDiff() 计算。

UserForm代码模块声明头

为了保持正确的开始和结束日期（Date 类型和 not 字符串），我定义了一个Type 结构，可以在后续过程中轻松重用。

Option Explicit

Private Type TThis
    StartDate As Date
    EndDate   As Date
End Type
Dim this      As TThis

示例程序

• Sub CheckDays() 根据上面声明的类型结构中的条目计算 DateDiff。它与您的代码不同，因为每次退出文本框输入后都会调用计算函数。
• Function getDateString() 尝试通过调整可能导致错误日期转换的格式结果，使 TextBox 字符串可转换为 Date 类型。在调用CheckDays 计算之前，在文本框的事件过程中进行最后的IsDate() 检查。

Private Sub CheckDays()
' Purpose: calculate DateDiff and enter result into TextBox22
' Note   : called by TextBox20_Exit|TextBox21_Exit events
If this.StartDate > 0 And this.EndDate >= this.StartDate Then
    TextBox22.Text = DateDiff("d", this.StartDate, this.EndDate, vbMonday)
End If
End Sub

Private Function getDateString(ByVal txt As String) As String
' Purpose: make (TextBox) string convertible to Date type, if possible
   'a) remove leading day names (e.g. "Wednesday, 1 Jan 2020" ~> "1 Jan 2020")
    If InStr(txt, ",") > 0 Then txt = Split(txt, ",")(1)
   'b) add current year if missing (e.g. "1.1." ~> "1.1.2020")
    If Not IsDate(txt) Then
        If IsDate(txt & " " & Year(Now)) Then txt = txt & " " & Year(Now)
    End If
    getDateString = txt                     ' return function result
End Function

UserForm 事件过程

这些程序几乎没有改变，但包括

• 通过`getDateString() 分配DateString 以提供可转换的日期字符串以及
• CheckDays的过程调用计算DateDiff并将结果输入TextBox22。

附加说明： 除了_Exit 事件之外，还可以使用_AfterUpDate 事件。

Private Sub TextBox20_Exit(ByVal Cancel As MSForms.ReturnBoolean)
With TextBox20
    Dim DateString As String
    DateString = getDateString(.Text)       'Make TextBox string convertible to Date type.

    'check date format
    If IsDate(DateString) Then              'Format as desired.
        this.StartDate = CDate(DateString)  'Remember date (Date type).
        .Text = Format(this.StartDate, "Dddd, d Mmm yyyy", vbMonday)
        '========
        CheckDays                           '<< Call procedure to calculate DateDiff.
        '--------
    Else
        .Text = ""                          'Clear the TextBox string
        this.EndDate = 0
        MsgBox "Por favor, ingresar una fecha valida."
        Cancel = True
        Exit Sub
    End If
End With
End Sub

Private Sub TextBox21_Exit(ByVal Cancel As MSForms.ReturnBoolean)
With TextBox21
    Dim DateString As String
    DateString = getDateString(.Text)       'Make TextBox string convertible to Date type.

    'check date format
    If IsDate(DateString) Then              'Format as desired.
        this.EndDate = CDate(DateString)    'Remember date (Date type).
        .Text = Format(this.EndDate, "Dddd, d Mmm yyyy", vbMonday)
        '========
        CheckDays                           '<< call procedure to calculate DateDiff
        '--------
    Else
        .Text = ""                          'Clear the TextBox string
        this.EndDate = 0
        MsgBox "Por favor, ingresar una fecha valida."
        Cancel = True
        Exit Sub
    End If
End With
End Sub