TBPF_INDETERMINATE 状态在 Windows 7 任务栏上的 .NET 2.0 中无效

Question

我有一个非常奇怪的问题。我有一个 VB.NET 2.0 应用程序，它利用了 Windows 7 任务栏按钮进度功能，即在 Win7 任务栏按钮中显示某些进度和应用程序状态。

一切正常 - 我可以设置和更新进度，我可以将按钮设置为暂停或错误状态，我可以将其设置为无进度。一切正常，除了 MARQUE（不确定）模式。这完全是个谜，每当我将状态设置为 TBPF_INDETERMINATE（值为 0x1）时，它都会简单地更改回 NOPROGRESS 类型，即它会从任务栏按钮中删除所有进度指示并将其设置回默认状态 - 从来没有动画标记显示！

我已阅读 MSDN 上的文档 - http://msdn.microsoft.com/en-us/library/dd391697(v=vs.85).aspx ；尝试了各种组合，例如将进度设置为 0，然后调用 set state 来不确定；或者喜欢先将其设置为正常，然后再设置为不确定 - 没有任何效果。这完全是个谜——文档中没有任何线索说明它失败的原因......

代码如下： API 实现：

    <StructLayout(LayoutKind.Sequential)> _
Public Structure RECT
    Public left As Integer
    Public top As Integer
    Public right As Integer
    Public bottom As Integer

    Public Sub New(left As Integer, top As Integer, right As Integer, bottom As Integer)
        Me.left = left
        Me.top = top
        Me.right = right
        Me.bottom = bottom
    End Sub
End Structure

Public Enum TBPFLAG
    TBPF_NOPROGRESS = 0
    TBPF_INDETERMINATE = &H1
    TBPF_NORMAL = &H2
    TBPF_ERROR = &H4
    TBPF_PAUSED = &H8
End Enum

Public Enum TBATFLAG
    TBATF_USEMDITHUMBNAIL = &H1
    TBATF_USEMDILIVEPREVIEW = &H2
End Enum

Public Enum THBMASK
    THB_BITMAP = &H1
    THB_ICON = &H2
    THB_TOOLTIP = &H4
    THB_FLAGS = &H8
End Enum

Public Enum THBFLAGS
    THBF_ENABLED = 0
    THBF_DISABLED = &H1
    THBF_DISMISSONCLICK = &H2
    THBF_NOBACKGROUND = &H4
    THBF_HIDDEN = &H8
End Enum

<StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)> _
Public Structure THUMBBUTTON
    <MarshalAs(UnmanagedType.U4)> _
    Public dwMask As THBMASK
    Public iId As UInteger
    Public iBitmap As UInteger
    Public hIcon As IntPtr
    <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=260)> _
    Public szTip As String
    <MarshalAs(UnmanagedType.U4)> _
    Public dwFlags As THBFLAGS
End Structure

<ComImportAttribute()> _
<GuidAttribute("ea1afb91-9e28-4b86-90e9-9e9f8a5eefaf")> _
<InterfaceTypeAttribute(ComInterfaceType.InterfaceIsIUnknown)> _
Public Interface ITaskbarList3
    ' ITaskbarList
    <PreserveSig()> _
    Sub HrInit()
    <PreserveSig()> _
    Sub AddTab(hwnd As IntPtr)
    <PreserveSig()> _
    Sub DeleteTab(hwnd As IntPtr)
    <PreserveSig()> _
    Sub ActivateTab(hwnd As IntPtr)
    <PreserveSig()> _
    Sub SetActiveAlt(hwnd As IntPtr)

    ' ITaskbarList2
    <PreserveSig()> _
    Sub MarkFullscreenWindow(hwnd As IntPtr, <MarshalAs(UnmanagedType.Bool)> fFullscreen As Boolean)

    ' ITaskbarList3
    Sub SetProgressValue(<[In]()> ByVal hwnd As IntPtr, <[In]()> ByVal ullCompleted As UInt64, <[In]()> ByVal ullTotal As UInt64) 'hwnd As IntPtr, ullCompleted As UInt64, ullTotal As UInt64)
    Sub SetProgressState(<[In]()> ByVal hwnd As IntPtr, <[In]()> ByVal tbpFlags As TBPFLAG) 'hwnd As IntPtr, tbpFlags As TBPFLAG) 'As Integer
    Sub RegisterTab(hwndTab As IntPtr, hwndMDI As IntPtr)
    Sub UnregisterTab(hwndTab As IntPtr)
    Sub SetTabOrder(hwndTab As IntPtr, hwndInsertBefore As IntPtr)
    Sub SetTabActive(hwndTab As IntPtr, hwndMDI As IntPtr, tbatFlags As TBATFLAG)
    Sub ThumbBarAddButtons(hwnd As IntPtr, cButtons As UInteger, <MarshalAs(UnmanagedType.LPArray)> pButtons As THUMBBUTTON())
    Sub ThumbBarUpdateButtons(hwnd As IntPtr, cButtons As UInteger, <MarshalAs(UnmanagedType.LPArray)> pButtons As THUMBBUTTON())
    Sub ThumbBarSetImageList(hwnd As IntPtr, himl As IntPtr)
    Sub SetOverlayIcon(hwnd As IntPtr, hIcon As IntPtr, <MarshalAs(UnmanagedType.LPWStr)> pszDescription As String)
    Sub SetThumbnailTooltip(hwnd As IntPtr, <MarshalAs(UnmanagedType.LPWStr)> pszTip As String)
    '[MarshalAs(UnmanagedType.LPStruct)]
    Sub SetThumbnailClip(hwnd As IntPtr, ByRef prcClip As RECT)
