使用 autotools 安装 systemd 服务

Question

我有一个自动工具项目，它成功地构建和测试了一个应用程序 (https://github.com/goglecm/AutoBrightnessCam)。该应用程序安装在 bin 目录中（前面有用户指定的任何前缀）。这很简单。我现在需要创建一个 systemd 服务以在启动时启动它。我已经创建了服务文件并手动运行它，它工作正常。

最后一点是告诉 configure.ac 和 Makefile.am 用应用程序的正确路径修补 *.service.in 文件（就像 config.h 是从 config.h.in 创建的一样）。

使用 AC_CONFIG_HEADERS 是否适合将 *.service.in 修补到 *.service 中？是否有另一个宏用于“非标题”？

另外，我如何指定服务文件应该登陆（即安装）在 /etc/systemd/system 中？

是否有更好的方法在没有 systemd 的情况下在启动时启动此应用？

Answer 1

如何指定服务文件应该登陆（即安装）在 /etc/systemd/system 中？

根据Systemd的daemon man page：

安装 systemd 服务文件

在构建安装时（例如，在包构建期间make install），建议将包安装在pkg-config systemd --variable=systemdsystemunitdir（用于系统服务）或pkg-config systemd --variable=systemduserunitdir（用于用户服务）返回的目录中。这将使系统中的服务在明确请求时可用，但不会在引导期间自动激活它们。可选地，在软件包安装过程中（例如管理员rpm -i），应通过systemctl(1)工具的启用命令在systemd配置目录中创建符号链接，以便在启动时自动激活它们。

建议使用autoconf(1) 的软件包在源配置期间使用如下配置脚本摘录来确定单元安装路径：

PKG_PROG_PKG_CONFIG
AC_ARG_WITH([systemdsystemunitdir],
     [AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files])],,
     [with_systemdsystemunitdir=auto])
AS_IF([test "x$with_systemdsystemunitdir" = "xyes" -o "x$with_systemdsystemunitdir" = "xauto"], [
     def_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)

     AS_IF([test "x$def_systemdsystemunitdir" = "x"],
   [AS_IF([test "x$with_systemdsystemunitdir" = "xyes"],
    [AC_MSG_ERROR([systemd support requested but pkg-config unable to query systemd package])])
    with_systemdsystemunitdir=no],
   [with_systemdsystemunitdir="$def_systemdsystemunitdir"])])
AS_IF([test "x$with_systemdsystemunitdir" != "xno"],
      [AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])])
AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$with_systemdsystemunitdir" != "xno"])

这个 sn-p 允许在 systemd 机器上自动安装单元文件，并且可以选择允许在缺少 systemd 的机器上安装它们。 （对用户单元目录的这个sn-p的修改留给读者练习。）

另外，为确保 make distcheck 继续工作，建议在基于 automake(1) 的项目的顶级 Makefile.am 文件中添加以下内容：

AM_DISTCHECK_CONFIGURE_FLAGS = \
  --with-systemdsystemunitdir=$$dc_install_base/$(systemdsystemunitdir)

最后，应在系统中安装单元文件，其中包含如下的 automake 摘录：

if HAVE_SYSTEMD
systemdsystemunit_DATA = \
  foobar.socket \
  foobar.service
endif

...

看来您应该使用systemdsystemunitdir 和systemduserunitdir。 Autotools 对它的支持如何，嗯...

在 Fedora 31 上使用 grep systemdsystemunitdir /bin/autoconf 和 grep -IR systemdsystemunitdir /usr/share 快速 grep 显示尚不支持 Autotools。 7 年了……

---

有没有更好的方法在没有 systemd 的情况下在启动时启动这个应用程序？

Systemd 应该可以启动您的应用程序。只需使用systemctl(1) 像往常一样启用和启动它们。

根据您的GitHub and autobrightnesscam.service.in，我不会为此使用 Autotools。您可能会浪费大量时间来解决 Autotols 的缺点（根据经验）。

我的configure.ac 脚本（它只是一个shell 脚本）会将autobrightnesscam.service.in 复制到autobrightnesscam.service，然后使用sed 复制正确的目录和文件。然后，我会将更新后的autobrightnesscam.service 复制到AC_CONFIG_COMMANDS_POST 中的正确位置。可能是这样的：

SERVICE_FILE=autobrightnesscam.service
SYSTEMD_DIR=`pkg-config systemd --variable=systemdsystemunitdir`

# Use default if SYSTEMD_DIR is empty
if test x"$SYSTEMD_DIR" = "x"; then
    SYSTEMD_DIR=/etc/systemd/system
fi

AC_CONFIG_COMMANDS_POST([cp "$SERVICE_FILE" "$SYSTEMD_DIR"])
AC_CONFIG_COMMANDS_POST([systemctl enable "$SYSTEMD_DIR/$SERVICE_FILE"])
AC_CONFIG_COMMANDS_POST([systemctl start "$SERVICE_FILE"])

Answer 2

使用 AC_CONFIG_HEADERS 是否适合将 *.service.in 修补到 *.service 中？是否有另一个宏用于“非标题”？

没有。 AC_CONFIG_HEADERS 用于设置配置标头以支持您的构建。除了构建 config.h 来记录 Autoconf 执行的某些测试的结果之外，它很少用于其他任何事情，而且它不像该领域的其他选项那样灵活。

如果您希望 Autoconf 从模板构建其他文件，那么您应该通过 AC_CONFIG_FILES 告诉 Autoconf。示例：

AC_CONFIG_FILES([Makefile AutoBrightnessCam.service])

但是，如果您填写该模板的某些数据是安装目录，那么 Autoconf 可能根本不适合这样做，因为它规定安装前缀可以通过 make 的参数进行更改.您至少需要解决这个问题，但最好的办法是使用它，并在make 的控制下构建.service 文件。这并不难，而且有几个技术优势，即使不需要担心任何安装目录替换，也有一些技术优势。

您可以像configure 那样做，通过运行您已经通过sed 使用的相同模板，并使用适当的脚本。你的Makefile.am中会出现这样的内容：

SERVICE_SUBS = \
    s,[@]VARIABLE_NAME[@],$(VARIABLE_NAME),g; \
    s,[@]OTHER_VARIABLE[@],$(OTHER_VARIABLE),g

AutoBrightnessCam.service: AutoBrightnessCam.service.in
    $(SED) -e '$(SERVICE_SUBS)' < $< > $@

另外，我如何指定服务文件应该登陆（即 安装）在/etc/systemd/system？

您使用Automake's standard mechanism for specifying custom installation locations。也许是这样的：

sytemdsysdir = $(sysconfdir)/systemd/system

systemdsys_DATA = AutoBrightnessCam.service

有没有更好的办法 在没有 systemd 的情况下在启动时启动此应用？

在基于 systemd 的机器上，systemd 控制着启动时的启动。如果您希望机器在启动时自动启动您的应用程序，那么我认为您的选择仅限于

• 配置 systemd 以启动它
• 配置最终由 systemd 启动的程序链中的某些内容以启动它
• 破解引导加载程序或内核以启动它

这里有不同意见的余地，但我认为其中第一个是最干净和最适合未来的，我不推荐最后一个。