在 awk 字符串中调用“日期”命令，格式为 +%a

Question

这个网站还是新手，但这里有...... 基本上我将事件存储在多个文件中，每个事件都是一行，每一行包含日期（$1）、开始（$2）和停止（$3）时间以及其他几条数据。我使用两个双下划线（“__”）作为字段分隔符。我一直在使用各种 shell 脚本来管理数据，并且我正在使用 awk 来计算统计数据，但我在调用 date 函数时遇到了麻烦，因此我可以按星期几获得总数。经过大量修补和扫描讨论板后，我得到了这个：

ls /home/specified/folder/MBRS.db/* |
xargs -n 1 -I % awk -F"__" '$6 == "CLOSED" && $1 >= "'$backDATE'" { print $0 }' % |
awk 'BEGIN{FS="__"}{specDATE=system("date --date="$1" +%a")} specDATE == "Tue" {print $2" "$3}'

或

ls /home/lingotech/Einstein/data/MBRS.db/* |
xargs -n 1 -I % awk -F"__" '$6 == "CLOSED" && $1 >= "'$backDATE'" { print $0 }' % |
awk 'BEGIN{FS="__"}system("date --date="$1" +%a") == "Mon" {print $2" "$3}'`

我没有输出开始和停止时间，而是为每个条目获取一周中所有不同日期的列表。

我尝试了比我愿意承认的更多的日期用法变体，包括：

for y in Sun Mon Tue Wed Thu Fri Sat; do
  for directory in $( ls /home/specified/directory/MBRS.db/* | xargs -n 1 ); do
    printf "."
    [[ $( cat $directory | awk -F"__" '$6 == "CLOSED" && $1 >= "'$backDATE'" { print $1 }' | xargs -n 1 -I z date +%a -d z ) == "$y" ]] && echo BLAH
  done
done

非常感谢对我搞砸的事情进行一些有用的解释。提前致谢。哦，我以 YYMMDD 格式存储日期，但这对于 ubuntu 服务器的“日期”版本似乎不是问题。

Answer 1

好的，所以我最终使用了这个：

>backDATE=150000; 
>     for x in $listOFsites; do
>        for y in Sun Mon Tue Wed Thu Fri Sat; do
>            totalHOURS=$( awk 'BEGIN{FS="__"} NF == 10 && $1 >= "'$backDATE'" && $4 == "'$x'" && $6 == "CLOSED" {while ( ( "date +%a -d \""$1"\"" | getline newDAY) > 0 ){if (newDAY == "'$y'") print $2" "$3}}' /home/absolute/path/* | xargs -I % /home/custom/duration/calc % | paste -sd+ | bc ); printf "."; 
>        done
>     done

我必须在单引号内使用日期（这样我就可以将 $1 传递给它）而不是在外面（使用 -F"__" -v newDAY=...），但在单引号内得到输出system() 是有问题的。在看到：How can I pass variables from awk to a shell command? 之后，我终于看到了 while (cmd | get line x) 格式，这是我的问题的症结所在。给 Ed Morton 的道具

Answer 2

我不知道其余的所有内容（对于我的阅读口味而言，文字太多了！）但是根据您发布的答案，它的这一部分：

awk 'BEGIN{FS="__"} NF == 10 && $1 >= "'$backDATE'" && $4 == "'$x'" && $6 == "CLOSED" {while ( "date +%a -d "$1"" | getline newDAY){if (newDAY == "'$y'") print $2" "$3}}' /home/absolute/path/*

假设它做你想做的事情会写成：

awk -v backDATE="$backDATE" -v x="$x" -v y="$y" '
    BEGIN { FS="__" }
    (NF == 10) && ($1 >= backDATE) && ($4 == x) && ($6 == "CLOSED") {
        cmd = "date +%a -d \"" $1 "\""
        while ( (cmd | getline newDAY) > 0 ) {
            if (newDAY == y) {
                print $2, $3
            }
        }
        close(cmd)
    }
' /home/absolute/path/*

为什么要使用 awk 变量而不是让 shell 变量扩展成为 shell 脚本主体的一部分，答案是健壮性和简单性。

这是让 shell 变量扩展成为 awk 脚本主体的一部分：

$ x="hello world"
$ awk 'BEGIN{ print '$x' }'
awk: cmd. line:1: BEGIN{ print hello
awk: cmd. line:1:                   ^ unexpected newline or end of string
$ awk 'BEGIN{ print "'$x'" }'
awk: cmd. line:1: BEGIN{ print "hello
awk: cmd. line:1:              ^ unterminated string
awk: cmd. line:1: BEGIN{ print "hello
awk: cmd. line:1:              ^ syntax error
$ awk 'BEGIN{ print "'"$x"'" }'
hello world
$ x="hello
world"
$ awk 'BEGIN{ print "'"$x"'" }'
awk: cmd. line:1: BEGIN{ print "hello
awk: cmd. line:1:              ^ unterminated string
awk: cmd. line:1: BEGIN{ print "hello
awk: cmd. line:1:              ^ syntax error

这是使用一个用 shell 变量的值初始化的 awk 变量：

$ x="hello world"
$ awk -v x="$x" 'BEGIN{ print x }'
hello world

$ x="hello
world"
$ awk -v x="$x" 'BEGIN{ print x }'
hello
world

看到区别了吗？

至于为什么将命令存储在变量中 - 因为您必须在使用后关闭它，并且在关闭命令中的拼写方式必须与打开管道时完全相同。比较：

cmd = "date +%a -d \"" $1 "\""
cmd | getline
close(cmd)

对比：

"date +%a -d \"" $1 "\"" | getline
close("date +%a -d \"" $l "\"")

并用非常接近的时间l确定第二版中的错误。