End Interface

<GuidAttribute("56FDF344-FD6D-11d0-958A-006097C9A090")> _
<ClassInterfaceAttribute(ClassInterfaceType.None)> _
<ComImportAttribute()> _
Public Class CTaskbarList
End Class

以下是使用代码的实际过程：

 Friend Sub SetWindows7Progress(ByVal aValue As Integer)
        If Not IsWin7orLater Then Exit Sub
            If w7tb Is Nothing Then
                w7tb = CType(New CTaskbarList, ITaskbarList3)
            End If
            CType(w7tb, ITaskbarList3).SetProgressValue(My.Forms.Form1.Handle, Math.Min(Math.Max(1, aValue), 1000), 1000)
 End Sub

    Friend Sub ResetWindows7Progress()
        If Not IsWin7orLater Then Exit Sub
            If w7tb Is Nothing Then
                w7tb = CType(New CTaskbarList, ITaskbarList3)
            End If
            CType(w7tb, ITaskbarList3).SetProgressState(My.Forms.Form1.Handle, TBPFLAG.TBPF_NOPROGRESS)
    End Sub

    Friend Sub SetWindows7ProgressMon()
        If Not IsWin7orLater Then Exit Sub
            If w7tb Is Nothing Then
                w7tb = CType(New CTaskbarList, ITaskbarList3)
            End If
            CType(w7tb, ITaskbarList3).SetProgressState(My.Forms.Form1.Handle, TBPF_INDETERMINATE)
    End Sub

我什至尝试从 SetProgressState 获取 HRESULT 代码并检查以确保没有抛出异常，但无济于事：SetProgressState 始终返回 0（一切正常）；并且不会抛出异常！

任何帮助解决问题将不胜感激！我简直不敢相信除了 MARQUE/INDETERMINATE 状态之外的一切都正常！

谢谢。

Answer 1

首先，很奇怪，您的工作函数正在使用以下代码访问您的表单实例：

 My.Forms.Form1.Handle

这意味着这些函数没有定义在与您的表单相同的类中（因为如果是，编译器会提示您使用Me，而不是）。如果是这样的话，你真的应该将表单的句柄作为参数传递给函数。

（这样做的原因是你的函数是可重用的。如果你硬编码一个对特定表单的引用，当你重命名该表单时会发生什么，或者一次在屏幕上显示它的两个实例，或者只是想要要在任务栏中为不同的表单显示进度指示器？事情坏了。将表单实例作为参数传递是一种更简洁、更可重用的方法。）

第二，似乎进行了不必要的选角。为什么不首先将w7tb 变量声明为ITaskbarList3 类型，而不是在它和CTaskbarList 之间来回转换？

第三，我不确定这是错字还是实际问题，但您的SetWindows7ProgressMon 函数实际上并未引用TBPF_INDETERMINATE 的正确值。当它实际上在TBPFLAG 枚举中定义时，您使用对该标识符的非限定引用。

因此，考虑到以上所有情况，我将重写您发布的第二个代码块，如下所示：

Private w7tb As ITaskbarList3

Friend Sub SetWindows7Progress(ByVal frm As Form, ByVal aValue As Integer)
    If (Not IsWin7orLater()) OrElse (frm Is Nothing) Then
        Exit Sub
    End If

    If w7tb Is Nothing Then
        w7tb = CType(New CTaskbarList, ITaskbarList3)
    End If
    w7tb.SetProgressValue(frm.Handle, Math.Min(Math.Max(1, aValue), 1000), 1000)
End Sub

Friend Sub ResetWindows7Progress(ByVal frm As Form)
    If (Not IsWin7orLater()) OrElse (frm Is Nothing) Then
        Exit Sub
    End If

    If w7tb Is Nothing Then
        w7tb = CType(New CTaskbarList, ITaskbarList3)
    End If
    w7tb.SetProgressState(frm.Handle, TBPFLAG.TBPF_NOPROGRESS)
End Sub

Friend Sub SetWindows7ProgressMon(ByVal frm As Form)
    If (Not IsWin7orLater()) OrElse (frm Is Nothing) Then
       Exit Sub
    End If

    If w7tb Is Nothing Then
        w7tb = CType(New CTaskbarList, ITaskbarList3)
    End If
    w7tb.SetProgressState(frm.Handle, TBPFLAG.TBPF_INDETERMINATE)
End Sub

经过测试，它可以在 32 位 Windows 7 上完美运行。请注意，您可以通过简单地为 frm 参数指定 Me 来从表单类内部的代码中调用函数。