将 weeknum 放入数组中？

Question

这是我想要做的：Cell B2：开始日期和Cell B3：结束日期

示例：
B2 --> 2019 年 1 月 1 日
B3 --> 01/03/2019

我想获取所有的周数并将它们放入一个数组中

这是 Excel 单元格的图片

这是我目前的代码

Application.ScreenUpdating = False
Application.DisplayAlerts = False

Dim StartD As Date, EndD As Date 
Set wks = ThisWorkbook.Sheets("Foglio1")

Worksheets("Foglio1").Range("D2:XZ39").Clear 

StartD = Worksheets("Foglio1").Cells(2, 2) 
EndD = Worksheets("Foglio1").Cells(3, 2) 

我想遍历给定的两个日期： 01/01/2019 ， 01/03/2019 获取周数并将它们放入一个数组中（如果可能的话）

所以我的输出是：

Array(1, 2, 3, 4, 5, 6, 7, 8, 9) --> 从一月到三月有9周

Answer 1

你可以使用类似下面的东西

Option Explicit

Sub Sample()
    Dim sDate As Date, eDate As Date
    Dim NoOfWeeks As Long
    Dim arr As Variant
    Dim i As Long

    With Worksheets("Foglio1")
        sDate = .Range("B2")

        If Weekday(sDate, vbMonday) <> 1 Then
            sDate = DateAdd("d", 7 - Weekday(sDate, vbMonday) + 1, sDate)
            NoOfWeeks = 1
        End If

        eDate = .Range("B3")
    End With

    If sDate = eDate Then
        NoOfWeeks = NoOfWeeks + 1
    Else
        NoOfWeeks = NoOfWeeks + WorksheetFunction.RoundUp((eDate - sDate) / 7, 0)
    End If

    ReDim arr(1 To NoOfWeeks)
    For i = 1 To NoOfWeeks
        arr(i) = i
    Next i

    MsgBox Join(arr, ";")
End Sub

Answer 2

你可以像下面这样定义一个UDF：

Public Function GetWeekNums(startDate As Date, endDate As Date, Optional varDelim As Variant)
Dim lngStartWeek As Long
Dim lngEndWeek As Long
Dim i As Long

If IsMissing(varDelim) Then varDelim = ","

lngStartWeek = Application.WorksheetFunction.WeekNum(startDate)
lngEndWeek = Application.WorksheetFunction.WeekNum(endDate)
For i = lngStartWeek To lngEndWeek
    GetWeekNums = GetWeekNums & " " & i
Next

GetWeekNums = Replace(Trim(GetWeekNums), " ", varDelim & " ")

End Function

然后在工作簿中使用它，例如：

=GetWeekNums(B2,B3,";")

Answer 3

如果您不想要日历周，并且想要包括一周，即使其中有一天，那么您可以试试这个。

逻辑

1. 它会查找下一周的开始时间。所以默认的周数是1。
2. 循环并计算两个日期之间的天数（例如 Monday，然后是 Tuesday 等等），以最高者为准，将其返回并将其添加到 @ 987654323@。

也不需要循环和创建数组。您可以在 One Go

中创建顺序数组

代码

Option Explicit

Sub Sample()
    Dim WeeksCount As Long
    Dim CurCount As Long
    Dim countOfWeeks As Long
    Dim i As Long, tmpCount As Long

    Dim sDate As Date, eDate As Date

    sDate = DateSerial(2019, 1, 6)
    eDate = DateSerial(2019, 1, 8)

    If Weekday(sDate, vbMonday) <> 1 Then
        sDate = DateAdd("d", 7 - Weekday(sDate, vbMonday) + 1, sDate)
        WeeksCount = 1
    End If

    For i = 1 To 7
        CurCount = GetMeMyKindOfWeeksTotal(sDate, eDate, i)
        If tmpCount < CurCount Then tmpCount = CurCount
    Next i

    WeeksCount = WeeksCount + tmpCount

    Dim MyArray

    MyArray = Evaluate("Row(1" & ":" & WeeksCount & ")")

    If WeeksCount = 1 Then
        Debug.Print MyArray(1)
    Else
        For i = LBound(MyArray) To UBound(MyArray)
            Debug.Print MyArray(i, 1)
        Next i
    End If
End Sub

Private Function GetMeMyKindOfWeeksTotal(ByVal sDate As Date, ByVal eDate As Date, dy As Long)
    Dim j As Long
    Dim TotalDays As Long

    For j = sDate To eDate
        If Weekday(j) = dy Then
            TotalDays = TotalDays + 1
        End If
    Next

    GetMeMyKindOfWeeksTotal = TotalDays
End Function

各种测试

sDate = DateSerial(2019, 1, 6)
eDate = DateSerial(2019, 1, 8)

这会给你2

sDate = DateSerial(2019, 1, 1)
eDate = DateSerial(2019, 3, 1)

这会给你9

sDate = DateSerial(2019, 1, 1)
eDate = DateSerial(2019, 1, 1)

这会给你1

sDate = DateSerial(2019, 1, 1)
eDate = DateSerial(2019, 1, 8)

这会给你2

Answer 4

如果有人只喜欢工作表公式，您可以使用：

=ROW(INDEX($A:$A,WEEKNUM($B$2),1):INDEX($A:$A,WEEKNUM($B$3),1))

根据您的一周开始时间，为函数使用适当的 return_type 参数。