Perl - 将 PC UTF-8 转换为 PC ANSI

Question

我有一个以 PC UTF-8 编码的文件。我想将文件转换为 PC ANSI。

我已经尝试了以下，但我总是得到输出文件是 PC UTF-8。

use Encode;

$infile = $ARGV[0];
open(INFILE, $infile);

my $outfile = "temp.txt";

open(OUTFILE, ">$outfile");

while(<INFILE>) {
  my $row = $_;
  chomp $row;

  $row = Encode::encode("Windows-1252", $row);
  print OUTFILE $row."\n";

}

close INFILE;
close OUTFILE;

Answer 1

问题是您从不解码您编码的数据。

use strict;
use warnings;
use Encode qw( encode decode );

open(my $INFILE,  '<', $ARGV[0]) or die $!;
open(my $OUTFILE, '>', $ARGV[1]) or die $!;

while (my $utf8 = <$INFILE>) {
   my $code_points = decode('UTF-8', $utf8);    # <-- This was missing.
   my $cp1252 = encode('cp1252', $code_points);
   print $OUTFILE $cp1252;
}

但是你可以更容易地做到这一点：

use strict;
use warnings;

open(my $INFILE,  '<:encoding(UTF-8)',  $ARGV[0]) or die $!;
open(my $OUTFILE, '>:encoding(cp1252)', $ARGV[1]) or die $!;

while (<$INFILE>) {
   print $OUTFILE $_;
}

Answer 2

您应该使用 PerlIO-Layers，而不是手动进行解码和编码。您可以使用binmode 函数指定层，或者在三参数open 的模式参数中：

use strict; use warnings;
use autodie;

open my $INFILE,  '<:utf8',                 $ARGV[0];
open my $OUTFILE, '>:encoding(iso-8859-1)', "temp.txt";
#                   ^-- the layers

while (my $line = <$INFILE>) {
  print $OUTFILE $line;
}

请注意，Perl 默认不会以 UTF8 格式打开文件，您还必须指定解码层。 :encoding(utf8)这个层太常见了，你可以直接说:utf8。

您可以列出所有可用的编码

use Encode;
print "$_\n" for Encode->encodings();