将字符串格式的月份转换为 Word 宏中的数字

Question

我正在使用一个必须将日期转换为另一种格式的 Word 宏。

输入：2019 年 10 月 10 日

预计输出：2019 年 10 月 3 日

问题是日期的月份是字符串（10 de Marzo de 2019）。 我找不到将该日期转换为 dd/mm/YYYY 的方法。

到目前为止，我发现的所有内容都从 dd-mm-YYYY 转换为文本日期。

上面的代码可以使用字符串月份或其他格式从 dd/mm/yyyy 转换为日期，但它从不进入 isDate() 函数。如果我删除 isDate() 函数，格式不会执行。

这是我目前所拥有的：

Sub ChangeDates()

FoundOne = True ' loop at least once

Do While FoundOne ' loop until no date is found
    With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = "([0-9]{1,2}) de (*) de ([0-9]{4})"
        .Format = True
        .Forward = True
        .MatchWildcards = True
    End With

    Selection.Find.Execute replace:=wdReplaceNone

    ' check the find to be sure it's a date
    If IsDate(Selection.Text) Then
        Selection.Text = Format(Selection.Text, "dd-mm-yyyy")
        Selection.Font.Color = wdColorLightOrange
        Selection.Collapse wdCollapseEnd
    Else ' not a date - end loop
        FoundOne = False
    End If
Loop

End Sub

有没有办法做到这一点？ 提前致谢！

Answer 1

试试：

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "<[0-9]{1,2} de <*> de [0-9]{4}>"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute
  End With
  Do While .Find.Found
    Select Case LCase(Split(.Text, " de ")(1))
      Case "enero": i = 1
      Case "febrero": i = 2
      Case "marzo": i = 3
      Case "abril": i = 4
      Case "mayo": i = 5
      Case "junio": i = 6
      Case "julio": i = 7
      Case "agosto": i = 8
      Case "septiembre": i = 9
      Case "octubre": i = 10
      Case "noviembre": i = 11
      Case "diciembre": i = 12
      Case Else: i = 0
    End Select
    Select Case i
      Case 0
      Case Else: .Text = Split(.Text, " de ")(0) & "/" & Format(i, "00") & "/" & Split(.Text, " de ")(2)
    End Select
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

Answer 2

为了让 Word-VBA 识别日期，数据必须与日期的系统设置相匹配。例如，如果系统设置为美式英语，则问题中的日期不会被识别为有效日期，只会识别美式英语的日期。

VBA 代码需要包含将文本内容解析为特定语言的日期的逻辑。然后它需要将其转换为与系统日期匹配的日期，以便Format 函数起作用，或者它还需要处理格式转换。

Answer 3

我已经尝试过@macropod，尽管它对我不起作用，但我知道他的解决方案是有效的（可能是一些与语言有关的 Word 问题），一些更改应该可以使它工作，所以也可以随意使用它。

我接受了@Cindy Meister 的建议，这就是代码。这种方法的缺点是您必须进行两次搜索而不是一次，但优点是您使用 Word Format 内置功能并且可以随时更改格式。

Private Sub FechasEnTexto()

'We take the date to english format (dd M, Y)
With ActiveDocument.Range.Find
     .Text = "([0-9]{1,2}) de (*) de ([0-9]{4})"
     .Replacement.Text = "\1 \2, \3"
     .Forward = True
     .MatchWildcards = True
     .Execute replace:=wdReplaceAll
End With


'Here we look for the english format, and proceed to apply the format desired.   
Selection.HomeKey Unit:=wdStory, Extend:=wdMove
FoundOne = True ' loop at least once


Do While FoundOne ' loop until no date is found
    With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = "([0-9]{1,2}) (*), ([0-9]{4})"
        .Format = True
        .Forward = True
        .MatchWildcards = True
    End With

    Selection.Find.Execute replace:=wdReplaceNone


    ' check the find to be sure it's a date
    If IsDate(Selection.Text) Then
        Selection.Text = Format(Selection.Text, "dd/mm/yyyy")
        Selection.Collapse wdCollapseEnd
    Else ' not a date - end loop
        FoundOne = False
    End If
Loop


End Sub

Answer 4

Nicolas，也许在您的 IF 语句之前使用 NumberFormat。这样，您将设置格式以保证 IsDate 表达式将读取为 True，因此您的 IF 条件将得到满足。

Selection.NumberFormat = "dd-mm-yyyy"
If IsDate(Selection.Text) Then
    Selection.Text = Format(Selection.Text, "dd-mm-yyyy")
    Selection.Font.Color = wdColorLightOrange
    Selection.Collapse wdCollapseEnd
Else ' not a date - end loop
    FoundOne = False
End If